批处理之家 - Powered by Discuz! Board

标题: [文件操作] [已解决]关于批处理删除文件夹的 bug ？ [打印本页]

作者: 慕夜蓝化 时间: 2020-9-27 13:02 标题: [已解决]关于批处理删除文件夹的 bug ？

本帖最后由慕夜蓝化于 2020-9-29 14:46 编辑

@echo off
ECHO 清理target中的所有内容


set "projectDir=H:\InReason\irapy_x64"
for /f "delims=" %%i in ('dir /s/b/l/ad %projectDir%') do (
    echo %%i|findstr "target$" >nul&&echo,指定要删除的文件夹---：%%i&rd /s /q %%i
)
复制代码

结果我想要的删除的没删掉。
而是所有的不包含指定条件的被删除了。
好在我这边做了备份，不然所有的文件都没了。

然后，我做了一个更改。

for /f "delims=" %%i in ('dir /s/b/l/ad %projectDir%') do (
    echo %%i|findstr "target$" >nul&&rd /s /q %%i
)
复制代码

我把那个 echo 拿掉就正常了。

作者: xczxczxcz 时间: 2020-9-27 14:03

不是BUG，是第7行的&rd xxxx和前面的findstr结果没有任何瓜果关系。而是一个独立的命令行。

作者: Batcher 时间: 2020-9-27 15:21

回复 1# 慕夜蓝化

用if命令可以避免出现【&、&&代码实际语法跟你的想象不一样】的问题：

@echo off
set "projectDir=H:\InReason\irapy_x64"
for /f "delims=" %%i in ('dir /s /b /l /ad "%projectDir%"') do (
    echo %%i|findstr "target$" >nul
    if errorlevel 1 (
        echo 不符合删除条件的文件夹---：%%i
    ) else (
        echo 指定要删除的文件夹---：%%i
        rd /s /q "%%i"
    )
)
复制代码

还可以试试把findstr命令放到for循环的fileset里面，避免循环内部重复调用findstr命令导致代码效率较低：

@echo off
set "projectDir=H:\InReason\irapy_x64"
for /f "delims=" %%i in ('dir /s /b /l /ad "%projectDir%"^|findstr "target$"') do (
    echo 指定要删除的文件夹---：%%i
    rd /s /q "%%i"
)
复制代码

作者: 慕夜蓝化 时间: 2020-9-29 14:43

回复 2# xczxczxcz

可是，如果只有

&& echo,%%i
复制代码

所显示出的结果确实是正确的，而且使用

&&echo,%%i&del /s /q %%i
复制代码

也是完全没有问题的。
问题就出现在换了 rd 命令立马出错，变成了不包含条件的全部删除了。

作者: 慕夜蓝化 时间: 2020-9-29 14:45

回复 3# Batcher

谢谢batcher大大，我这边已经解决了。
解决办法，是添加一个括号，将如果正确情况下要执行的语句全部括起来就可以了。

set "projectDir=H:\InReason\irapy_x64"
for /f "delims=" %%i in ('dir /s/b/l/ad %projectDir%') do (
    echo %%i|findstr "target$" >nul&&(echo,指定要删除的文件夹---：%%i&rd /s /q %%i)
)
复制代码

欢迎光临批处理之家 (http://www.bathome.net/)