批处理之家 - Powered by Discuz! Board

标题: 一个“灵异”批处理引发的思考加补充说明 [打印本页]

作者: lxzzr 时间: 2009-6-4 13:25 标题: 一个“灵异”批处理引发的思考加补充说明

本文来自: 脚本之家(www.jb51.net) 详细出处参考：http://www.jb51.net/article/14350.htm

批处理的要求是：
随机显示的数字为（6，7，8，9，10，11，12，14，15，16，17）为其中的一个
注：里面没有13的

下面的两个代码，第一个出错，第二个却成功了，但他们的区别只是第一个(%random%)%%(%n%)+1运算后的值赋予%tn%，而第二个则将运算后的值继续赋予%n%……

@echo off 
set "string=6 7 8 9 10 11 12 14 15 16 17" 
for %%i in (%string%) do call set /a "n=%%n%%+1" 
set /a "tn=(%random%)%%(%n%)+1" 
for /f "usebackq tokens=%tn% delims= " %%i in ('%string%') do echo %%i 
pause 
goto :EOF 
复制代码

@echo off 
set "string=6 7 8 9 10 11 12 14 15 16 17" 
for %%i in (%string%) do call set /a "n=%%n%%+1" 
set /a "n=(%random%)%%(%n%)+1" 
for /f "usebackq tokens=%n% delims= " %%i in ('%string%') do echo %%i 
pause 
goto :EOF 
复制代码

发现set /a "tn=(%random%)%%(%n%)+1"这个语句里面被赋值的变量名称只能是一个字符的，多于一个字符也会出错（测试过，和for无关），但如果把赋值表达式两边的引号也去掉，则不会出现这个错误！

for %%i in (%string%) do call set /a "n=%%n%%+1"
这个语句让偶理解了好半天：
我们知道批处理在运行过程中，在读取每条语句/执行每个命令都会扩充一次语句/命令里的变量。
我们来看看这个例子发生了什么事情：
在读取for语句时，%%n%%被扩充为%n%，即do的是call set /a "n=%n%+1"。
此时我们也许会认为直接set /a "n=%n%+1"不就行了吗，call是多此一举。
但是，实际上在这个例子里，如果省略call，set命令会出错，提示“找不到操作数。”
为什么呢？因为读取for时已经扩充过一次，所以for语句会剥夺do后第一个命令扩充变量的权力。
所以，省略call后，set不再扩充%n%，认为%n%不是数字，所以出错了。
经过call之后，set命令再次扩充%n%，即使%n%未赋值也能被扩充为空，此时就可以进行set运算了。
即call并没有扩充变量，只是起到了把set命令与for语句隔开的作用，让set不被for剥夺扩充变量的权力。
当然，你认为是call扩充的也可以，效果一样，虽然实际过程不相同。
当%%i=6时，%n%被扩充为空，set把n赋值为1
当%%i=7时，%n%被扩充为1，set把n赋值为2
当%%i=8时，%n%被扩充为2，set把n赋值为3
以此类推。
举例理解：
set n=123
for %%i in (1) do echo %%n%%
pause
在运行这个批处理的时候，我们看到的是for %i in (1) do echo %n%
即是说，读取for语句的时候，%%n%%已经被扩充为%n%
如果echo还具有扩充变量的权力，echo %n%应该显示%n%的真实值123
实际上，echo原原本本的显示“%n%”
说明，for把echo扩充变量的权力剥夺了。
当然，您平时一定是直接for %%i in (1) do echo %n%
但是，这个“灵异”批处理是想引用一个不被for扩充的变量，而又想在do里能够得到扩充，也就是说想达到延迟环境变量的效果。目的就是使用一个递增变量统计%string%包含了多少个字符。

作者: 随风 时间: 2009-6-4 13:48

谁说不是for的语句的问题，
:

@echo off
set "string=6 7 8 9 10 11 12 14 15 16 17" 
for /f "usebackq tokens=12 delims= " %%i in ('%string%') do echo %%i 
pause
复制代码

[ 本帖最后由随风于 2009-6-4 14:15 编辑 ]

作者: 随风 时间: 2009-6-4 14:23

@echo off 
set "string=6 7 8 9 10 11 12 14 15 16 17" 
::发现问题竟然是出在这一句，不要引号一切正常，或不用usebacdq语句，
::则加不加引号都正常，cmd的机制真是令人费解～
for %%i in (%string%) do call set /a "n=%%n%%+1"
for /f "usebackq tokens=5 delims= " %%i in ('%string%') do echo %%i 
pause 
goto :EOF 
复制代码

作者: inittab 时间: 2009-6-4 14:31

可能原作者对set /a 语句不是很了解。走了很多弯路。简单的东西想复杂了。
set /a 是数值运算，可以直接使用变量。顶楼可改为:

@echo off 
set "string=6 7 8 9 10 11 12 14 15 16 17" 
for %%i in (%string%) do set/a n+=1
set /a tn=%random%%%n+1 
for /f "tokens=%tn% delims= " %%i in ("%string%") do echo %%i 
pause 
goto :EOF 
复制代码

[ 本帖最后由 inittab 于 2009-6-4 14:32 编辑 ]

作者: lxzzr 时间: 2009-6-4 14:45

呵呵，FOR 的处理机制......

作者: lxzzr 时间: 2009-6-4 15:20

又如：

@echo off
for /f "usebackq tokens=15 delims= " %%i in (`"ipconfig /all | FIND /I "address""`) do echo %%i
pause

for /f "tokens=15 delims= " %%i in ('ipconfig /all ^| FIND /I "address"') do echo %%i
pause
复制代码

作者: zqz0012005 时间: 2009-6-4 18:35

set n=3
set /a "tn=(%random%)%%(%n%)+1"
echo %tn%
没问题啊。

for /f 使用 usebackq 会改变一些符号的的作用：
'：界定字符串
"：引用文件名
`：包含命令行
用'界定字符串时，如果字符串中有空格，会导致一些问题，可能是语法上的原因。
类似的帖子：http://www.bathome.net/viewthread.php?tid=3614

for /f "usebackq" %%a in ('C:\boot.ini') do echo %%a
for /f "usebackq" %%a in ('C:\boot.ini 1') do echo %%a
for /f %%a in ("C:\boot.ini 1") do echo %%a
pause
复制代码

不使用usebackq，用双引号界定字符串时，因为双引号本身有特殊作用，会将其中的特殊字符转义掉。

作者: zqz0012005 时间: 2009-6-4 18:44

至于call set /a "n=%%n%%+1"这个语句，这样的用法实在太平常了。
lxzzr兄以前没有接触过call变量延迟的用法吗？

作者: Batcher 时间: 2009-6-4 19:58 标题: 回复 8楼的帖子

楼主只是转帖，可能是原文作者“理解了好半天”，而不是楼主^_^

作者: zqz0012005 时间: 2009-6-4 20:09

哦~~被标题误导了，“引发的思考加补充说明”。。。

另外，建议lxzzr兄不要再从脚本之家转载文章，它几乎（完全？）没有自己的原创。而且它会篡改某些内容，引用时最好用文章中的某些关键字google一下原始出处。

[ 本帖最后由 zqz0012005 于 2009-6-4 20:10 编辑 ]

作者: wxcute 时间: 2009-6-4 20:25 标题: 简单问题复杂化了。

简化

@echo off
set "string=6 7 8 9 10 11 12 14 15 16 17"
for %%i in (%string%) do set /a n+=1
set /a "tn=(%random%)%%(%n%)+1"
for /f "usebackq tokens=%tn% delims= " %%i in ('%string%') do echo %%i
pause
goto :EOF
复制代码

再简化

@echo off
set "string=6 7 8 9 10 11 12 14 15 16 17"
for %%i in (%string%) do set/a n+=1
set/a tn=%random%%%n+1
for /f "tokens=%tn%" %%i in ("%string%") do echo %%i
pause
goto :EOF
复制代码

作者: netbenton 时间: 2009-6-4 20:42

开起变量延迟后，批处理的变量会让人晕头！
但这其中的奥秒是其它语言不能比的，呵呵。。
setlocal enabledelayedexpansion
set aa=1
set bb=2
set tt.bb=aa
set cc=bb
set /a num=!tt.%cc%!+1
这时num的值会是什么呢？

作者: wjjy 时间: 2009-6-7 02:55 标题: 回复 12楼的帖子

嘿嘿～～！2不～～～：）

作者: qzwqzw 时间: 2009-6-14 11:08

首先
usebackq存在bug这是已公开的秘密
尽量少用是第一原则
不得不用时只用"文件名"的形式
'字符串' 和 `命令串` 的形式坚决不用！
否则你的麻烦还会很多

其次
楼上的代码仍然没有足够小心
明知道%string%含有空格
仍然把它至于没有双引号保护的危险境地
不出问题才怪
就事论事修改后的代码

for /f "usebackq tokens=%tn% delims= " %%i in ('" %string% "') do echo %%i 
复制代码

至于%string%两边为什么加空格
有心的自己琢磨一下就明白了

再三
复杂问题简单化是永恒的主题
楼上代码的绕了那么多圈子
难怪让人费解
同样的命题解答再简化

@echo off
:RndLoop
set /a num=%random% %% 12 + 6
if %num%0 equ 130 goto :RndLoop
echo.%num%
pause
复制代码

[ 本帖最后由 qzwqzw 于 2009-6-14 11:15 编辑 ]

欢迎光临批处理之家 (http://www.bathome.net/)