批处理之家 - Powered by Discuz! Board

标题: [文件操作] 批处理如何根据文件名规律查找文件并将查找的文件移动到文件夹 [打印本页]

作者: csh522 时间: 2019-4-15 20:48 标题: 批处理如何根据文件名规律查找文件并将查找的文件移动到文件夹

文件名称为：郭书瑶-幸福不远[国语].MKV 和郭穗-丽之星.MKV……
文件名都有-符号，而且有些不止一个，想要把第一个“-”符号前的文字提取出来新建文件夹，并且把含有第一个“-”符号前的文字的文件移动到新建的文件夹
结果是郭书瑶-幸福不远[国语].MKV移动到郭书瑶文件夹，郭穗-丽之星.MKV移动到郭穗文件夹

作者: zaqmlp 时间: 2019-4-15 21:17

@echo off
set info=互助互利,支付宝扫码头像,感谢赞助
rem 有问题,可加QQ956535081及时沟通
title %info%
start mshta VBScript:Execute("msgbox(""%info%""):close")
cd /d "%~dp0"
for /f "delims=" %%a in ('dir /a-d/b *-*^|find /v "%~nx0"') do (
    for /f "tokens=1* delims=-" %%b in ("%%~na") do (
        if not exist ".\%%b\" md ".\%%b\"
        echo;"%%a" --^> ".\%%b\"
        move "%%a" ".\%%b\"
    )
)
pause
复制代码

作者: ivor 时间: 2019-4-15 21:27

powershell "dir *.mkv | %{md $_.Name.Split('-')[0];$_.MoveTo($_.Name.Split('-')[0]+'\'+$_.Name)}"
复制代码

作者: Batcher 时间: 2019-4-15 21:45

@echo off
cd /d "%~dp0"
for /f "delims=" %%a in ('dir /a-d /b *-*.mkv ^| find /v "%~nx0"') do (
    for /f "delims=-" %%b in ("%%a") do (
        md "%%b" 2>nul
        move /y "%%a" "%%b"
    )
)
复制代码

欢迎光临批处理之家 (http://www.bathome.net/)