@echo off
set var="av sdkjf   dfj  sdjf   abc efg"
for /f "tokens=5 delims= " %%i in (%var%) do echo %%i
pause
复制代码

@echo off
set a=sd sdfs sdf sdfsdfa sdfasd 123 sdf1
for %%i in (%a%) do (call set b=%%i %%b%%)
for /f "tokens=2" %%i in ("%b%") do echo %%i
pause
复制代码

@echo off
set var=av sdkjf   dfj  sdjf   abc efg
for %%i in (%var%) do (
   call set num=%%str%%
   set str=%%i
)
echo %num%
pause
复制代码

@echo off
set a=sd sdfs sdf sdfsdfa sdfasd 123 sdf1
for %%i in (%a%) do (call set a=%%i %%a%%)
call :a %a%
:a
echo.%2
pause
复制代码

@echo off
set a=sd sdfs sdf sdfsdfa sdfasd abc sdf1
call :lis %a%
pause
:lis
if "%3"=="" echo %1&goto :eof
shift /1
goto lis
复制代码

@echo off
set a=sd sdfs sdf sdfsdfa sdfasd abc sdf1
call :lis "%a%"
pause
:lis
for /f "tokens=1,2*" %%a in ("%~1") do (
  if "%%c"=="" (echo %%a) else call :lis "%%b %%c"
)
goto :eof
复制代码

@echo off
set var=av sdkjf   dfj  sdjf df abc efg
set var=%var: =.%
for %%i in (%var%) do set "var=%%~ni"
for %%i in (%var%) do set "var=%%~xi"
echo %var:.=%
pause
复制代码

@echo off
set var=av sdkjf   dfj  sdjf df abc efg
set var=%var: =.%
call :get %var% 0
call :get %var% 1
echo %var:.=%
pause
exit
:get
if %2 == 0 (set var=%~n1) else set var=%~x1
复制代码

@echo off
set var=av sdkjf   dfj  sdjf df abc efg
for %%i in (%var%) do call :rev %%i
set /a c-=1
call echo %%#%c%%%
pause
exit
:rev
set /a c+=1
set #%c%=%1
复制代码

@echo off
set var=av sdkjf   dfj  sdjf df     abc    efg
set var=%var: =.%
call :xx %var%
call :x %var%
pause>nul
:xx
set var=%~n1
goto :eof
:x
echo%~x1
复制代码

@echo off
set var=av sdkjf   dfj  sdjf df     abc    efg
set var=%var: =.%
for %%i in (%var%) do set "var=%%~ni"
call :x %var%
pause>nul
goto :eof
:x
echo%~x1
复制代码

@echo off
set /p str=请输入字符串(形如:ee dd   dd  sf abc ed):
for %%i in (%str%) do set /a n+=1
set /a n-=1
for /f "tokens=%n%" %%i in ("%str%") do echo %%i
pause
复制代码

rem 试用于截取倒数任何一段
@echo off
set "str=aa bb cc dd ee ff gg hh"
for %%a in (%str%) do set /a n+=1&call,set _%%n%%=%%a
set /p num=请输入要倒数截取的段数（请注意应小于总段数加1）：
set /a num-=1,n-=num
call,echo 截取的字符为：%%_%n%%%&pause>nul
复制代码

@echo off
set /p var1=请输入字符串：
set n=0
set var=%var1% #
:begin
set /a n+=1
set /a m=%n%+2
for /f "tokens=%n%,%m%" %%i in ("%var%") do (
if "%%j"=="#" (echo %%i)  else (goto begin))
pause
复制代码

@echo off&setlocal enabledelayedexpansion
set var=av sdkjf   dfj  sdjf   abc efg
for %%a in (%var%) do (set/a m+=1&set !m!=%%a)
set/a m-=1
echo !%m%!
复制代码

@echo off&setlocal enabledelayedexpansion
set "var=av sdkjf dfj sdjf afsd wry av sdkjf dfj sdjf abc wry"
set "str="
for /l %%i in (1,1,8189) do (
set v=!var:~-%%i,1!
if "!v!"==" " set/a n+=1&if !n! equ 2 echo !str!&pause&goto :eof
if !n! geq 1 set str=!var:~-%%i,1!!str!
)
复制代码