批处理之家 - Powered by Discuz! Board

标题: [文件操作] 求助鼠标选几个文件拖到bat上就可以重命名 [打印本页]

作者: myacg 时间: 2020-1-17 17:44 标题: 求助鼠标选几个文件拖到bat上就可以重命名

一个中文改数字的bat
应用对象是“bat所在文件夹下的所有文件”这个改成“当前选择的文件（任意文件夹）”就是用鼠标选几个文件拖到bat上就可以重命名的那种。

@echo off


for /f "delims=" %%i in ('dir /b') do call :Replacement "%%i"


exit


:Replacement


set t1=%~1


set t1=%t1:九十=90%


set t1=%t1:八十=80%


set t1=%t1:七十=70%


set t1=%t1:六十=60%


set t1=%t1:五十=50%


set t1=%t1:四十=40%


set t1=%t1:三十=30%


set t1=%t1:二十=20%


set t1=%t1:十一=11%


set t1=%t1:十二=12%


set t1=%t1:十三=13%


set t1=%t1:十四=14%


set t1=%t1:十五=15%


set t1=%t1:十六=16%


set t1=%t1:十七=17%


set t1=%t1:十八=18%


set t1=%t1:十九=19%


set t1=%t1:十=10%


set t1=%t1:九=9%


set t1=%t1:八=8%


set t1=%t1:七=7%


set t1=%t1:六=6%


set t1=%t1:五=5%


set t1=%t1:四=4%


set t1=%t1:三=3%


set t1=%t1:二=2%


set t1=%t1:一=1%


set t1=%t1:零=0%


set t1=%t1:09=9%


set t1=%t1:08=8%


set t1=%t1:07=7%


set t1=%t1:06=6%


set t1=%t1:05=5%


set t1=%t1:04=4%


set t1=%t1:03=3%


set t1=%t1:02=2%


set t1=%t1:01=1%


echo %t1%


ren %1 "%t1%"


goto :eof
复制代码

作者: /zhqsystem/zhq 时间: 2020-1-17 22:19

1,for行替换和追加
if exist "%~f1\" cd/d "%~f1" //引入for循环,文件夹执行职能执行一个文件夹
if not exist "%~f1\" cd/d "%~dp1" call:1 %* //引入多文件执行

2,exit行下方追加
:1
if /i "%~f1"=="" goto:eof
call:Replacement "%~f1"
shift
goto:1

3,其他保持不变

作者: myacg 时间: 2020-1-19 11:02

回复 3# /zhqsystem/zhq
能麻烦高人直接贴一下修改版好吗，小白一个。

作者: went 时间: 2020-1-19 13:13

@echo off
setlocal enabledelayedexpansion
set "fileName=%~nx1"
set "str=九十:90 八十:80 七十:70 六十:60 五十:50 四十:40 三十:30 二十:20 十一:11 十二:12 十三:13 十四:14 十五:15 十六:16 十七:17 十八:18 十九:19 十:10 九:9 八:8 七:7 六:6 五:5 四:4 三:3 二:2 一:1 零:0 09:9 08:8 07:7 06:6 05:5 04:4 03:3 02:2 01:1"
for %%i in (%str%) do (
	for /f "tokens=1,2 delims=:" %%a in ("%%i") do (
		set "fileName=!fileName:%%a=%%b!"
	)
)
echo 即将重命名 "%~nx1" --^> "%fileName%" 
echo 确认请按回车键...
pause >nul
rename "%~1" "!fileName!" && echo 重命名完成 || 重命名失败
pause
复制代码

这是吧单个文件拖到bat上执行重命名

作者: myacg 时间: 2020-1-20 16:38

本帖最后由 myacg 于 2020-1-20 16:43 编辑

回复 5# went

好像只能执行选择的第一个文件。。。
而且希望能够不跳出确认框框，直接执行就行。可以吗，谢谢。

作者: myacg 时间: 2020-1-20 16:58

回复 2# xczxczxcz
谢谢，能改成不提示操作那种吗，直接运行就好了。

作者: went 时间: 2020-1-20 21:27

回复 6# myacg

@echo off
setlocal enabledelayedexpansion
:loop
if not "%1"=="" (
	call :renNow "%~1"
	shift /1
	goto :loop
)
echo 重命名完成
pause&exit
:renNow
set "fileName=%~nx1"
set "str=九十:90 八十:80 七十:70 六十:60 五十:50 四十:40 三十:30 二十:20 十一:11 十二:12 十三:13 十四:14 十五:15 十六:16 十七:17 十八:18 十九:19 十:10 九:9 八:8 七:7 六:6 五:5 四:4 三:3 二:2 一:1 零:0 09:9 08:8 07:7 06:6 05:5 04:4 03:3 02:2 01:1"
for %%i in (%str%) do (
	for /f "tokens=1,2 delims=:" %%a in ("%%i") do (
		set "fileName=!fileName:%%a=%%b!"
	)
)

echo 重命名 "%~nx1" --^> "%fileName%" 
rename "%~1" "!fileName!" && echo 成功 || echo 失败
echo -----------------------------
复制代码

作者: myacg 时间: 2020-1-23 10:39

回复 8# went

非常感谢！

欢迎光临批处理之家 (http://www.bathome.net/)