@echo off
setlocal enabledelayedexpansion
set "f="
timeout /?>nul 2>&1&&set v=1||set v=2
:begin
set "n="
set "fd="
set "flag="
for /f "delims=" %%a in ('dir /b "D:\Repair1\"*.log 2^>nul') do set "t=%%a"&set "fd=D:\Repair1"
for /f "delims=" %%a in ('dir /b "D:\Repair2\"*.log 2^>nul') do set "t=%%a"&set "fd=D:\Repair2"
if "%t%" neq "%f%" (
    set "f=%t%"
    for /f "delims=" %%b in ('type "%fd%\!f!"') do (
        set "line=%%b"
        if "!line:-AdditionalPartInfo-=!" neq "%%b" set n=1
        if defined n (
            for /f "tokens=1-8 delims=," %%c in ("%%b") do (
                if "%%i" neq "" (
                    if "%%i" neq "BarcodeFailure" (
                        set "#_#%%e=%%i"
                    ) else set flag=1
                )
            )
        )
    )
    if defined flag (
        set "n="
        (for /f "tokens=1* delims=:" %%b in ('findstr /n .* "%fd%\!f!"') do (
            set "line=#%%c"
            if "!line:-AdditionalPartInfo-=!" neq "#%%c" set n=1
            if defined n (
                if "!line:BarcodeFailure=!" neq "#%%c" (
                    set line=!line:~1!
                    for /f "tokens=1-8 delims=," %%i in ("%%c") do (
                        for /f "delims=" %%i in ("!#_#%%k!") do echo;!line:BarcodeFailure=%%i!
                    )
                ) else echo;%%c
            ) else echo;%%c
        ))>"%tmp%\$tmp.txt"
        copy "%tmp%\$tmp.txt" "%fd%\!f!" /y
    ) else echo;"%fd%\!f!" no BarcodeFailure
)

for /f "tokens=1 delims==" %%a in ('set #_# 2^>nul') do set "%%a="
if %v% equ 2 (>nul ping /n 4 0) else (>nul timeout /t 4 /nobreak)
goto begin
复制代码