Board logo

标题: [特效代码] 分形图:谢尔宾斯基地毯 [打印本页]
作者: a20150604    时间: 2017-4-12 00:42     标题: 分形图:谢尔宾斯基地毯

本帖最后由 a20150604 于 2017-4-13 13:02 编辑

有点闲, 想画点简单的平面分形图, 就先画个 谢尔宾斯基地毯 吧


这个图形是左右, 上下, 中心对称的, 用图形复制的方法是很快的
  1. REM Sierpinski carpet call 递归图形复制高速版

  2. %1 @goto :initCON

  3. @echo off & setlocal enabledelayedexpansion

  4. set /a "w=83,h=83, h1=h,t=w*h,xc=w/2+1,yc=h/2"

  5. set "TAB=	" & for /F %%a in ('"prompt $h&for %%b in (1) do rem"')do Set "BS=%%a"

  6. set /a "buffwid = w, linesWantBackAbove = h + 1 - 1, cntBS = 2 + (buffwid + 7) / 8 * linesWantBackAbove"

  7. set "BSs=" & for /L %%a in (1 1 !cntBS!) do set "BSs=!BSs!%BS%"

  8. set "aLineBS=" & for /L %%a in (1 1 !w!) do set "aLineBS=!aLineBS!%BS%"

  9. mode %w%,%h1%

  10. for /l %%i in (1 1 !t!) do set "s=!s! "

  11. call :f 0 0 81 s

  12. REM <nul set /p "=!aLineBS!" & (2>nul echo;%TAB%!BSs!) & <nul set /p "=%BS%"

  13. REM <nul set /p "=%BS%!s:~0,-1!"

  14. title complete & >nul pause &exit

  15. :f xcnt ycnt hei s

  16. setlocal

  17. set "s=!%4!"

  18. if %3 leq 1 (

  19.     set /a "i=%1-xc + (%2-yc) * w + 1, L=i-1"

  20.     for /f "tokens=1,2" %%a in ("!L! !i!") do (set s=!s:~0,%%a!#!s:~%%b!)

  21. ) else (

  22.     set /a "h=%3 / 3"

  23.     set /a "x=%1 + - h, y=%2 + - h"

  24.     call :f !x! !y! !h! %4

  25.     set /a "x1=%1 + (- %3/2), y1=%2 + (- %3/2), xb=x1+h, yb=y1+h"

  26.     for %%x in (- 0^& +) do for %%y in (- 0^& +) do (

  27.         if "%%x%%y" neq "0&0&" if "%%x%%y" neq "--" (

  28.             set /a "x2=xb + (%%x h), y2=yb + (%%y h)"

  29.             for /L %%j in (1 1 !h!) do (

  30.                 set /a "i=x2-xc + (y2-yc + %%j-1) * w + h, L=i-h, i1=x1-xc + (y1-yc + %%j-1) * w"

  31.                 for /f "tokens=1-4" %%a in ("!L! !i! !i1! !h!") do (

  32.                     set "s=!s:~0,%%a!!s:~%%c,%%d!!s:~%%b!"

  33.                     <nul set /p "=!aLineBS!" & (2>nul echo;%TAB%!BSs!) & <nul set /p "=%BS%"

  34.                     <nul set /p "=%BS%!s:~0,-1!"

  35.                 )

  36.             )

  37.         )

  38.     )

  39. )

  40. (

  41.     endlocal

  42.     set "%4=%s%"

  43.     exit /b

  44. )

  45. :initCON

  46. @echo off

  47. for %%a in (  FontSize:00080008      FontFamily:00000030  WindowSize:00C800C8

  48.               ScreenColors:0000000f  CodePage:000001b5    ScreenBufferSize:00C800C8

  49. ) do for /f "tokens=1,2 delims=:" %%b in ("%%a") do (

  50.   >nul reg add HKCU\Console\Sierpinski_carpet /v %%b /t reg_dword /d 0x%%c /f

  51. )

  52. start "Sierpinski_carpet" /max "%ComSpec%" /c "%~0" REM & (call :delReg) & exit

  53. REM end of :initCON

  54. exit /b

  55. :delReg

  56. setlocal enabledelayedexpansion

  57. set "s=!time:~-4,1!"

  58. :delReg.loop

  59. set /a "elapse = (1!time:~-4,1! - s) %% 10"

  60. if %elapse% lss 2 goto :delReg.loop

  61. >nul reg delete HKCU\Console\Sierpinski_carpet /f

  62. endlocal

  63. exit /b

  64. REM end of :delReg
复制代码
for 模拟递归版
  1. %1 @goto :initCON

  2. @echo off & setlocal enabledelayedexpansion

  3. call :clearVars

  4. set /a "w=83,h=83, h1=h,t=w*h,xc=w/2+1,yc=h/2"

  5. mode %w%,%h1%

  6. 

  7. set "TAB=	" & for /F %%a in ('"prompt $h&for %%b in (1) do rem"')do Set "BS=%%a"

  8. set /a "buffwid = w, linesWantBackAbove = h + 1 - 1, cntBS = 2 + (buffwid + 7) / 8 * linesWantBackAbove"

  9. set "BSs=" & for /L %%a in (1 1 !cntBS!) do set "BSs=!BSs!%BS%"

  10. set "aLineBS=" & for /L %%a in (1 1 !w!) do set "aLineBS=!aLineBS!%BS%"

  11. 

  12. for /l %%i in (1 1 !t!) do set "s=!s! "

  13. REM 堆栈 xSt, ySt, hSt, iSt 都取 4 位一节

  14. set "xL=- + + - 0&0&- + "

  15. set "yL=- + - + - + 0&0&"

  16. set /a "xcnt=0, ycnt=0, hei=81, istep=-2"

  17. 

  18. :enter

  19. 

  20. for /L %%* in () do (

  21.         <nul set /p "=!aLineBS!" & (2>nul echo;%TAB%!BSs!) & <nul set /p "=%BS%"

  22.         <nul set /p "=%BS%!s:~0,-1!"

  23. 

  24.         REM if 层终结条件 满足

  25.         if !hei! leq 1 (

  26.             REM 层终结计算

  27.             set /a "i=xcnt-xc + (ycnt-yc) * w + 1, L=i-1"

  28.             for /f "tokens=1,2" %%a in ("!L! !i!") do (set s=!s:~0,%%a!#!s:~%%b!)

  29. 

  30.             REM 参数出栈

  31.             set /a "xcnt=!xSt:~-4!, ycnt=!ySt:~-4!, hei=!hSt:~-4!, istep=!iSt:~-4!"

  32.             set "xSt=!xSt:~0,-4!"

  33.             set "ySt=!ySt:~0,-4!"

  34.             set "hSt=!hSt:~0,-4!"

  35.             set "iSt=!iSt:~0,-4!"

  36.             REM goto :enter

  37.         ) else (

  38.         REM else

  39.             REM if 本层子计算未完成

  40.             if !istep! lss 14 (

  41.                 REM 生成 并更新 下一个(或第1个)子计算 的 参数

  42.                 if !istep! geq 0 (

  43.                     REM 还原上层中心坐标

  44.                     for %%i in (!istep!) do set /a "xcnt-=(!xL:~%%i,2! hei/3), ycnt-=(!yL:~%%i,2! hei/3)"

  45.                 )

  46.                 set /a "istep+=2"

  47.                 for %%i in (!istep!) do set /a "xcnt+=(!xL:~%%i,2! hei/3), ycnt+=(!yL:~%%i,2! hei/3)"

  48.                 REM 参数入栈

  49.                 set "t=!xcnt!   !ycnt!"

  50.                 set "xSt=!xSt!!t:~0,4!"

  51.                 set "ySt=!ySt!!t:~-4!"

  52.                 set "t=!istep!   !hei!"

  53.                 set "hSt=!hSt!!t:~-4!"

  54.                 set "iSt=!iSt!!t:~0,4!"

  55.                 REM 层递进一

  56.                 set /a "hei/=3, istep=-2"

  57.                 REM goto :enter

  58.             ) else (

  59.             REM else

  60.                 REM if 栈空

  61.                 if "!hSt!"=="" (

  62.                     REM goto :complete

  63.                     <nul set /p "=!aLineBS!" & (2>nul echo;%TAB%!BSs!) & <nul set /p "=%BS%"

  64.                     <nul set /p "=%BS%!s:~0,-1!"                    

  65.                     title complete any to exit... &  >nul pause &exit

  66.                 ) else (

  67.                 REM else

  68.                     REM 参数出栈

  69.                     set /a "xcnt=!xSt:~-4!, ycnt=!ySt:~-4!, hei=!hSt:~-4!, istep=!iSt:~-4!"

  70.                     set "xSt=!xSt:~0,-4!"

  71.                     set "ySt=!ySt:~0,-4!"

  72.                     set "hSt=!hSt:~0,-4!"

  73.                     set "iSt=!iSt:~0,-4!"

  74.                     REM goto :enter

  75.                 )

  76.             )

  77.         )

  78. 

  79. )

  80. :complete

  81. exit

  82. 

  83. :initCON

  84. @echo off

  85. for %%a in (  FontSize:00080008      FontFamily:00000030  WindowSize:00C800C8

  86.               ScreenColors:0000000f  CodePage:000001b5    ScreenBufferSize:00C800C8

  87. ) do for /f "tokens=1,2 delims=:" %%b in ("%%a") do (

  88.   >nul reg add HKCU\Console\Sierpinski_carpet /v %%b /t reg_dword /d 0x%%c /f

  89. )

  90. start "Sierpinski_carpet" /max "%ComSpec%" /c "%~0" REM & (call :delReg) & exit

  91. REM end of :initCON

  92. exit /b

  93. 

  94. :clearVars

  95. set "Path=%SystemRoot%\system32"

  96. for /f "delims==" %%a in ('set') do (

  97.   if /i "%%a" neq "Path" set "%%a="

  98. )

  99. exit /b

  100. REM end of :clearVars
复制代码
call 递归版:
  1. %1 @goto :initCON

  2. @echo off & setlocal enabledelayedexpansion

  3. call :clearVars

  4. 

  5. set /a "w=83,h=83, h1=h+1,t=w*h,xc=w/2+1,yc=h/2-1"

  6. mode %w%,%h1%

  7. for /l %%i in (1 1 !t!) do set "s=!s! "

  8. call :f 0 0 81 s

  9. echo;!s! &pause &exit

  10. 

  11. :f xcnt ycnt hei s

  12. setlocal

  13. set "s=!%4!"

  14. if %3 leq 1 (

  15. 

  16.     set /a "i=%1-xc + (%2-yc) * w + 1, L=i-1"

  17.     for /f "tokens=1,2" %%a in ("!L! !i!") do (set s=!s:~0,%%a!#!s:~%%b!)

  18.     cls & echo;!s!

  19. ) else (

  20.     set /a "h=%3 / 3"

  21.     for %%x in (- 0^& +) do for %%y in (- 0^& +) do (

  22.         if "%%x%%y" neq "0&0&" (

  23.             set /a "x=%1 + (%%x h), y=%2 + (%%y h)"

  24.             call :f !x! !y! !h! %4

  25.         )

  26.     )

  27. )

  28. (

  29.     endlocal

  30.     set "%4=%s%"

  31.     exit /b

  32. )

  33. 

  34. :d

  35. set /a "i=%1-xc + (%2-yc) * w + 1, L=i-1"

  36. for /f "tokens=1,2" %%a in ("!L! !i!") do (set s=!s:~0,%%a!#!s:~%%b!)

  37. exit /b

  38. 

  39. 

  40. :initCON

  41. @echo off

  42. for %%a in (  FontSize:00080008      FontFamily:00000030  WindowSize:00C800C8

  43.               ScreenColors:0000000f  CodePage:000001b5    ScreenBufferSize:00C800C8

  44. ) do for /f "tokens=1,2 delims=:" %%b in ("%%a") do (

  45.   >nul reg add HKCU\Console\Sierpinski_carpet /v %%b /t reg_dword /d 0x%%c /f

  46. )

  47. start "Sierpinski_carpet" /max "%ComSpec%" /c "%~0" REM & (call :delReg) & exit

  48. REM end of :initCON

  49. 

  50. exit /b

  51. 

  52. :clearVars

  53. set "Path=%SystemRoot%\system32"

  54. for /f "delims==" %%a in ('set') do (

  55.   if /i "%%a" neq "Path" set "%%a="

  56. )

  57. REM set path=

  58. exit /b

  59. REM end of :clearVars
复制代码
goto 递归版, 没有期望的的速度, 毕竟 goto 要在文件中搜索行标, 快不了
  1. %1 @goto :initCON

  2. @echo off & setlocal enabledelayedexpansion

  3. call :clearVars

  4. set /a "w=83,h=83, h1=h+1,t=w*h,xc=w/2+1,yc=h/2-1"

  5. mode %w%,%h1%

  6. for /l %%i in (1 1 !t!) do set "s=!s! "

  7. REM 堆栈 xSt, ySt, hSt, iSt 都取 4 位一节

  8. set "xL=- + + - 0&0&- + "

  9. set "yL=- + - + - + 0&0&"

  10. set /a "xcnt=0, ycnt=0, hei=81, istep=-2"

  11. :enter

  12.     cls & echo;!s!

  13.         REM if 层终结条件 满足

  14.         if !hei! leq 1 (

  15.             REM 层终结计算

  16.             set /a "i=xcnt-xc + (ycnt-yc) * w + 1, L=i-1"

  17.             for /f "tokens=1,2" %%a in ("!L! !i!") do (set s=!s:~0,%%a!#!s:~%%b!)

  18. 

  19.             REM 参数出栈

  20.             set /a "xcnt=!xSt:~-4!, ycnt=!ySt:~-4!, hei=!hSt:~-4!, istep=!iSt:~-4!"

  21.             set "xSt=!xSt:~0,-4!"

  22.             set "ySt=!ySt:~0,-4!"

  23.             set "hSt=!hSt:~0,-4!"

  24.             set "iSt=!iSt:~0,-4!"

  25.             goto :enter

  26.         ) else (

  27.         REM else

  28.             REM if 本层子计算未完成

  29.             if !istep! lss 14 (

  30.                 REM 生成 并更新 下一个(或第1个)子计算 的 参数

  31.                 if !istep! geq 0 (

  32.                     REM 还原上层中心坐标

  33.                     for %%i in (!istep!) do set /a "xcnt-=(!xL:~%%i,2! hei/3), ycnt-=(!yL:~%%i,2! hei/3)"

  34.                 )

  35.                 set /a "istep+=2"

  36.                 for %%i in (!istep!) do set /a "xcnt+=(!xL:~%%i,2! hei/3), ycnt+=(!yL:~%%i,2! hei/3)"

  37.                 REM 参数入栈

  38.                 set "t=!xcnt!   !ycnt!"

  39.                 set "xSt=!xSt!!t:~0,4!"

  40.                 set "ySt=!ySt!!t:~-4!"

  41.                 set "t=!istep!   !hei!"

  42.                 set "hSt=!hSt!!t:~-4!"

  43.                 set "iSt=!iSt!!t:~0,4!"

  44.                 REM 层递进一

  45.                 set /a "hei/=3, istep=-2"

  46.                 goto :enter

  47.             ) else (

  48.             REM else

  49.                 REM if 栈空

  50.                 if "!hSt!"=="" (

  51.                     goto :complete

  52.                 ) else (

  53.                 REM else

  54.                     REM 参数出栈

  55.                     set /a "xcnt=!xSt:~-4!, ycnt=!ySt:~-4!, hei=!hSt:~-4!, istep=!iSt:~-4!"

  56.                     set "xSt=!xSt:~0,-4!"

  57.                     set "ySt=!ySt:~0,-4!"

  58.                     set "hSt=!hSt:~0,-4!"

  59.                     set "iSt=!iSt:~0,-4!"

  60.                     REM goto :enter

  61.                     goto :enter

  62.                 )

  63.             )

  64.         )

  65. 

  66. :complete

  67. echo;!s! &pause &exit

  68. 

  69. :d

  70. title xcnt=%1, ycnt=%2

  71. set /a "i=%1-xc + (%2-yc) * w + 1, L=i-1"

  72. for /f "tokens=1,2" %%a in ("!L! !i!") do (set s=!s:~0,%%a!#!s:~%%b!)

  73. exit /b

  74. :initCON

  75. @echo off

  76. for %%a in (  FontSize:00080008      FontFamily:00000030  WindowSize:00C800C8

  77.               ScreenColors:0000000f  CodePage:000001b5    ScreenBufferSize:00C800C8

  78. ) do for /f "tokens=1,2 delims=:" %%b in ("%%a") do (

  79.   >nul reg add HKCU\Console\Sierpinski_carpet /v %%b /t reg_dword /d 0x%%c /f

  80. )

  81. start "Sierpinski_carpet" /max "%ComSpec%" /c "%~0" REM & (call :delReg) & exit

  82. REM end of :initCON

  83. exit /b

  84. 

  85. :clearVars

  86. set "Path=%SystemRoot%\system32"

  87. for /f "delims==" %%a in ('set') do (

  88.   if /i "%%a" neq "Path" set "%%a="

  89. )

  90. REM set path=

  91. exit /b

  92. REM end of :clearVars
复制代码
作者: CrLf    时间: 2017-4-12 01:24

说好的 :delReg 去哪了...
作者: a20150604    时间: 2017-4-12 12:41

回复 2# CrLf

第二部也许出吧
作者: dingcool    时间: 2017-4-12 17:19

it is cool~~~~~~~~~



欢迎光临 批处理之家 (http://www.bathome.net/) Powered by Discuz! 7.2