批处理之家 - Powered by Discuz! Board

标题: [其他] 【已解决】批处理if多条命令和for /l的应用 [打印本页]

作者: x137943156 时间: 2017-9-6 21:04 标题: 【已解决】批处理if多条命令和for /l的应用

本帖最后由 x137943156 于 2017-9-7 01:11 编辑

用来解决的问题：
想下载一批文件，下载地址的格式为www.XXX\日期(例如20170801)\日期.txt由于有两个变量，无法使用迅雷批量下载。

解决方案：
方案一：
设置date1，date2，使用for /l将这两个日期之间的网址逐条写入1.txt，然后将txt写入剪贴板。代码如下：

@echo off
set /p date1=输入起始日期（四位数字，如0801）：
set /p date2=输入结束日期（四位数字，如0801）：

for /l %%a in (%date1%, 1, %date2%) do echo www.xxx\2017%%a\2017%%a.txt >> 1.txt
clip < 1.txt
pause
复制代码

结果出错，使用for /l %%a in (08, 1, 010) do echo %%a测试发现，当开始数和结束数以0开头时，无法正常显示。是以0开头为八进制？

转换思路，改用方案二：
使用if语句，当date1<=date2时，将网址逐条写入文本，然后将date1自加一，再用goto跳转到if语句
结果出错，发现出错在自加一一项，简化代码如下

@echo off
set /p date1=
set /p date2=
:1
if %date1% LEQ %date2% ( set /a %a%=%a%+1 && echo www.xxx\2017%date1%\2017%date1%.txt >> 1.txt  && goto 1)
pause
复制代码

显示运算符不存在。

就这两个问题，请求各位帮忙。

作者: Batcher 时间: 2017-9-6 21:17

跨月份的日期既不能 for /l 也不能 set /a 自加一
你想的两个方法适合不跨月份的情况

方案一的解决思路是，先在输入的四位数字左侧补一位数字，然后在 for /l 内部截取字符串的后四位。

@echo off
setlocal enabledelayedexpansion
set /p date1=输入起始日期（四位数字，如0801）：
set /p date2=输入结束日期（四位数字，如0801）：

(for /l %%a in (1%date1%, 1, 1%date2%) do (
    set ThisDate=%%a
    set CutDate=!ThisDate:~1!
    echo www.xxx\2017!CutDate!\2017!CutDate!.txt
))> 1.txt
clip < 1.txt
pause
复制代码

作者: x137943156 时间: 2017-9-7 01:07

回复 2# Batcher

多谢，截取法不错。因为该网站资源就保存最近一个月，所以没有考虑跨月份，测试的时候也是在当月内测试。主要还是以0开头的数字出错。
思路2里面运算符不存在的问题我自己也找到了，是因为这句set /a %a%=%a%+1应该是set /a date1+=1，这样改动后，也回到了跟思路1一样的问题，就是以0开头出错。

例如在cmd中用for /l %a in (08, 1, 010) do @echo %a测试，结果显示0到8，而不是8到10.

作者: Nsqs 时间: 2017-9-7 20:40

那要是输入的开始和结尾数为0730、0801 中间隔了70多个数那就不对了，这个思路是不科学的

欢迎光临批处理之家 (http://www.bathome.net/)