批处理之家 - Powered by Discuz! Board

标题: [文件操作] [分享]BAT脚本批量创建文件 [打印本页]

作者: Batcher 时间: 2019-7-23 16:20 标题: [分享]BAT脚本批量创建文件

问题：
为何我这批处理不能批量新建文件嗯

@echo off
Set i=0000
:start
@cd. >"c:\users\administrator\desktop\%i%.txt"
if /a i<=0005(
i=i+1
got start
)else exit
复制代码

方案1.bat

@echo off
setlocal enabledelayedexpansion
set "n=10000"
for /l %%i in (%n%,1,10005) do (
    set x=%%i
    set x=!x:~-4!
    cd.>"c:\users\administrator\desktop\!x!.txt"
)
复制代码

方案2.bat

@echo off
setlocal enabledelayedexpansion
set "i=10000"
:start
cd.>"c:\users\administrator\desktop\!i:~-4!.txt"
if !i! leq 10005 (
    set /a i=i+1
    goto :start
)
复制代码

作者: Batcher 时间: 2019-7-23 20:01

问题：
能帮助添加个选择项吗，输入txt新建txt，输入html 新建html，输入什么扩展名，新建什么扩展名的文件

方案1.bat

@echo off
setlocal enabledelayedexpansion
set "i=10000"
REM 设置文件扩展名
set "xxx=txt"
:start
cd.>"c:\users\administrator\desktop\!i:~-4!.%xxx%"
if !i! leq 10005 (
    set /a i=i+1
    goto :start
)
复制代码

方案2.bat

@echo off
setlocal enabledelayedexpansion
set "i=10000"
REM 提示用户输入扩展名
set /p "xxx=请输入文件扩展名："
:start
cd.>"c:\users\administrator\desktop\!i:~-4!.%xxx%"
if !i! leq 10005 (
    set /a i=i+1
    goto :start
)
复制代码

作者: Batcher 时间: 2019-7-23 21:12

问题：
刚才已经建立0000.txt ,我又点击了bat批处理，结果新文件覆盖了之前的文件，如果不想让它覆盖掉原文件，又该怎么处理呢

代码：

@echo off
setlocal enabledelayedexpansion
set "i=10000"
:start
if not exist "c:\users\administrator\desktop\!i:~-4!.txt" (
    cd.>"c:\users\administrator\desktop\!i:~-4!.txt"
)
if !i! leq 10005 (
    set /a i=i+1
    goto :start
)
复制代码

作者: impk 时间: 2019-7-25 20:29

本帖最后由 impk 于 2019-7-25 20:45 编辑

问题：
为何我这批处理不能批量新建文件嗯

@echo off
Set i=0000
:start
@cd. >"c:\users\administrator\desktop\%i%.txt"
if /a i<=0005(
i=i+1
got start
)else exit

@echo off
set i=1
:start
@echo test>"%cd%\%i%.txt"
set /a i=%i%+1
if %i% leq 5 (
goto :start
) else goto :eof
复制代码

@echo off
setlocal enabledelayedexpansion
set i=1
:start
cd.>"%cd%\!i!.txt"
set /a i=%i%+1
if !i! leq 5 (
goto :start
) else goto :eof
复制代码

作者: impk 时间: 2019-7-25 20:53

本帖最后由 impk 于 2019-7-25 21:26 编辑

问题：
能帮助添加个选择项吗，输入txt新建txt，输入html 新建html，输入什么扩展名，新建什么扩展名的文件

方案1.bat
@echo off
setlocal enabledelayedexpansion
set "i=10000"
REM 设置文件扩展名
set "xxx=txt"
:start
cd.>"c:\users\administrator\desktop\!i:~-4!.%xxx%"
if !i! leq 10005 (
set /a i=i+1
goto :start
)

@echo off
setlocal enabledelayedexpansion
set i=1
echo=
echo=
REM 设置文件扩展名
set /p 扩展名=    请设置扩展名:
:start
cd.>"%cd%\!i!.%扩展名%"
set /a i=!i!+1
if !i! leq 5 (
goto :start
) else goto :eof
复制代码

@echo off
setlocal enabledelayedexpansion
set i=10000
echo=
echo=
REM 设置文件扩展名
set /p 扩展名=    请设置扩展名:
:start
cd.>"%cd%\!i:~-3!.%扩展名%"
set /a i=!i!+1
if !i! leq 10005 (
goto :start
) else goto :eof
复制代码

欢迎光临批处理之家 (http://www.bathome.net/)