批处理之家 - Powered by Discuz! Board

标题: [文件操作] 如何把批处理执行的过程信息保存在日志里？ [打印本页]

作者: hkstudio 时间: 2009-7-5 10:45 标题: 如何把批处理执行的过程信息保存在日志里？

如何把批处理执行的过程信息保存在日志里？

附上批处理内容：

@echo off
echo 正在清除系统垃圾文件，请稍等......
del /f /s /q %systemdrive%\*.tmp
del /f /s /q %systemdrive%\*._mp
del /f /s /q %systemdrive%\*.gid
del /f /s /q %systemdrive%\*.chk
del /f /s /q %systemdrive%\*.old
del /f /s /q %systemdrive%\recycled\*.*
del /f /s /q %windir%\*.bak
del /f /s /q %windir%\prefetch\*.*
rd /s /q %windir%\temp & md %windir%\temp
del /f /q %userprofile%\recent\*.*
del /f /s /q "%userprofile%\Local Settings\Temporary Internet Files\*.*"
del /f /s /q "%userprofile%\Local Settings\Temp\*.*"
del /f /s /q "%userprofile%\recent\*.*"
echo 清除系统完成!!!
echo. & pause
复制代码

作者: defanive 时间: 2009-7-5 11:23

del /f /s /q %systemdrive%\*.tmp>a.txt
代表把这行批处理的信息保存到a.txt中

PS：这个P对系统有些许影响，不建议使用

作者: hkstudio 时间: 2009-7-5 12:47

这个在网上找，能否优化下？

作者: yslyxqysl 时间: 2009-7-5 12:48

@call :output>clean.log
exit
:output
@echo off
......
复制代码

[ 本帖最后由 yslyxqysl 于 2009-7-5 12:52 编辑 ]

作者: yslyxqysl 时间: 2009-7-5 12:50

http://user.qzone.qq.com/276902008/blog/1216130288

作者: hkstudio 时间: 2009-7-5 13:25

谢谢 yslyxqysl

作者: keen 时间: 2009-7-5 14:38 标题: 回复 1楼的帖子

这样试试：

@echo off
(
echo 正在清除系统垃圾文件，请稍等......
del /f /s /q %systemdrive%\*.tmp
del /f /s /q %systemdrive%\*._mp
del /f /s /q %systemdrive%\*.gid
del /f /s /q %systemdrive%\*.chk
del /f /s /q %systemdrive%\*.old
del /f /s /q %systemdrive%\recycled\*.*
del /f /s /q %windir%\*.bak
del /f /s /q %windir%\prefetch\*.*
rd /s /q %windir%\temp & md %windir%\temp
del /f /q %userprofile%\recent\*.*
del /f /s /q "%userprofile%\Local Settings\Temporary Internet Files\*.*"
del /f /s /q "%userprofile%\Local Settings\Temp\*.*"
del /f /s /q "%userprofile%\recent\*.*"
echo 清除系统完成!!!
echo. & pause
)>log.txt 2>&1<nul
echo 保存完成，请查看日志文件log.txt。
pause
复制代码

作者: tireless 时间: 2009-7-5 15:19

@echo off
echo 正在清除系统垃圾文件，请稍等......
cd/d "%windir%\temp" 2>nul && rd /s/q . 2>nul & cd /d %systemdrive%\ || exit/b
del /a/f/s/q *.tmp *._mp *.gid *.chk *.old recycled\ "%windir%\*.bak" "%windir%\prefetch\" "%userprofile%\Local Settings\Temporary Internet Files\" "%userprofile%\Local Settings\Temp\" "%userprofile%\recent\" > "%~dp0log.tx"
echo 清除系统完成!!!
echo. & pause
复制代码

[ 本帖最后由 tireless 于 2009-7-5 15:48 编辑 ]

作者: yinsigan 时间: 2009-7-5 23:54

请问:二楼和四楼的谁好呢?

作者: defanive 时间: 2009-7-6 00:03

效果一样，四楼的方便

作者: yinsigan 时间: 2009-7-6 00:05

我觉得四楼错了那个> 应为>>吧

作者: keen 时间: 2009-7-6 10:09 标题: 回复 11楼的帖子

怎么不试试我的7楼的代码，我的代码，不光把删除的文件写进日志，还有把没有删除的文件也写进了日志。
其他人的代码，只有把删除掉的文件记录在日志中。而没有记录错误信息。
自己夸自己^_^

作者: yinsigan 时间: 2009-7-6 12:15

七楼:

请问

>log.txt 2>&1<nul
这一行是什么意思,我不懂,你能解释一下吗?

作者: keen 时间: 2009-7-6 12:22 标题: 回复 13楼的帖子

这是重定向，你可以参考这个：
http://www.bathome.net/viewthrea ... =%D6%D8%B6%A8%CF%F2

欢迎光临批处理之家 (http://www.bathome.net/)