批处理之家 - Powered by Discuz! Board

标题: [文件操作] 批处理怎样遍历一级目录下所有二级目录内的照片数量？ [打印本页]

作者: redstonesing 时间: 2019-1-7 11:14 标题: 批处理怎样遍历一级目录下所有二级目录内的照片数量？

如下图：
一级目录如下

二级目录如下

三级目录如下

实现目标：
遍历一级目录下所有二级目录内的照片数量（JPG,PNG），数量与二级目录的文件夹命名一一对应。并生成excel或者txt
如下表

找遍了百度，在批处理之家看到了有类似的，让我看到了希望，感谢感谢！

作者: ivor 时间: 2019-1-7 12:20

本帖最后由 ivor 于 2019-1-7 13:15 编辑

论坛经费紧张，图片以后改成外连的吧

dir 2 -Include *.jpg, *.png -Recurse | Group-Object Directory  | % {-Join ($_.Name,"," ,$_.count)} | Out-File result.txt
复制代码

作者: yhcfsr 时间: 2019-1-7 12:22

@echo off

::设置父目录
set "SrcDir=%~dp0"
::设置输入文件
set "output=result.txt"

::自检
if not exist "%SrcDir%" echo;目录不存在: "%SrcDir%"&pause&exit
cd/d "%SrcDir%"

::遍历一级目录
>"%output%" (
echo;图符编号	图片数量
for /d %%a in (*) do (
	pushd "%%a"
	::遍历二级目录
	for /d %%b in (*) do (
		set "n="
		pushd "%%b"
		for /f "delims=" %%c in ('dir /a-d/b *.jpg') do set/a "n+=1"
		setlocal enabledelayedexpansion
		echo;%%b	!n!
		endlocal
		popd
	)
	popd
))
pause
复制代码

作者: Batcher 时间: 2019-1-7 13:10

代码保存为 test.bat 放在一级目录下运行

@echo off
setlocal enabledelayedexpansion
>"目的.csv" echo 图符编号,图片数量
(for /d %%a in (*) do (
    pushd "%%a"
    for /d %%b in (*) do (
        set n=0
        pushd "%%b"
        for /f "delims=" %%c in ('dir /a-d /b /s *.jpg *.png') do (
            set /a n+=1
        )
        echo %%b,!n!
        popd
    )
    popd
))>>"目的.csv"
复制代码

作者: lifei259 时间: 2019-1-7 18:55

@echo off
setlocal enabledelayedexpansion
>"目的.csv" echo 图符编号,图片数量
( for /d %%a in (*) do (
       set n=0
       pushd "%%a"
       for /f "delims=" %%c in ('dir /a-d /b /s *.jpg *.png') do (
              set /a n+=1
       )
  echo %%a,!n!
  popd
  ))>>"目的.csv"
pause
复制代码

欢迎光临批处理之家 (http://www.bathome.net/)