批处理之家 - Powered by Discuz! Board

标题: [文本处理] 批处理如何用set命令替换文本中的指定字符串？ [打印本页]

作者: zhsh1128 时间: 2016-5-31 09:23 标题: 批处理如何用set命令替换文本中的指定字符串？

求助：如何把111.txt中的文本“[组词]”替换为“[编词]”，其它文本不变，结果放在222.txt中？

最近在学set和for，怎么也写不好。要求：用set和for来实现。

作者: gawk 时间: 2016-5-31 10:23

@echo off
setlocal enabledelayedexpansion
(for /f "delims=" %%i in ('type "111.txt"') do (
    set OldStr=%%i
    set NewStr=!OldStr:[组词]=[编词]!
    echo,!NewStr!
))>222.txt
复制代码

作者: zhsh1128 时间: 2016-5-31 11:42

gawk 发表于 2016-5-31 10:23

我写的代码犯的错误是：1.do后面的括号另起一行了。2.变量延迟的引用不对。我写成：set str1=%!str!:[组词]=[编词]%。3.for语句中()部分直接写的是文件名，for /f "delims=" %%i in (111.txt) do

谢谢。另外您的程序把整个for给()起来，然后>222.txt。不是太懂。改写了您的代码。

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('type 111.txt') do (
set str=%%i
set str1=!str:[组词]=[编词]!
echo !str1! >> 222.txt
)

作者: zhsh1128 时间: 2016-5-31 11:48

gawk 发表于 2016-5-31 10:23

如果是333.txt这样的文本，两个文字块之间有空行，怎么在结果里把空行给保留下来？

作者: gawk 时间: 2016-5-31 16:02

回复 3# zhsh1128

重定向放在for循环内部会降低代码执行效率，待处理的文本越大效果越明显。

作者: gawk 时间: 2016-5-31 16:25

回复 4# zhsh1128

@echo off
setlocal enabledelayedexpansion
(for /f "tokens=1* delims=:" %%i in ('type "333.txt" ^| findstr /n ".*"') do (
    if "%%j" equ "" (
        echo,
    ) else (
        set OldStr=%%j
        set NewStr=!OldStr:[组词]=[编词]!
        echo,!NewStr!
    )
))>444.txt
复制代码

欢迎光临批处理之家 (http://www.bathome.net/)