批处理之家 - Powered by Discuz! Board

标题: [文件操作] [分享]批处理移动子目录文件到父目录 [打印本页]

作者: Batcher 时间: 2019-7-22 14:39 标题: [分享]批处理移动子目录文件到父目录

问题：
for /f "tokens=* delims=" %%i in ('dir /b /a-d /s "*.*"') do (move /-y "%%i" "%%~dpi./../")
这个是移动子目录文件到父目录的，但是执行时时，本来父目录的文件也会再往上移一级，那个大咖能帮改下？

代码：

@echo off
for /f "delims=" %%a in ('dir /b /ad') do (
    pushd "%%a"
    for /f "delims=" %%i in ('dir /b /a-d /s "*.*"') do (
        move /-y "%%i" "%%~dpi./../"
    )
    popd
)
复制代码

作者: xtyygyte 时间: 2019-8-27 01:20

怎么顺手删除子文件夹呢？？？

作者: qixiaobin0715 时间: 2019-8-27 09:37

回复 1# Batcher
不是大咖是小虾。
大神把简单的事情忘了，加个判断不就行了：
if not "%%~pi"=="%~p0"

作者: Batcher 时间: 2019-8-27 09:47

回复 3# qixiaobin0715

能否把你的完整代码发出来？我测试一下

作者: qixiaobin0715 时间: 2019-8-27 10:00

见笑了，不知这样行不？在你上面的代码加上
if not "%%~pi"=="%~p0" move /-y "%%i" "%%~dpi./../"

作者: qixiaobin0715 时间: 2019-8-27 10:29

回复 1# Batcher
这里标记和恢复路径，什么作用？

作者: Batcher 时间: 2019-8-27 10:42

回复 5# qixiaobin0715

@echo off
for /f "delims=" %%i in ('dir /b /a-d /s "*.*"') do (
    if not "%%~pi"=="%~p0" (
        move /-y "%%i" "%%~dpi./../"
    )
) 
复制代码

你的意思是if判断加在第一段代码里面是吧，应该是可以的。

作者: qixiaobin0715 时间: 2020-4-30 11:22

将楼上的代码修改一下，实现将当前文件夹中所有子文件夹中的文件全部移动到当前文件夹，并删除空子文件夹。

@echo off
for /f "delims=" %%i in ('dir /b /a-d /s') do (
    if not "%%~pi"=="%~p0" (
        move /-y "%%i" "%~dp0"
    )
) 
for /f "tokens=*" %%a in ('dir /b /ad /s^|sort /r') do (rd "%%a" 2>nul)
pause
复制代码

欢迎光临批处理之家 (http://www.bathome.net/)