批处理之家 - Powered by Discuz! Board

:敌方移动开始_BFS
Set BFS 1>var/BFS.env
for /f "tokens=1 delims==" %%i in (var/BFS.env) do (
Set "%%~i="
)
Rem 初始化方向顺序
Set "BFSMoveX=+0-1+0+1" || REM 上左下右
Set "BFSMoveY=-1+0+1+0"
Rem 初始化起始顶点
if %SelectX% lss 10 (
Set "BFS_Queue_X=+%SelectX%"
) else (
Set "BFS_Queue_X=%SelectX%"
)
if %SelectY% lss 10 (
Set "BFS_Queue_Y=+%SelectY%"
) else (
Set "BFS_Queue_Y=%SelectY%"
)
Set /a BFS_Queue_Length=1
Set BFS_Dist_%SelectX%_%SelectY%=t
Set "BFS_StackPath_X="
Set "BFS_StackPath_Y="
Set BFS_Next_Path_X=!最近单位X!
Set BFS_Next_Path_Y=!最近单位Y!
(
:BFS_Main
if !BFS_X!==!最近单位X! (
if !BFS_Y!==!最近单位Y! (
if /i "!QuickBFS!"=="Enable" (
Goto :BFS_Finish
)
)
)
if !BFS_Queue_Length! equ 0 (
Goto :BFS_Finish
)
Set /a BFS_X=!BFS_Queue_X:~0,2!|| Rem 取出队列
Set /a BFS_Y=!BFS_Queue_Y:~0,2!
Set "BFS_Queue_X=!BFS_Queue_X:~2!"
Set "BFS_Queue_Y=!BFS_Queue_Y:~2!"
Set /a BFS_Queue_Length-=1
for /l %%b in (0,2,6) do (
Set /a BFS_Next_X=!BFS_X!!BFSMoveX:~%%b,2!
Set /a BFS_Next_Y=!BFS_Y!!BFSMoveY:~%%b,2!
Set "IsWalk=True"
if !BFS_Next_X! GEQ 0 (
if !BFS_Next_Y! GEQ 0 (
if !BFS_Next_X! Lss 15 (
if !BFS_Next_Y! Lss 11 (
for %%c in (%无法通行的方块ID%) do (
for /f "delims=, tokens=1-2" %%d in ("!BFS_Next_X!,!BFS_Next_Y!") do (
if "!MapList_%%d_%%e!"=="%%c" (
Set "IsWalk=False"
)
)
)
if defined Player_!BFS_Next_X!_!BFS_Next_Y! (
Set "IsWalk=False"
)
if "!BFS_Next_X!"=="!NamePlayer_%敌方EnityId%_X!" (
if "!BFS_Next_Y!"=="!NamePlayer_%敌方EnityId%_Y!" (
Set "IsWalk=True"
)
)
if "!BFS_Next_X!"=="!最近单位X!" (
if "!BFS_Next_Y!"=="!最近单位Y!" (
Set "IsWalk=True"
)
)
) else (
Set "IsWalk=False"
)
) else (
Set "IsWalk=False"
)
) else (
Set "IsWalk=False"
)
) else (
Set "IsWalk=False"
)
if "!IsWalk!"=="True" (
if not defined BFS_Dist_!BFS_Next_X!_!BFS_Next_Y! (
Set "BFS_Dist_!BFS_Next_X!_!BFS_Next_Y!=t"
Set BFS_Path_!BFS_Next_X!_!BFS_Next_Y!_X=!BFS_X!
Set BFS_Path_!BFS_Next_X!_!BFS_Next_Y!_Y=!BFS_Y!
if !BFS_Next_X! lss 10 (
Set "BFS_Queue_X=!BFS_Queue_X!+!BFS_Next_X!"
) else (
Set "BFS_Queue_X=!BFS_Queue_X!!BFS_Next_X!"
)
if !BFS_Next_Y! lss 10 (
Set "BFS_Queue_Y=!BFS_Queue_Y!+!BFS_Next_Y!"
) else (
Set "BFS_Queue_Y=!BFS_Queue_Y!!BFS_Next_Y!"
)
Set /a BFS_Queue_Length+=1
)
)
)
goto :BFS_Main
)
:BFS_Finish
if !BFS_Path_%BFS_Next_Path_X%_%BFS_Next_Path_Y%_X! lss 10 (
Set "BFS_StackPath_X=+!BFS_Path_%BFS_Next_Path_X%_%BFS_Next_Path_Y%_X!!BFS_StackPath_X!"
) else (
Set "BFS_StackPath_X=!BFS_Path_%BFS_Next_Path_X%_%BFS_Next_Path_Y%_X!!BFS_StackPath_X!"
)
if !BFS_Path_%BFS_Next_Path_X%_%BFS_Next_Path_Y%_Y! lss 10 (
Set "BFS_StackPath_Y=+!BFS_Path_%BFS_Next_Path_X%_%BFS_Next_Path_Y%_Y!!BFS_StackPath_Y!"
) else (
Set "BFS_StackPath_Y=!BFS_Path_%BFS_Next_Path_X%_%BFS_Next_Path_Y%_Y!!BFS_StackPath_Y!"
)
(
Set BFS_Next_Path_X=!BFS_Path_%BFS_Next_Path_X%_%BFS_Next_Path_Y%_X!
Set BFS_Next_Path_Y=!BFS_Path_%BFS_Next_Path_X%_%BFS_Next_Path_Y%_Y!
)
if not "!BFS_Next_Path_X!"=="!NamePlayer_%敌方EnityId%_X!" (
goto :BFS_Finish
)
if not "!BFS_Next_Path_Y!"=="!NamePlayer_%敌方EnityId%_Y!" (
goto :BFS_Finish
)
set "回合=敌方移动AI处理_BFS"
goto Main

复制代码