Board logo

标题: [文件操作] 求助，打开bat后有几个选项根据选项更改文件的某一行，之后重启某个进程 [打印本页]
作者: 三世三繁锦    时间: 2019-10-6 18:51     标题: 求助，打开bat后有几个选项根据选项更改文件的某一行，之后重启某个进程

就是打开bat后有几个数字选项，1更改ip为xxxx 2更改ip为xxxx 3更改ip为xxxx
文件的位置在C:\MFPC_Client\MFPC_Client.ini
文件内容为：
  1. [Setting]

  2. PublicComputer=0

  3. ServerIP=x.x.x.x
复制代码
这里的x.x.x.x 每个部门的不一样，所以得改这一行的内容，
然后改完之后自动重启MFPC_Client.exe这个进程（这个我倒是知道）
  1. @echo off

  2. @tasklist|find "MFPC_Client.exe"

  3. @if %errorlevel%==0 taskkill.exe /IM MFPC_Client.exe /t /f

  4. @start C:\MFPC_Client\MFPC_Client.exe

  5. @exit
复制代码
求助各位大神~~~
作者: zaqmlp    时间: 2019-10-6 20:12

  1. @echo off

  2. set info=互助互利,支付宝扫码头像,感谢打赏

  3. rem 有问题,可加QQ956535081及时沟通

  4. title %info%

  5. :input

  6. for %%a in (

  7.     "1=192.168.1.1"

  8.     "2=192.168.1.55"

  9.     "3=192.168.1.66"

  10. ) do (

  11.     set "#%%~a"

  12.     for /f "tokens=1* delims==" %%b in (%%a) do echo;%%b、更改ip为%%c

  13. )

  14. 

  15. set "c="

  16. set /p c=输入数字序号:

  17. set "inifile=C:\MFPC_Client\MFPC_Client.ini"

  18. 

  19. if not defined #%c% (echo;input error&goto end)

  20. if not exist "%inifile%" (echo;"%inifile%" not found&goto end)

  21. 

  22. (for /f "delims=" %%a in ('type "%inifile%"') do (

  23.     set "line=%%a"

  24.     setlocal enabledelayedexpansion

  25.     if /i "!line:~,9!" equ "ServerIP=" (

  26.         echo;ServerIP=!#%c%!

  27.     ) else echo;!line!

  28.     endlocal

  29. ))>"%tmp%\t.t"

  30. 

  31. move "%tmp%\t.t" "%inifile%"

  32. 

  33. call echo;%%#%c%%%

  34. taskkill /im MFPC_Client.exe /t /f

  35. start "" "C:\MFPC_Client\MFPC_Client.exe"

  36. :end

  37. echo;%info%

  38. pause
复制代码




欢迎光临 批处理之家 (http://www.bathome.net/) Powered by Discuz! 7.2