批处理之家 - Powered by Discuz! Board

标题: [文件操作] 【已解决】批处理如何删除多个文本里指定列/字段的内容为指定字符串的行 [打印本页]

作者: shero 时间: 2016-11-9 19:51 标题: 【已解决】批处理如何删除多个文本里指定列/字段的内容为指定字符串的行

批量删除txt文件里第二列为0的行数据!!
有很多个文件一个文件里面有很多txt

格式基本一样
请问想要筛选分离出删除每个txt文件里面第二例为0的行

作者: pcl_test 时间: 2016-11-9 20:26

本帖最后由 pcl_test 于 2016-11-10 10:27 编辑

for/findstr
http://www.bathome.net/thread-2189-1-1.html
http://bbs.bathome.net/thread-31727-1-1.html
http://www.bathome.net/thread-5814-1-1.html
http://www.bathome.net/viewthread.php?tid=14682
http://www.bathome.net/thread-75-1-1.html

rem win7及以上系统运行
2>nul md "result\" 
powershell -c "dir *.txt|%%{gc $_|?{($_.trim() -split '\s+')[1] -ne 0}|out-file $('result\'+$_.Name) -encoding default}"
rem powershell -c "dir *.txt|%%{gc $_|?{$_ -notmatch '^\s*?\S+?\s+?0[^0]*?'}|out-file $('result\'+$_.Name) -encoding default}"
pause
复制代码

作者: 0000 时间: 2016-11-9 21:14

本帖最后由 0000 于 2016-11-9 21:15 编辑

rem 请把__tab__换成实际的tab字符
set tab=__tab__
for %%a in (*.txt) do (
for /f "tokens=1,2,* delims=%tab%" %%x in (%%a) do (
if not "%%y" == "0" echo %%x%tab%%%y%tab%%%z>>%%~na_1.txt
)
)
复制代码

如有错误请指正。

作者: shero 时间: 2016-11-11 15:32

回复 2# pcl_test

根据你的代码，我成功完成操作，万分感谢！现在还有一个问题，如果我是想保留第二列是0的行的数据该如何操作呢，请大神指教！

作者: Batcher 时间: 2016-11-11 17:26

回复 3# 0000

咱们论坛可以支持 tab 字符，你试试

set tab=	
for %%a in (*.txt) do (
    for /f "tokens=1,2,* delims=%tab%" %%x in (%%a) do (
        if not "%%y" == "0" echo %%x%tab%%%y%tab%%%z>>%%~na_1.txt
    )
)
复制代码

作者: pcl_test 时间: 2016-11-11 18:32

本帖最后由 pcl_test 于 2018-4-19 11:48 编辑

回复 4# shero

1、powershell
-eq
-match
2、

@echo off
for /f "tokens=*" %%a in ('type "文本.txt"') do (
    for /f "tokens=1,2" %%b in ("%%a") do (
        if "%%c" equ "0" echo;%%a
    )
)
pause
复制代码

3、

findstr /rc:"^[ 	]*[^ 	][^ 	]*[ 	][ 	]*0[^0]*" "文本.txt"
pause
复制代码

4、

#*第三方http://www.bathome.net/s/tool/index.html?key=gawk
#*&cls&2>nul md "result\" &dir /a-d/b *.txt|gawk -f "%~f0"&pause&exit
BEGIN{
   while(getline file>0){
      while(getline<file>0){
          if($2==0)print $0>"result\\"file
      }
   }
}
复制代码

作者: shero 时间: 2016-11-13 08:12

回复 6# pcl_test

版主大大，我没有明白你的意思，是这几个分别运行还是合在一起，我都试过了还是有问题，原谅我是一个初学者，请大大指导

作者: shero 时间: 2016-11-16 15:19

回复 6# pcl_test

版主大大只有第一个程序把“文本.txt”改为对应的文本可以用，但是只能一个一个文本改吗？不能直接批处理文件夹类的所有txt文件吗？

作者: pcl_test 时间: 2016-11-16 15:50

回复 8# shero

先把2楼发的教程学习学习吧

作者: shero 时间: 2016-11-17 21:58

回复 9# pcl_test

版主版主我根据您之前的程序修改了一下似乎改出来了好开心❤
rem win7及以上系统运行
2>nul md "result\"
powershell -c "dir *.txt|%%{gc $_|?{($_.trim() -split '\s+')[1] -eq 0}|out-file $('result\'+$_.Name) -encoding default}"
rem powershell -c "dir *.txt|%%{gc $_|?{$_ -notmatch '^\s*?\S+?\s+?0[^0]*?'}|out-file $('result\'+$_.Name) -encoding default}"
pause

作者: pcl_test 时间: 2016-11-17 22:17

回复 10# shero

这是两段代码，改其一皆可，rem表示注释

欢迎光临批处理之家 (http://www.bathome.net/)