Board logo

标题: [文本处理] 【已解决】我用了FOR嵌套怎么才能结束子循环的情况下不影响外边的循环 [打印本页]
作者: miqilaosu    时间: 2019-6-18 15:25     标题: 【已解决】我用了FOR嵌套怎么才能结束子循环的情况下不影响外边的循环

本帖最后由 miqilaosu 于 2019-6-21 09:54 编辑 
  1. @echo off

  2. setlocal enabledelayedexpansion

  3. for /f "delims=" %%i in ('type 1.txt') do (

  4. set n=1

  5. call set "var=%%i"

  6. 	for /l %%a in (1,1,99) do (

  7. 		call set "var1=%%var:~0,!n!%%"

  8. 		call set "var2=%%var:~!n!,!n!%%"

  9. 

  10. 		if !var1!==!var2! (

  11. 			echo,!var1!.

  12. 				::跳出子循环

  13. 		) else (

  14. 			set /a n+=1

  15. 				if !var2!=="" ::if跳出子循环

  16. 			)

  17. 		)

  18. 	)

  19. )

  20. pause
复制代码
是这样的，第一个：：跳出子循环的地方我想直接跳出子循环外边的循环继续，第二个我想做个判断!var2!==""的时候跳出子循环，但是发现不能用GOTO 不然就直接全跳出的，查了半天没找到方法，请问各位大神怎么才能实现
作者: WHY    时间: 2019-6-18 16:49

本帖最后由 WHY 于 2019-6-18 22:29 编辑

批处理 for 循环里面只能 goto 到循环外部，不能在 for 循环内部 goto
这样应该可以：
  1. @echo off

  2. setlocal enabledelayedexpansion

  3. for /f "delims=" %%i in ('type 1.txt') do (

  4.     set "var=%%i"

  5.     for /l %%a in (1,1,99) do (

  6.         set "var1=!var:~0,%%a!"

  7.         set "var2=!var:~%%a!"

  8.         if "!var1!" == "!var2!" (echo;!var1!)

  9.     )

  10. )

  11. pause
复制代码
或者试试 call :标签
  1. @echo off

  2. setlocal enabledelayedexpansion

  3. for /f "delims=" %%i in ('type 1.txt') do (

  4.     call :GetString "%%i"

  5. )

  6. pause & goto :EOF

  7. 

  8. :GetString

  9. set "var=%~1"

  10. for /l %%a in (1,1,99) do (

  11.     set "var1=!var:~0,%%a!"

  12.     set "var2=!var:~%%a!"

  13.     if "!var1!" == "!var2!" (echo;!var1!&goto :EOF)

  14. )
复制代码




欢迎光临 批处理之家 (http://www.bathome.net/) Powered by Discuz! 7.2