批处理之家 - Powered by Discuz! Board

标题: [文本处理] [已解决]批处理怎样把系统信息横排输出 [打印本页]

作者: testest 时间: 2020-3-30 17:46 标题: [已解决]批处理怎样把系统信息横排输出

本帖最后由 testest 于 2020-4-8 10:57 编辑

@echo off & setlocal enabledelayedexpansion
for /f "tokens=2 delims==" %%a in ('wmic csproduct get Vendor /value ^| findstr /i "Vendor"') do echo 制造商：%%~a >>d:\mac.csv
for /f "tokens=2 delims==" %%a in ('wmic csproduct get Name /value ^| findstr /i "Name"') do echo 电脑型号：%%~a >>d:\mac.csv
for /f "tokens=2 delims==" %%a in ('wmic os get caption /value ^| findstr /i "caption"') do echo 操作系统：%%~a >>d:\mac.csv
复制代码

写了一个读取系统信息的程序，生成mac.csv,可是生成的结果是竖排的，可否横排，各位老大帮忙，谢谢~
如下：
制造商电脑型号操作系统
... ... ...
各占一列

作者: wujunkai 时间: 2020-3-30 18:25

回复 1# testest

@echo off & setlocal enabledelayedexpansion
echo 制造商	电脑型号	操作系统>mac.csv
for /f "tokens=2 delims==" %%a in ('wmic csproduct get Vendor /value ^| findstr /i "Vendor"') do set "value=%%~a"
for /f "tokens=2 delims==" %%a in ('wmic csproduct get Name /value ^| findstr /i "Name"') do set "value=%value%	%%~a"
for /f "tokens=2 delims==" %%a in ('wmic os get caption /value ^| findstr /i "caption"') do set "value=%value%	%%~a"
echo %value%>>mac.csv
pause
复制代码

不知道为什么，我好像没法把他写到D:\mac.csv，只能用相对路径了。。。
请自行解决

作者: testest 时间: 2020-3-30 19:35

回复 2# wujunkai
不好意思，我没说清楚，可否在生成的excel表格中按ABC排列呢？
A B C
1 制造商电脑型号操作系统

作者: wujunkai 时间: 2020-3-30 19:40

回复 3# testest

@echo off & setlocal enabledelayedexpansion
echo 制造商,电脑型号,操作系统>mac.csv
for /f "tokens=2 delims==" %%a in ('wmic csproduct get Vendor /value ^| findstr /i "Vendor"') do set "value=%%~a"
for /f "tokens=2 delims==" %%a in ('wmic csproduct get Name /value ^| findstr /i "Name"') do set "value=%value%,%%~a"
for /f "tokens=2 delims==" %%a in ('wmic os get caption /value ^| findstr /i "caption"') do set "value=%value%,%%~a"
echo %value%>>mac.csv
pause
复制代码

作者: testest 时间: 2020-3-30 20:38

回复 4# wujunkai

for /f "tokens=1,3 delims=," %%i in ('getmac /v /nh /fo:csv ^| findstr
"..-..-..-..-..-.."') do (
    echo %%i %%j
) 
复制代码

再加个物理地址呢

作者: wujunkai 时间: 2020-3-30 20:45

本帖最后由 wujunkai 于 2020-3-31 08:00 编辑

回复 5# testest

我这里有三个，不怎么知道做

"无线网络连接" "balabalabala"
"本地连接" "balabalabala"
"Bluetooth 网络连接" "balabalabala"
复制代码

给出一个近似的解决方案。

@echo off & setlocal enabledelayedexpansion

set "type=制造商,电脑型号,操作系统"

for /f "tokens=2 delims==" %%a in ('wmic csproduct get Vendor /value ^| findstr /i "Vendor"') do set "value=%%~a"
for /f "tokens=2 delims==" %%a in ('wmic csproduct get Name /value ^| findstr /i "Name"') do set "value=%value%,%%~a"
for /f "tokens=2 delims==" %%a in ('wmic os get caption /value ^| findstr /i "caption"') do set "value=%value%,%%~a"
for /f "tokens=1,3 delims=," %%i in ('getmac /v /nh /fo:csv ^| findstr "..-..-..-..-..-.."') do (
    set type=!type!,%%i
    set value=!value!,%%j
)

echo %type%>mac.csv
echo %value%>>mac.csv

pause
复制代码

接下来，请仔细阅读代码，自行修改。（别告诉我你不会csv格式）

作者: testest 时间: 2020-3-31 18:17

本帖最后由 testest 于 2020-3-31 18:19 编辑

回复 testest

我这里有三个，不怎么知道做给出一个近似的解决方案。接下来，请仔细阅读代码，自 ...
wujunkai 发表于 2020-3-30 20:45

太帅了，可否把

"无线网络连接" "balabalabala"
"本地连接" "balabalabala"
"Bluetooth 网络连接" "balabalabala"

放在一个表格里
如：          A          B             C
1          制造商    电脑型号       MAC
                                             "无线网络连接" "balabalabala"
                                             "本地连接" "balabalabala"
                                             "Bluetooth 网络连接" "balabalabala"
2          ....       ....             ...

作者: wujunkai 时间: 2020-3-31 19:46

回复 7# testest

　　我在这里说一下代码的原理吧。
　　首先，设置type和value两个变量，tpye储存A行的数据，value储存B行的数据。
然后，在程序的主要部分慢慢地将数据加入type和value。
　　最后，输出type和value的值。
　　所以，接下来的需求请自行解决。

作者: testest 时间: 2020-4-1 10:05

回复 8# wujunkai

好的，谢谢你

作者: testest 时间: 2020-4-1 22:51

本帖最后由 testest 于 2020-4-1 22:53 编辑

回复 8# wujunkai

@echo off & setlocal enabledelayedexpansion
if  1  lss  2   (
set "type=制造商,电脑型号,操作系统"

for /f "tokens=2 delims==" %%a in ('wmic csproduct get Vendor /value ^| findstr /i "Vendor"') do set "value=%%~a"
for /f "tokens=2 delims==" %%a in ('wmic csproduct get Name /value ^| findstr /i "Name"') do set "value=%value%,%%~a"
for /f "tokens=2 delims==" %%a in ('wmic os get caption /value ^| findstr /i "caption"') do set "value=%value%,%%~a"
for /f "tokens=1,3 delims=," %%i in ('getmac /v /nh /fo:csv ^| findstr "..-..-..-..-..-.."') do (
    set type=!type!,%%i
    set value=!value!,%%j
)

echo %type%>mac.csv
echo %value%>>mac.csv
) else (
echo ok
)

pause
复制代码

在问问，如果加了判断语句，为啥得到的文档里头只显示

ECHO 处于关闭状态。
ECHO 处于关闭状态。

作者: wujunkai 时间: 2020-4-2 07:11

回复 10# testest

这个是延时变量的问题，把里面所有的%balabala%改成!balabala!就可以了

欢迎光临批处理之家 (http://www.bathome.net/)