批处理之家 - Powered by Discuz! Board

标题: [文件操作] 求助批处理解压文件后去除中间多层文件夹 [打印本页]

作者: ymica 时间: 2018-9-22 17:43 标题: 求助批处理解压文件后去除中间多层文件夹

使用软件批量解压：每个文件到单独的文件夹后→有的文件夹是压缩文件名/压缩文件名/压缩文件名/需要的文件，有的直接是很方便的压缩文件名/需要的文件。
就是想要去除中间多余文件夹，当文件夹内只有一个文件夹时候获取更底层文件，当文件夹内有其它情况比如多个文件夹或者文件就把这些需要文件移动到第一层文件夹下并删除中间文件夹，就是压缩文件名/需要的文件这样的形式，发现会经常遇到多余文件夹却不知道如何入手。

作者: Batcher 时间: 2018-9-22 22:00

@echo off
for %%i in (*.rar) do (
    if not exist "%%~ni\" (
        md "%%~ni"
        move "%%i" "%%~ni\"
        pushd "%%~ni"
        "C:\Program Files\WinRAR\rar.exe" e "%%i"
        popd
    )
)
复制代码

作者: ymica 时间: 2018-9-24 01:50

回复 1# ymica

很抱歉这么晚才回复，很感谢花时间，测试了下如果是rar完全能解决我的问题非常好。但我想的是已经解压出来的文件夹/文件夹/文件这样的格式，去除中间多余层(思考)。

作者: flashercs 时间: 2018-9-24 02:20

回复 3# ymica

都移动到根目录下可能出现同名文件覆盖

作者: ymica 时间: 2018-9-24 02:51

回复 4# flashercs

大致就是这样的意思，我也在找网上类似的，bat文件放在一个目录下，对这个目录下所有文件夹内的内容缩减，用于批量处理解压后的无用文件夹。就是仅把 AAA\AAA\AAA\AAA\BB\1.txt变成AAA\BB\1.txt 的格式

作者: flashercs 时间: 2018-9-24 22:22

回复 5# ymica

@echo off
set "dir=%~1"
if not defined dir set "dir=%~dp0"
call :recurse "%dir%" 0 "%dir%"
pause
exit /b
:recurse
setlocal
pushd %1||goto end
set /a "childlevel=%2+1"
for /f "delims=" %%A in ('"2>nul,dir /ad /b"') do (
	call :recurse "%%A" %childlevel% %3
	rd /q "%%A"||echo "%%~fA"
)
if %2 leq 1 goto out
set "destDir=%~3\%~1"
if exist "%destDir%" (
	for /f "delims=" %%B in ('"2>nul,dir /a-d /b"') do (
		call :rf "%%B" "%destDir%"
	)
) else (
	md "%destDir%"
	move /y * "%destDir%\"
)
:out
popd
:end
endlocal
exit /b
:rf
set "fname=%~n1"
set "fext=%~x1"
set /a "cnt=1"
:loop
if exist "%~2\%fname%%fext%" (
	set "fname=%~n1_%cnt%"
	set /a "cnt+=1"
	goto loop
) else (
	move %1 "%~2\%fname%%fext%"
)
exit /b
复制代码

保留一级子目录.bat
子目录下的文件都提取到根目录下。
例如文件夹"E:\A"是根目录：可以将批处理放到“E:\A”下运行或者给批处理传递参数保留一级子目录.bat “E:\A”

作者: ymica 时间: 2018-9-26 22:43

回复 6# flashercs

感谢写了这么多，基本上差不多了。这段假如我在子文件夹新建一个文件夹，运行后新建文件夹也会被移动到根目录，我实际想要的是缩减中间重复文件夹

欢迎光临批处理之家 (http://www.bathome.net/)