批处理之家 - Powered by Discuz! Board

标题: [文件操作] 批处理为何只能删除文件夹内的全部文件，不能排除文件？ [打印本页]

作者: solipsimy 时间: 2021-1-9 19:14 标题: 批处理为何只能删除文件夹内的全部文件，不能排除文件？

目录树
1.目录\WTF\Account\账号
2.目录\WTF\Account\账号\服务器\角色
其中"账号"和"角色"文件夹下都有名为"SavedVariables"的文件夹

自己照葫芦画瓢写的

@echo off
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /ad /b /s ^| findstr "SavedVariables"') do (
	del /q "%%i"
	echo "%%i"
)
pause
复制代码

想要的效果
1.在当前根目录文件夹内执行；
2.只删除根目录下WTF文件夹内名称为"SavedVariables"的文件夹内的文件（该文件夹内的文件只有.lua和.lua.bak类型的文件）
3.需要保留"SavedVariables"文件夹内的"SuperMacro.lua"和"SuperMacro.lua.bak"文件，其他的文件都删除（文件很多，只上传了部分）

感谢大佬

作者: went 时间: 2021-1-9 19:56

显示无误,就把第8行的REM删掉

@echo off & cd /d "%~dp0"
for /r /d %%i in ("SavedVariables*") do (
	echo %%i
	pushd "%%i"
	for %%a in ("*") do (
		if /i not "%%a"=="SuperMacro.lua" if /i not "%%a"=="SuperMacro.lua.bak" (
			echo del %%a
			REM del /f "%%a"
		)
	)
	popd "%%~i"
	echo -----------------------------------
)
pause
复制代码

作者: solipsimy 时间: 2021-1-9 20:51

回复 2# went

大佬牛批！膜拜！

作者: 路过 时间: 2021-1-9 21:05

稍微修改了一下

@echo off
cd /d "%~dp0"
for /f "delims=" %%i in ('dir /ad /b /s ^| findstr "SavedVariables"') do (
        copy "%%i\SuperMacro.lua" "1.lua" >nul
        copy "%%i\SuperMacro.lua.bak" "1.lua.bak" >nul	
        del /q "%%i" >nul
        echo "%%i"
        move "1.lua" "%%i\SuperMacro.lua" >nul
        move "1.lua.bak" "%%i\SuperMacro.lua.bak" >nul
)
pause
复制代码

欢迎光临批处理之家 (http://www.bathome.net/)