批处理之家 - Powered by Discuz! Board

标题: [文本处理] 求改个批处理，增加替换文件名中特定字符的功能 [打印本页]

作者: anszboy 时间: 2021-1-5 16:00 标题: 求改个批处理，增加替换文件名中特定字符的功能

请热心的坛友帮改个bat，增加批量替换文件名中特定字符的功能，比如文件名中的"_生产周报"，替换为"_第六车间简报"；
不要另外单独写个bat,请在原命令中增加语句，另外不要提示输入，需要替换的内容直接写死，点击后直接运行。先谢谢了！！

原来的命令如下：

@echo off & title 以当前批处理文件所在位置的层级为根目录，移动所有下级子目录里的所有文件到根目录,并对指定类型文件增加文件夹命名的前缀，最后删除空文件夹。 警告：会覆盖同名文件
for /f "delims=" %%a in ('dir /a-d /b /s ') do (move "%%~a" ./)
for /f "tokens=*" %%i in ('dir/s/b/ad^|sort /r') do rd "%%i"
rem 获取当前文件夹名
set str=%~p0
set str=%str:~,-1%&call :lp
rem 更名
for /f "delims=" %%i in ('dir /a-d /b *.xls') do (
ren "%%i" %var%"#"%%i
)
echo 搞定!&pause>nul&goto :eof
:lp
if "%str:~-1%" equ "\" goto :eof
set a=%str:~-1%
set var=%a%%var%&set str=%str:~,-1%&goto lp
复制代码

作者: qixiaobin0715 时间: 2021-1-5 16:29

本帖最后由 qixiaobin0715 于 2021-1-5 16:34 编辑

回复 1# anszboy
重新写一个批处理，用你的批处理处理好文件后，将下面代码放在文件所在目录运行：

@echo off
set /p str1=请输入替换前的字符：
set /p str2=请输入替换后的字符：
setlocal enabledelayedexpansion
for %%a in ("*%str1%*.xls") do (
    set "var=%%a"
    ren "%%a" "!var:%str1%=%str2%!"
)
pause
复制代码

作者: anszboy 时间: 2021-1-5 16:36

本帖最后由 anszboy 于 2021-1-5 16:56 编辑

回复 2# qixiaobin0715
最好能整合到一起，你写的网上有现成的，我就是不知如何整合，才发帖求助

作者: Batcher 时间: 2021-1-5 17:09

回复 1# anszboy

试试这样可以吗

@echo off
title 以当前批处理文件所在位置的层级为根目录，移动所有下级子目录里的所有文件到根目录,并对指定类型文件增加文件夹命名的前缀，最后删除空文件夹。 警告：会覆盖同名文件
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /a-d /b /s') do (move "%%~a" ./)
for /f "tokens=*" %%i in ('dir/s/b/ad^|sort /r') do rd "%%i"
rem 获取当前文件夹名
set str=%~p0
set str=%str:~,-1%
call :lp
rem 更名
for /f "delims=" %%i in ('dir /a-d /b *.xls') do (
    set "NewName=%var%#%%i"
    set "NewName=!NewName:_生产周报=_第六车间简报!"
    ren "%%i" "!NewName!"
)
echo 搞定
pause
goto :eof

:lp
if "%str:~-1%" equ "\" goto :eof
set a=%str:~-1%
set var=%a%%var%
set str=%str:~,-1%
goto :lp
复制代码

作者: anszboy 时间: 2021-1-5 17:19

回复 4# Batcher

谢谢老大，可以了，3Q艾瑞玛曲！！

欢迎光临批处理之家 (http://www.bathome.net/)