批处理之家 - Powered by Discuz! Board

标题: [文件操作] 批处理全盘搜索指定文件获取其完整路径 [打印本页]

作者: smss 时间: 2019-4-9 13:47 标题: 批处理全盘搜索指定文件获取其完整路径

引用自管理大神Batcher

@echo off
rem 指定待搜索的文件
set "FileName=BatHome_Batcher.txt"
echo 正在搜索，请稍候...
for %%a in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
    if exist %%a:\ (
        pushd %%a:\
        for /r %%b in (*%FileName%) do (
            if /i "%%~nxb" equ "%FileName%" (
                echo,%%b
))))
pause
复制代码

例如在C盘中找到了BatHome_Batcher.txt 无论其它盘有没有都不继续寻找搜到就停止并把找到的路径传递给变量待用应该怎样写想提高效率

作者: yhcfsr 时间: 2019-4-9 16:41

@echo off
for /f "tokens=2 delims==" %%a in ('wmic datafile where "FileName='BatHome_Batcher' and extension='txt'" get Caption /value') do set "filepath=%%a"
echo;%filepath%
复制代码

作者: Batcher 时间: 2019-4-9 17:00

第10行下面 goto 一下

作者: ivor 时间: 2019-4-9 20:54

需要

cli.c
es.exe
Everything.exe
Everything.lng

es.exe BatHome_Batcher.txt
复制代码

作者: smss 时间: 2019-4-9 21:28

本帖最后由 smss 于 2019-4-9 21:40 编辑

第10行下面 goto 一下
Batcher 发表于 2019-4-9 17:00

@echo off
if not exist *.kux (echo 逗我呢,木有kux文件！！！&ping 0 -n "2">nul&exit) else echo 搜索ffmpeg.exe
set "FileName=ffmpeg.exe"&echo 正在搜索，请稍候...
for %%a in (D C E F G H I J K L M N O P Q R S T U V W X Y Z) do (if exist %%a:\ (pushd %%a:\
for /r %%b in (*%FileName%) do (if /i "%%~nxb" equ "%FileName%" (echo,%%b
set ffmpeg=%%b
goto 优酷视频kux格式转换MP4
))))
:优酷视频kux格式转换MP4
if exist %ffmpeg% (for /r . %%i in (*.kux) do (%ffmpeg% -y -i "%%i" -c:a copy -c:v copy -threads 2 "%%~dpni.mp4"&&del /s /q *.kux)) else echo 请检查优酷客户端ffmpeg路径！&ping 0 -n "2">nul&exit
复制代码

可把1080P会员视频转换成MP4

作者: yhcfsr 时间: 2019-4-9 23:05

回复 2# yhcfsr

如果存在电脑中存在多个同名文件,可以采用伪数组的方法

@echo off
for /f "tokens=2 delims==" %%a in ('wmic datafile where "FileName='BatHome_Batcher' and extension='txt'" get Caption /value') do (
	set/a n+=1
	call,set "files[%%n%%]=%%a"
)
	
for /f "tokens=2 delims==" %%a in ('set files[') do echo;%%a
pause
复制代码

欢迎光临批处理之家 (http://www.bathome.net/)