@echo off
powershell -command "$aExcludes=@('c:\windows','d:\办公保存','e:\档案保存');[System.IO.DriveInfo]::GetDrives()|ForEach-Object{Get-ChildItem -LiteralPath $_.Name -Filter *.* -Directory|Where-Object{$_.FullName -notin $aExcludes}|ForEach-Object{Remove-Item -LiteralPath $_ -Filter *.* -Include *.xls,*.doc,*.jpg -Recurse  -WhatIf}}"
复制代码

    谢谢您不厌其烦的帮助我！！谢谢您！
我水平有限，是因为工作中需要，而且是想以批处理文件形式交给同事们去运行完成需求。
将您的代码保存为“指定删除.bat”，运行报错。
有个帖子也曾简介了一下powershell与BAT混用的事儿，但我搞不来。
我就想请您继续帮助我搞成一键点击执行的一个东东（bat），否则，同事们拿到手也搞不来的。
拜托了！
报错——
C:\Users\Administrator.AFOHQ-712210916\Desktop\指定删除>指定删除.bat
必须在“-”运算符的右侧提供值表达式。
所在位置 行:1 字符: 182
+ $aExcludes=@('c:\windows','d:\办公保存','e:\档案保存');[System.IO.DriveInfo]:
:GetDrives()|ForEach-Object{Get-ChildItem -LiteralPath $_.Name -Filter *.* -Dir
ectory|Where-Object{$_.FullName - <<<< notin $aExcludes}|ForEach-Object{Remove-
Item -LiteralPath $_ -Filter *.* -Include *.xlsx,*.doc,*.jpg,*.bmp -Recurse  -W
hatIf}}
    + CategoryInfo          : ParserError: ( [], ParentContainsErrorRecordEx
   ception
    + FullyQualifiedErrorId : ExpectedValueExpression

   

@echo off
setlocal EnableDelayedExpansion
REM 设置要排除的目录列表,用双引号包括,以空格分割.
set dirsExclude="c:\windows" "d:\办公保存" "e:\档案保存" 
REM 要删除的文件扩展名列表,用双引号包括,以空格分割.
set exts="*.xls" "*.doc" "*.jpg"
echo 全盘搜索中,请稍候...
for /f "tokens=1*" %%A in ('fsutil fsinfo drives') do (
  for %%D in (%%B) do (
    pushd "%%D"
    for /f "delims=" %%E in ('dir /ad-h-s /b') do (
      set flag=1
      for %%F in (%dirsExclude%) do (
        if /i "%%~fE"==%%F set flag=0
      )
        if !flag!==1 (
          for /f "delims=" %%G in ('where /r "%%~fE" /f %exts% 2^>nul') do (
            REM 若要真正删除文件，请去掉下面这行的 "echo"
            echo del /f /q %%G
          )
        )
      )
    popd
    )
  )
)
endlocal
pause
exit /b
复制代码

我简单测试了一下 七楼的代码，您的这个BAT完全按照我的需要能列出需要的文件出来。

——那么，我现在想继续按您的思路，修改为：将列出的路径及文件名保存到一个TXT文件去，如保存到：d:\DEL_list.txt

@echo off
setlocal EnableDelayedExpansion
REM 设置要排除的目录列表,用双引号包括,以空格分割.
set dirsExclude="c:\windows" "d:\办公保存" "e:\档案保存" 
REM 要删除的文件扩展名列表,用双引号包括,以空格分割.
set exts="*.xls" "*.doc" "*.jpg"
REM 设置保存文件路径
set outFile="d:\DEL_list.txt"
echo 全盘搜索中,请稍候...
(
  for /f "tokens=1*" %%A in ('fsutil fsinfo drives') do (
    for %%D in (%%B) do (
      pushd "%%D"
      for /f "delims=" %%E in ('dir /ad-h-s /b') do (
        set flag=1
        for %%F in (%dirsExclude%) do (
          if /i "%%~fE"==%%F set flag=0
        )
          if !flag!==1 (
            for /f "delims=" %%G in ('where /r "%%~fE" /f %exts% 2^>nul') do (
              echo %%G
            )
          )
        )
      popd
      )
    )
  )
)>%outFile%
endlocal
pause
exit /b
复制代码

@echo off
setlocal EnableDelayedExpansion
REM 设置要排除的目录列表,用双引号包括,以空格分割.
set dirsExclude="c:\windows" "d:\办公保存" "e:\档案保存"
REM 要删除的文件扩展名列表,用双引号包括,以空格分割.
set exts="*.xls" "*.doc" "*.jpg"
REM 设置保存文件路径
set outFile="d:\DEL_list.txt"
echo 全盘搜索中,请稍候...
(
  for /f "tokens=1*" %%A in ('fsutil fsinfo drives') do (
    for %%D in (%%B) do (
      pushd "%%D"
      for /f "delims=" %%E in ('dir /ad-h-s /b') do (
        set flag=1
        for %%F in (%dirsExclude%) do (
          if /i "%%~fE"==%%F set flag=0
        )
          if !flag!==1 (
            for /f "delims=" %%G in ('where /r "%%~fE" /f %exts% 2^>nul') do (
              echo %%G
            )
          )
        )
      popd
      )
    )
)>%outFile%
endlocal
pause
exit /b
复制代码