批处理之家 - Powered by Discuz! Board

标题: [数值计算] [已解决]批处理set /a计算的结果为什么不对 [打印本页]

作者: Tall 时间: 2019-4-8 17:20 标题: [已解决]批处理set /a计算的结果为什么不对

求助批处理为什么num1num2num3的值计算不了var的值

@echo on&setlocal enabledelayedexpansion
for /l %%i in (100 1 999) do (
	set /a num1=%%i/100
	set /a num2=%%i/10%%10
	set /a num3=%%i%%10
	set /a var=!num1!*!num1!*!num1!+!num2!*!num2!*!num2!+!num3!*!num3!*!num3!
	if !var! equ %%i  echo %%i
	
)
pause
复制代码

作者: zaqmlp 时间: 2019-4-8 18:03

你各位取得的值对吗？bat求水仙花数可以直接截取各位

set n=%%i
set /a a=!n:~,1!,b=!n:~1,1!,c=!n:~-1!
复制代码

作者: Batcher 时间: 2019-4-9 09:39

代码语法没有问题，可能是你的算法不对，在这个算法之下!var!和%%i这两个变量的值不会出现相等的情况。自己验证一下就知道啦：

@echo off
setlocal enabledelayedexpansion
for /l %%i in (100 1 999) do (
    set /a num1=%%i/100
    set /a num2=%%i/10%%10
    set /a num3=%%i/10
    set /a var=!num1!*!num1!*!num1!+!num2!*!num2!*!num2!+!num3!*!num3!*!num3!
    echo 调试信息 i=%%i, var=!var!, num1=!num1!, num2=!num2!, num3=!num3!
    if !var! equ %%i  echo %%i
    pause
)
复制代码

作者: Tall 时间: 2019-4-9 10:06

回复 3# Batcher
我改成这个后set /a num3=%%i%%10现在可以计算出！var！的值但是传不到if语句里！var！这是怎么回事

作者: Batcher 时间: 2019-4-9 10:16

回复 4# Tall

我这边测试没有问题，你是不是哪里敲错代码了

@echo off
setlocal enabledelayedexpansion
for /l %%i in (100 1 999) do (
    set /a num1=%%i/100
    set /a num2=%%i/10%%10
    set /a num3=%%i%%10
    set /a var=!num1!*!num1!*!num1!+!num2!*!num2!*!num2!+!num3!*!num3!*!num3!
    REM echo 调试信息 i=%%i, var=!var!, num1=!num1!, num2=!num2!, num3=!num3!
    if !var! equ %%i (
        echo 调试信息 i=%%i, var=!var!
        echo %%i
    )
)
pause
复制代码

作者: Feng2008 时间: 2019-4-10 16:43

应该是if语句问题，试下将if中的echo语句用括号括上，运行后显示153，370，371，407

欢迎光临批处理之家 (http://www.bathome.net/)