批处理之家 - Powered by Discuz! Board

标题: [网络连接] 批处理怎样设置本机DNS？ [打印本页]

作者: hotdog00 时间: 2019-3-19 15:25 标题: 批处理怎样设置本机DNS？

请教大家一个问题，折腾了几天，实在是搞不出来了，希望能帮帮我。谢谢！
分别测试两段代码，一段选择1个DNS，和将固定值设置了DNS，两段分别测试没有问题，但合在一起就报错。
第一段：

@echo off
for /f "tokens=1* delims=:" %%i in (
'findstr/rvxc:" *" "1.txt"^|findstr/n .')do set "#%%i=%%j"&set/a n+=1
set/a "s=%random%%%n+1"
call set s=%%#%s%%%
echo %s%
pause
复制代码

第二段：

@echo off
set dns1=8.8.8.8
set dns2=8.8.6.6
cmd /c netsh interface ip set dns name="本地连接" source=static addr=%dns1% register=PRIMARY validate=no
cmd /c netsh interface ip add dns name="本地连接" addr=%dns2% validate=no
pause
复制代码

合在一起：

@echo off
for /f "tokens=1* delims=:" %%i in (
'findstr/rvxc:" *" "1.txt"^|findstr/n .')do set "#%%i=%%j"&set/a n+=1
set/a "dns1=%random%%%n+1"
call set dns1=%%#%dns1%%%

for /f "tokens=1* delims=:" %%i in (
'findstr/rvxc:" *" "1.txt"^|findstr/n .')do set "#%%i=%%j"&set/a n+=1
set/a "dns2=%random%%%n+1"
call set dns2=%%#%dns2%%% 

cmd /c netsh interface ip set dns name="本地连接" source=static addr=%dns1% register=PRIMARY validate=no
cmd /c netsh interface ip add dns name="本地连接" addr=%dns2% validate=no

pause
复制代码

合在一起就报错
FINDSTR: 无法打开 1.txt
以零为除数的错误。
FINDSTR: 无法打开 1.txt
以零为除数的错误。
参数错误。
参数错误。
请按任意键继续. . .

作者: zaqmlp 时间: 2019-3-19 17:36

@echo off
title 互助互利,扫码头像,感谢赞助;有问题,加QQ956535081及时沟通
cd /d "%~dp0"
set "txtfile=1.txt"
for /f "tokens=1* delims=:" %%i in ('type "%txtfile%"^|findstr /rvxc:" *"^|findstr /n .') do (set "_#%%i=%%j"&set n=%%i)
set /a d1=%random% %% n +1
set /a d2=%random% %% n +1
call set dns1=%%_#%d1%%%
call set dns2=%%_#%d2%%%
echo;dns1=%dns1%          dns2=%dns2%
netsh interface ip set dns name="本地连接" source=static addr=%dns1% register=PRIMARY validate=no
netsh interface ip add dns name="本地连接" addr=%dns2% validate=no
pause
复制代码

作者: hotdog00 时间: 2019-3-19 18:08

回复 2# zaqmlp

谢谢大师！

作者: zaqmlp 时间: 2019-3-19 20:30

回复 3# hotdog00
赞助才有动力

欢迎光临批处理之家 (http://www.bathome.net/)