@echo off & setlocal enabledelayedexpansion
::演示：删除指定路径下指定天数之前（以文件的最后修改日期为准）的文件。
::如果演示结果无误，把del前面的echo去掉，即可实现真正删除。
::本例调用了临时VBS代码进行日期计算
::本例为兼容不同的日期格式，调用reg命令（XP系统自带）统一设置日期格式，
::处理完毕之后再把日期格式恢复成原来的状态。


rem 指定待删除文件的存放路径
set SrcDir=C:\000\1M
rem 指定天数
set DaysAgo=1


for /f "delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
    set "RegDateOld=%%a"
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
>"%temp%\DstDate.vbs" echo LastDate=date()-%DaysAgo%
>>"%temp%\DstDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
>>"%temp%\DstDate.vbs" echo wscript.echo FmtDate
for /f %%a in ('cscript /nologo "%temp%\DstDate.vbs"') do (
    set "DstDate=%%a"
)
set DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%
for /r "%SrcDir%" %%a in (*.*) do (
    if "%%~ta" leq "%DstDate%" (
        if exist "%%a" (
            del /f /q "%%a"
        )
    )
)
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
pause
复制代码

@echo off & setlocal enabledelayedexpansion
::演示：删除指定路径下指定天数之前（以文件的最后修改日期为准）的文件。
::如果演示结果无误，把del前面的echo去掉，即可实现真正删除。
::本例调用了临时VBS代码进行日期计算
::本例为兼容不同的日期格式，调用reg命令（XP系统自带）统一设置日期格式，
::处理完毕之后再把日期格式恢复成原来的状态。


rem 指定待删除文件的存放路径
set SrcDir1=C:\000\1M
set SrcDir2=C:\000\2M
rem 指定天数
set DaysAgo=1

for %%f in ("%SrcDir1%";"%SrcDir2%") do (
set SrcDir=%%f

echo 这里该怎么套用代码1里的代码

)
pause
复制代码

@echo off&setlocal enabledelayedexpansion
rem -1为一天前、-2为两天前……以此类推
set DaysAgo=-1
rem 指定需处理的文件类型/扩展名，默认为所有类型文件，如需处理所有txt文件，则修改为set FileExt=*.txt
set FileExt=
for /f "tokens=3" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do set "RegDateOld=%%a"
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-MM-dd /f >nul
for /f %%a in ('mshta VBScript:Execute("NewDate=date()+(%DaysAgo%):FmtDate=right(year(NewDate),4)&right(""0""&month(NewDate),2)&right(""0""&day(NewDate),2):CreateObject(""Scripting.FileSystemObject"").GetStandardStream(1).Write FmtDate:close"^)') do set "dstDate=%%a"
for /f "delims=" %%a in ('more +23 "%~f0"') do (
    if exist "%%a" (
        cd /d "%%a"
        for /f "delims=" %%b in ('dir /a-d/b/s %FileExt%') do (
            for /f "tokens=1" %%c in ("%%~tb") do set srcDate=%%c
            set srcDate=!srcDate:-=!
            set srcDate=!srcDate:/=!
            echo;if !srcDate! lss %dstDate% del "%%b" /q
        )
    ) else echo;%%a 不存在
)
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f >nul
echo;Done
pause&exit
::文件夹列表
c:\000\00-00\APILog
c:\000\00-00\SysLog
复制代码

@echo off & setlocal enabledelayedexpansion
::演示：删除指定路径下指定天数之前（以文件的最后修改日期为准）的文件。
::如果演示结果无误，把del前面的echo去掉，即可实现真正删除。
::本例调用了临时VBS代码进行日期计算
::本例为兼容不同的日期格式，调用reg命令（XP系统自带）统一设置日期格式，
::处理完毕之后再把日期格式恢复成原来的状态。


rem 指定待删除文件的存放路径
set SrcDir1=c:\000\00-00\APILog
set SrcDir2=c:\000\00-00\SysLog
set SrcDir3=e:\test
rem 指定天数
set DaysAgo=1
rem 指定类型
set FileExt=log


for /f "delims=" %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
    set "RegDateOld=%%a"
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
>"%temp%\DstDate.vbs" echo LastDate=date()-%DaysAgo%
>>"%temp%\DstDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
>>"%temp%\DstDate.vbs" echo wscript.echo FmtDate
for /f %%a in ('cscript /nologo "%temp%\DstDate.vbs"') do (
    set "DstDate=%%a"
)
set DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%
for /l %%a in (1 1 1000) do (
  call :ok SrcDir%%a
  if errorlevel 5 goto :end
)

:end
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
pause&exit

:ok
echo %1
if not defined %1 exit /b 5
  for /f "delims=" %%b in ('dir /s /b !%1!\*.%FileExt%') do (
    if "%%~tb" leq "%DstDate%" (
        if exist "%%b" (
            del /f /q "%%b"
        )
    )
  )
exit /b
复制代码