批处理之家 - Powered by Discuz! Board

标题: 30元求助.牛人闲的帮写个，第一个好用的人我必给！ [打印本页]

作者: kissn 时间: 2019-8-30 20:58 标题: 30元求助.牛人闲的帮写个，第一个好用的人我必给！

要求：用CMD批处理提取当前文件夹下所有子文件夹内的指定名称的子文件按该文件所在的子文件夹名称命名并提取到当前文件夹下新建个汇总文件夹中，列如：当前文件夹下有十个子文件夹，分别是1、2、3、4、5、6、7、8、9、10，而在每个文件夹下有a.txt,b.txt.c.txt等等每多文件，而我在主文件夹下抽取所有子文件夹下a.txt文件与c.txt文件，并存到主文件夹下汇总这个新文件夹中，1下的文件就是1a.txt与1b.txt ,如果没有的不取。这是一个角本。

另一个角本是：把以上取到的这个值再反回给各各文件夹中并覆盖重原文件名称，

是牛人来吧,
我vx: 198343

作者: zaqmlp 时间: 2019-8-30 21:09

本帖最后由 zaqmlp 于 2019-8-30 21:20 编辑

汇总

@echo off
set info=互助互利,支付宝扫码头像,感谢赞助
rem 有问题,可加QQ956535081及时沟通
title %info%
cd /d "%~dp0"
set "newfolder=汇总"
if not exist "%newfolder%" md "%newfolder%"
for /f "delims=" %%a in ('dir /ad/b') do (
    if "%%~nxa" neq "%newfolder%" (
        for %%b in ("a.txt" "c.txt") do (
                if exist "%%a\%%~b" (
                    echo;"%%a\%%~b" --^> ".\%newfolder%\%%~nxa_%%~b"
                    copy /y "%%a\%%~b" ".\%newfolder%\%%~nxa_%%~b"
                )
        )
    )
)
echo;%info%
pause
复制代码

作者: zaqmlp 时间: 2019-8-30 21:13

本帖最后由 zaqmlp 于 2019-8-30 21:21 编辑

分离

@echo off
set info=互助互利,支付宝扫码头像,感谢赞助
rem 有问题,可加QQ956535081及时沟通
title %info%
cd /d "%~dp0"
set "newfolder=汇总"
for /f "delims=" %%a in ('dir /a-d/b "%newfolder%"') do (
    for /f "tokens=1* delims=_" %%b in ("%%a") do (
        if exist ".\%%b\" (
            echo;"%newfolder%\%%a" --^> ".\%%b\%%c"
            copy /y "%newfolder%\%%a" ".\%%b\%%c"
        )
    )
)
echo;%info%
pause
复制代码

作者: flashercs 时间: 2019-8-30 21:56

汇总

@echo off
cd /d "%~dp0"
set "dstdir=汇总"
if not exist ".\%dstdir%" md ".\%dstdir%"
for /f "delims=" %%A in ('dir /ad /b') do (
    if /i not "%%A"=="%dstdir%" (
        for %%B in ("a.txt" "c.txt") do (
                if exist ".\%%A\%%~B" (
                    copy /y ".\%%A\%%~B" ".\%dstdir%\%%A%%~B"
                )
        )
    )
)
pause
exit /b
复制代码

复原

@echo off
setlocal EnableDelayedExpansion
cd /d "%~dp0"
set "srcdir=汇总"
if not exist ".\%srcdir%" md ".\%srcdir%"
for /f "delims=" %%A in ('dir /a-d /b ".\%srcdir%\*a.txt" ".\%srcdir%\*c.txt"') do (
    set "fname=%%A"
    set "dstdir=!fname:~,-5!"
    set "fname=!fname:~-5!"
    if not exist ".\!dstdir!" md ".\!dstdir!"
    copy /y ".\%srcdir%\%%A" ".\!dstdir!\!fname!"
)
endlocal
pause
exit /b
复制代码

作者: kissn 时间: 2019-8-30 22:45

回复 2# zaqmlp

汇总分离都没问题。钱已付

欢迎光临批处理之家 (http://www.bathome.net/)