标题: [系统相关] XP系统下批处理如何设置/更改本地连接的IP地址和子网掩码? [打印本页]
作者: ck95785045 时间: 2016-6-15 16:05 标题: XP系统下批处理如何设置/更改本地连接的IP地址和子网掩码?
本帖最后由 pcl_test 于 2016-6-16 12:32 编辑
在XP系统中如何批处理修改IP 我只需要自动设置成
192.168.0.4
255.255.255.0
其它的网关还有DNS都不设置。
作者: ck95785045 时间: 2016-6-16 08:47
找不到才发的帖 搜索也找不到
作者: 小程936 时间: 2016-6-17 21:35
本帖最后由 小程936 于 2016-6-17 22:11 编辑
- @echo off&title ip和dns设置助手V3.0(小程936制作)&cd /d "%~dp0"
- reg query "HKU\S-1-5-19" >nul 2>&1 || (echo 请右键“以管理员身份运行”&echo.&pause&exit /b 1)
- set ah=%*
- set aj=%2
- if DEFINED aj goto #2
- if DEFINED ah goto #
-
- :1
- echo 【Win8/10用户输入1】【Win7/xp用户输入2】
- echo 【Wifi连接用户输入3】【自定义直接回车】
- set /p in=请输入序号:
- if "%in%"=="1" set 连接名称=以太网&goto 3
- if "%in%"=="2" set 连接名称=本地连接&goto 3
- if "%in%"=="3" set 连接名称=无线网络连接&goto 3
- echo 正在扫描可用连接名……
- systeminfo|find /i "连接名:"
- set /p 连接名称=请输入连接名(自定义):&goto 3
-
- :3
- set ip=netsh interface ip set address name="%连接名称%" source
- set dns=netsh interface ip set dnsserv name="%连接名称%" source
- set dns2=netsh interface ip add dnsserv name="%连接名称%" addr
- echo 请输入IP地址,留空为自动获取&set /p IP地址=IP:
- if "%IP地址%"=="" %ip%=dhcp&goto 31
- echo 请输入子网掩码,留空自动设置为255.255.255.0&set /p 子网掩码=掩码:
- if "%子网掩码%"=="" set 子网掩码=255.255.255.0
- echo 请输入网关地址(路由器管理地址),不推荐留空&set /p 网关地址=网关:
- if "%网关地址%"=="" set 网关地址=none
- %ip%=static addr=%IP地址% mask=%子网掩码% gateway=%网关地址% gwmetric=1
- :31
- echo 请输入主dns地址,留空为自动获取&set /p 主dns地址=主dns:
- if "%主dns地址%"=="" (%dns%=dhcp&goto 3end) else (%dns%=static addr=%主dns地址% primary)
- echo 请输入备dns地址,可以留空。&set /p 备dns地址=备dns:
- if not "%备dns地址%"=="" %dns2%=%备dns地址%
- :3end
- ipconfig /renew
- ipconfig /flushdns
- echo 设置成功。
- if not DEFINED aj echo 下面是本程序的命令行使用方法。& pause>nul & cls &goto #
- pause>nul & exit /b
-
- :#
- echo 设置局域网IP地址和DNS。下面是本程序的命令行使用方法。
- echo.
- echo 用法:本程序 ^<序号或连接名^>
- echo [ip]
- echo [ip IP地址 [子网掩码^|0 [网关地址]]
- echo [dns]
- echo [dns [主DNS [备DNS]]]
- echo.
- echo 参数:
- echo ip - 自动获取IP
- echo ip IP地址 - 指定IP地址,子网掩码自动设置为225.255.225.0,网关留空。
- echo ip IP地址 子网掩码 - 指定IP地址和子网掩码,网关留空。
- echo ip IP地址 子网掩码 网关地址 - 指定IP地址和子网掩码和网关。
- echo ip IP地址 0 网关地址 - 指定IP地址和网关,子网掩码自动设置为225.255.225.0
- set/p=
- echo dns - 自动获取DNS
- echo dns 主DNS - 指定主DNS地址
- echo dns 主DNS 备DNS - 指定主DNS地址和备DNS地址
- echo.
- echo 备注:IP设置和DNS设置命令分开。Win8/10序号为1,Win7/xp序号为2,Wifi序号为3
- echo 桌面右键,新建快捷方式,按上述语法输入,使用起来更加方便。
- echo.
- echo 示例:
- echo 本程序 1 ip
- echo 本程序 以太网 ip 192.168.10.101 0 192.168.10.1
- echo 本程序 2 dns
- echo 本程序 本地连接 dns 223.5.5.5 223.6.6
- set/p=
- exit /b 2
- :#2
- set ai=%1
- set aj=%2
- set ak=%3
- set al=%4
- set am=%5
- if "%ai%"=="1" set ai=以太网
- if "%ai%"=="2" set ai=本地连接
- if "%ai%"=="3" set ai=无线网络连接
- set ip=netsh interface ip set address name="%ai%" source
- set dns=netsh interface ip set dnsserv name="%ai%" source
- set dns2=netsh interface ip add dnsserv name="%ai%" addr
- goto #%aj%
- :#ip
- if "%ak%"=="" %ip%=dhcp&goto 3end
- if "%al%"=="" set al=255.255.255.0
- if "%al%"=="0" set al=255.255.255.0
- if "%am%"=="" set am=none
- %ip%=static addr=%ak% mask=%al% gateway=%am% gwmetric=1
- goto 3end
- :#dns
- if "%ak%"=="" (%dns%=dhcp&goto 3end) else (%dns%=static addr=%ak% primary)
- if not "%al%"=="" %dns2%=%al%
- goto 3end
复制代码
作者: 小程936 时间: 2016-6-17 21:40
本帖最后由 小程936 于 2016-6-17 21:49 编辑
回复 2# ck95785045
xp啊……- netsh interface ip set address name="本地连接" source=static addr=%IP地址% mask=255.255.255.0 gateway=none gwmetric=1
- ipconfig /renew
- ipconfig /flushdns
复制代码
若以上命令无效,请执行以下代码确认连接名到底是啥- systeminfo|find /i "连接名:"
复制代码
作者: ck95785045 时间: 2016-6-23 10:35
回复 4# 小程936
谢谢
欢迎光临 批处理之家 (http://www.bathome.net/) |
Powered by Discuz! 7.2 |