批处理之家 - Powered by Discuz! Board

标题: 【出题】批处理输出n阶幻方 [打印本页]

作者: lhjoanna 时间: 2009-4-1 12:50 标题: 【出题】批处理输出n阶幻方

所谓n阶幻方：1-n^2个数排为n行n列，横、竖、对角线相加和相同。
  输入：幻方阶数n (暂限制为奇数阶)
  输出：n行n列的方阵，横、竖、对角线相加和相同。
  举例：5阶幻方，横、竖、对角线相加和为65

17 24  1  8 15
23  5  7 14 16
4  6 13 20 22
10 12 19 21  3
11 18 25  2  9

作者: pusofalse 时间: 2009-4-1 13:53

这个题目相当难啊~ 以前做过类似的，没做出来~ - -|||

作者: batman 时间: 2009-4-1 15:11

解此题最重要的不是代码，而是思路。。。

作者: lhjoanna 时间: 2009-4-1 16:56

恩，幻方生成规则知道了，代码也就不难了。^_^

作者: lhjoanna 时间: 2009-4-1 20:02

是不是太难了，怎么没人贴代码来？可以先到网上搜索一下奇次幻方的构造规律，然后再转化为代码就相对容易些了！

作者: Lumiere 时间: 2009-4-1 21:08

是想自己摸索出来那个规则吧？

作者: slore 时间: 2009-4-1 22:30

cn-dos不是有么

作者: lhjoanna 时间: 2009-4-1 22:56

哦？我刚搜了下没搜到啊。slore兄不妨把那帖子链接贴来，看能不能激发些灵感想出些不同的方法。

作者: Batcher 时间: 2009-4-1 23:27

不知道slore兄是不是说的这个：
http://www.cn-dos.net/forum/viewthread.php?tid=26647

CN-DOS这次出问题看来丢了十来天的数据，哎~

作者: lhjoanna 时间: 2009-4-2 06:47

呵，我发现什么帖子都逃不过batcher的眼睛啊~此链接中楼主所说的九宫格就是三阶幻方，又看到了namejm的精彩代码~~不过此题要求是n阶幻方(暂定为奇数阶)，下面11楼 pengfei所上传的附件sigil.exe符合此题题意。虽然没提供代码，但是提供了算法。大家尝试着看谁能写出代码？

作者: more 时间: 2009-4-2 10:19

试试:

@echo off
:bgn
set input=&set /p input=请输入3以上的单数(回车退出):
if not defined input goto :eof
cls
if %input% lss 3 (echo.你输入的也太小了吧...&goto :bgn)
echo.%input:~-1%|findstr "[^13579]" >nul&&(echo.请输入单数...&goto :bgn)
set /a num1=(%input%*%input%+1)*%input%/2,num2=%input%*%input%
echo.%input%阶幻方各行,列以及对角线相加的和为:%num1%
set /a lie=%input%/2+1,hang=1,all=1
set h1l%lie%=1
:agn
set /a hang-=1,lie+=1,all+=1
if %hang% lss 1 set hang=%input%
if %lie% gtr %input% set lie=1
if defined h%hang%l%lie% (set /a hang+=2,lie-=1)
set h%hang%l%lie%=%all%
if "%hang%"=="1" (
  if "%lie%"=="%input%" (
    set /a hang+=1,all+=1
    call set h%%hang%%l%lie%=%%all%%
  )
)
if %all% equ %num2% goto :show
goto :agn
:show
for /l %%a in (1 1 %input%) do (
  for /l %%b in (1 1 %input%) do (
    call set/p=%%h%%al%%b%%  <nul
    set "h%%al%%b="
  )
  echo.
)
goto :bgn
复制代码

作者: tyc 时间: 2009-4-2 16:19 标题: 我试试，化了一节课的时间才做出来的

 
program aa;
var
i,j,m,n:integer;
a:array [1..100,1..100] of integer;
begin
repeat
readln(n);
m:=n mod 2;
until m<>0;
for i:=1 to n do
  for j:=1 to n do a[i][j]:=0;
i:=2;j:=n div 2;
for m:=1 to n*n do
begin
  i:=i-1;j:=j+1;
  if (i=0) and (j<>n+1) then  i:=n;
  if (j=n+1) and (i<>0) then j:=1;
  if (a[i][j]<>0) or (i=0) and (j=n+1) then
  begin
    i:=i+2;
    j:=j-1;
  end;
  a[i][j]:=m;
end;
for i:=1 to n do
  begin
  for j:=1 to n do
   write(a[i][j]:5);
  writeln;
  end;
end.
复制代码

[ 本帖最后由 tyc 于 2009-4-2 16:20 编辑 ]

作者: lhjoanna 时间: 2009-4-2 18:43

Re:more
结果符合幻方的要求，代码也不错，在此基础上提些小建议(供参考)：
1、对于大于3的要求我觉得不必，因为1阶幻方也是幻方，只不过所含的元素只有一个而已，可以统一起来考虑；
2、对于输入的限制，兄所用的方法是判断最后一位是否奇数，对于要求不高的情况可以满足，但如果要求苛刻些，比如输入a3、12a5等情况，可能会出错。最好还是用完全匹配来限制输入；
3、对于算法的实现，我没有仔细的验证，应该没问题，毕竟结果正确，并且也符合了行++，列- -，到边的话首尾相接，元素已存在的话放到正下方等规则；
4、输出结果正确，再加上对齐就完美了。^_^

Re：tyc
不知兄用的什么语言，我还真没用过，不过我基本看懂了，一些语法的问题我就无从知晓了，不过算法是正确的。其实对于输出幻方来说，实现起来这样的高级语言比批处理容易些，因为数组类型是内置的，而批处理则需要自己构建一个类似的二维数组来方便操作；此题要求是用批处理来实现，所以希望兄闲暇时也考虑下用批处理来实现~不管怎么说，毕竟动了一番脑子，加分鼓励^_^

作者: more 时间: 2009-4-2 19:52

应版主的要求,再做一些修改吧:

@echo off
:bgn
set input=&set /p input=请输入一个单数(回车退出):&cls
if not defined input goto :eof
echo.%input%|findstr /v "^[0-9]*$" >nul&&(echo.请输入纯数字!!!&goto :bgn)
echo.%input:~-1%|findstr "[^13579]" >nul&&(echo.请输入单数!!!&goto :bgn)
set /a num1=(%input%*%input%+1)*%input%/2,num2=%input%*%input%
echo.%input%阶幻方各行,列以及对角线相加的和为:%num1%&echo.
set /a lie=%input%/2+1,hang=1,all=1
if %num2% gtr 99 (set h1l%lie%=  1) else (set h%hang%l%lie%= 1)
:agn
set /a hang-=1,lie+=1,all+=1
if %hang% lss 1 set hang=%input%
if %lie% gtr %input% set lie=1
if defined h%hang%l%lie% (set /a hang+=2,lie-=1)
call :duiqi
if "%hang%"=="1" (
  if "%lie%"=="%input%" (
    set /a hang+=1,all+=1
    call :duiqi
  )
)
if %all% geq %num2% goto :show
goto :agn
:show
for /l %%a in (1 1 %input%) do (
  for /l %%b in (1 1 %input%) do (
    call set/p=%%h%%al%%b%%  <nul
    set "h%%al%%b="
  )
  echo.&echo.
)
goto :bgn
:duiqi
if %num2% gtr 99 (
  if %all% lss 10 (
    set h%hang%l%lie%=  %all%
  ) else (
    if %all% lss 100 (
      set h%hang%l%lie%= %all%
    ) else (
      set h%hang%l%lie%=%all%
    )
  )
) else (
  if %num2% gtr 9 (
    if %all% lss 10 (
      set h%hang%l%lie%= %all%
    ) else (
      set h%hang%l%lie%=%all%
    )
  ) else (set h%hang%l%lie%= %all%)
)
复制代码

作者: tyc 时间: 2009-4-2 20:35 标题: 兄弟不才，用了其它语言

我用pascal，批处理写不出来，一急就用其它高级语言了，不过这一题是初中生的竞赛题。

[ 本帖最后由 tyc 于 2009-4-3 07:34 编辑 ]

作者: lhjoanna 时间: 2009-4-2 20:38

Re:more
呵，结果是可以对齐了，只是代码是不是繁了点。不需要在赋值的过程中多次调用duiqi，可以在赋值完毕后统一调整格式(包括1)。
在兄11楼代码基础上修改：

@echo off&setlocal enabledelayedexpansion
:bgn
echo.&set input=&set /p input=请输入一个单数(回车退出):
if not defined input goto :eof
cls
echo %time%&echo.
echo.%input%|findstr /v "^[0-9]*$" >nul&&(echo.请输入纯数字!!!&goto :bgn)
echo.%input:~-1%|findstr "[^13579]" >nul&&(echo.请输入单数...&goto :bgn)
set /a num1=(%input%*%input%+1)*%input%/2,num2=%input%*%input%
echo.%input%阶幻方各行,列以及对角线相加的和为:%num1%
set /a lie=%input%/2+1,hang=1,all=1
set h1l%lie%=1
:agn
set /a hang-=1,lie+=1,all+=1
if %hang% lss 1 set hang=%input%
if %lie% gtr %input% set lie=1
if defined h%hang%l%lie% (set /a hang+=2,lie-=1)
set h%hang%l%lie%=%all%
if "%hang%"=="1" (
   if "%lie%"=="%input%" (
     set /a hang+=1,all+=1
     call set h%%hang%%l%lie%=%%all%%
   )
)
if %all% geq %num2% goto :show
goto :agn

:show
call :duiqi
echo.
for /l %%a in (1 1 %input%) do (
  for /l %%b in (1 1 %input%) do (
    call set/p=%%h%%al%%b%% <nul
    set "h%%al%%b="
  )
  echo.
)
echo %time%&echo.
goto :bgn

:duiqi
for /l %%a in (1 1 !input!) do (
  for /l %%b in (1 1 !input!) do (
   if !h%%al%%b! lss 10 set "h%%al%%b= !h%%al%%b!"
   if !input! gtr 10  (
        if !h%%al%%b! lss 100 ( set "h%%al%%b= !h%%al%%b!")
   )
  )
)
复制代码

附：一点改进的建议
1、可以考虑不用二维变量来实现，直接用一维变量即可。即h%hang%l%lie%可以用类似h%var%来实现；这样做的好处有：1>精简代码，方便调试；2>提高效率，使用二维变量，在输出时就要2个for嵌套，时间复杂度会达到平方级，且变量的设立与空间分配也要多出一倍。
2、我用19阶幻方输出做为测试。二维变量的情况下运行时间为1.3~1.4s，而一维变量的情况下只需要0.4~0.5s。虽然不同机子上时间不相同，但同一台机子上，同种情况下的对比结果还是能说明一些问题的。

[ 本帖最后由 lhjoanna 于 2009-4-2 20:44 编辑 ]

作者: 随风 时间: 2009-4-3 10:09

奇数阶幻方的构造方法(楼梯法)。
把1(或最小的数)放在第一行正中；
按以下规律排列剩下的n*n-1个数：
　　1)每一个数放在前一个数的右上一格；
　　2)如果这个数所要放的格已经超出了顶行那么就把它放在底行，仍然要放在右一列；
　　3)如果这个数所要放的格已经超出了最右列那么就把它放在最左列，仍然要放在上一行；
　　4)如果这个数所要放的格已经超出了顶行且超出了最右列那么就把它放在前一个数的下一行同一列的格内；
　　5)如果这个数所要放的格已经有数填入，处理方法同4)。

@echo off
:start
setlocal enabledelayedexpansion
echo.&set /p n= 请输入一个奇数 &cls
set /a m=n/2+1,h=1,c=n*n,he=(n*n+1)*n/2
echo  !n! 阶幻方各行,列以及对角线相加的和为: %he%&echo.
set .1-!m!=1
for /l %%a in (2 1 !c!) do call :loop %%a
for /l %%a in (0 1 9) do set c=!c:%%a= %%a !
for %%a in (!c!) do set /a j+=1
for /l %%a in (1 1 !n!) do (
   set "num="
   for /l %%b in (1 1 !n!) do (
      set "var=                                !.%%a-%%b!"
      set "num=!num! !var:~-%j%!"
)
   echo.!num!
)
endlocal&goto start
:loop
   set /a h-=1,m+=1
   if !h! lss 1 set /a h=n
   if !M! gtr !n! set /a m=1
   if defined .!h!-!m! (
      if !qh! equ !n! (set /a h=2) else set /a h=qh+2
   set /a qh=h-1,m=qm-1
   goto loop
)
   set ".!h!-!m!=%~1"
   set /a qh=h,qm=m
goto :EOF
复制代码

[ 本帖最后由随风于 2009-4-3 10:46 编辑 ]

作者: lhjoanna 时间: 2009-4-3 11:57

Re：随风
从兄的代码中又学了不少，变量清空操作只需要endlocal就可以代替几行语句；并且输出时赋值给变量，按行输出确实比按个输出节省了不少时间(特别是阶数很高的情况下)；兄能否考虑下用一维的变量来实现，这应该也是提升效率的一个方法。

作者: 随风 时间: 2009-4-4 16:20 标题: 回复 18楼的帖子

不懂什么是一维变量，代码一写好就发现效率是个大问题，一直没有办法解决，这种幻方构造方法是临时在网上找的，lhjoanna兄是否还有更好的算法？拿来分享一下。又或者我的代码还可以如何改进，请指点。。

作者: lhjoanna 时间: 2009-4-4 19:11

呵，指点谈不上，说讨论更贴切些~~说实话，一维变量是我编出来的，官方没有这样的说法,举个例子，类似.%%a%%b我称它为二维的，而对比下 .%%a就是一维了。感觉这样说简炼些^_^
我的算法也就是兄所说的楼梯法，更确切些叫罗伯法。这是目前比较容易的构造方法了。我也一直在思考效率的提高问题，在目前的这个算法下，我也只想到把变量改为一维(暂称)的可以提高一些效率，我的代码在下面，还请兄帮忙测试或者改进下！

@echo off
:begin
 setlocal enabledelayedexpansion
 color 0c
 cls
 echo.&echo  本程序功能为输出n阶幻方！
 echo.&echo  所谓n阶幻方：1-n^^2个数排为n行n列；
 echo.&echo  要求：横、竖、对角线相加和相同。
 echo.&echo  算法：loubere法
 echo.&set /p "n= 请输入方阵阶数(奇数):"
 echo !n!|findstr "^[1-9]*$">nul || (echo.& echo  Non-Numberic & pause>nul & goto begin)
 set /a a=n%%2
 if !a! equ 0 echo.&echo  Non-Odd & pause>nul & goto begin
 cls
 echo.&echo %time%
 set /a "sum=(1+n*n)*n/2"
 echo.&echo  !n!阶幻方横、竖、对角线相加和为 !sum!
 echo.
 set /a square=n*n,i=1,j=(n+1)/2,loc=j
 set ".!loc!=1"
 for /l %%i in (2 1 !square!) do (
     set /a "i=(i-1)%%n,j=(j+1)%%n"
     if !i! equ 0 set /a i=n
     if !j! equ 0 set /a j=n
     set /a "loc=n*(i-1)+j"
     if defined .!loc! ( 
         set /a "i=(i+2)%%!n!,j=(j-1)%%n"  
         if !i! equ 0 set /a i=n
         if !j! equ 0 set /a j=n
         set /a "loc=n*(i-1)+j"
     )
     set .!loc!=%%i
  rem echo  i:!i!,j:!j!,loc:!loc!,.loc:%%i
 )

 call :unify

 for /l %%i in (1 1 !square!) do (
     set /a "c=%%i%%n"
     set "result=!result! !.%%i!"
     if !c! equ 0 echo !result!&set "result="
 )
echo.&echo %time%&echo.
 pause>nul&endlocal&goto begin

:unify
 for /l %%i in (1 1 !square!) do (
     if !.%%i! lss 10 set ".%%i= !.%%i!"
     if !n! gtr 10  (
        if !.%%i! lss 100 ( set ".%%i= !.%%i!")
     )
 )
 goto :eof
复制代码

作者: 随风 时间: 2009-4-4 21:58

仔细琢磨了兄的代码。效率及算法都比我的强多了。
最不懂的一句 set /a "loc=n*(i-1)+j" 应该也是精华吧。
不过有一处不太明白，好像也不太容易说明白。举个例吧
a 1 c
3 e f
g h 2
此时 4 应该放在 b 的位置，也就是 1 的位置，但位置被 1 占了，
所以 4 就应该放在前一个数的下一行同一列的格内，也就是 g 位，
问题来了，不知道幻方会不会有这种情况出现，就是 g 位此时也已经被别的数占了，
如果这种情况存在，那么按我的理解就应该放在g的下面。
同样，如果存在这种情况，那么兄的代码似乎没对这种反复的情况作处理啊。

作者: lhjoanna 时间: 2009-4-5 00:59

要存储n^2个数，就要建立n^2个变量，我是用.1-.n^2来表示这n^2个数的，所以set /a "loc=n*(i-1)+j这句也就是计算当前的数在幻方整个n^2个数中的位置。这样也就代替了用.%%a%%b构建行、列的情况。
兄说到的那个问题，我想这种情况是不可能出现的，目标数的下一行对应的数不可能被占用。我想数学家罗伯在构思这种幻方构造法时如果发现目标数下一行对应的数会出现被占用的可能，那么在构造规则中就会声明这种情况的处理办法了。我仔细观察了19阶幻方，用此法构建确实不会出现上述情况，可能数学能力有限，我很难用数学语言严谨的表达出来。不过设想下19阶幻方第一行与最后一行相接，第一列与最后一列相接，会出现一个球，那么从1开始连线，你会发现1-19的连线划过的区域是此球最大的圆周，并且假设单位为1，则此圆的周长就是19单位，而此连线只经过了18单位，因为在继续到第19单位时，此位置已经有1占了。所以转到第二个圆周，此第二个圆周与第一个圆周之间的夹角为(360/19)°，这样连续转19次，也就满了360°，即画了19个最大圆，并且每个圆都是不封闭的，每个圆都不相交(因为每将要到相交的地方，就会跳到下一个圆周)，这样看来下一个圆周的第一个位置是永远不会被占的。拿19阶幻方为例，从1-361相连，你会发现是一条不间断的空间曲线，并且361的下一个就是1。361与1衔接，成功的构造了一个球体。只是这个球体的表面是不光滑的，有间隔的凹陷。在此构造过程中，幻方的各个元素在逆时针旋转，而构成的圆周(纵向来看)是顺时针转动的。由此猜想：抛开球体看，只看1-n^2的连线，阶数越高，此连线也接近球体。既然如此接近球体，那么此曲线的方程(坐标由幻方的各个元素构成)和球体的方程(x-a)²+(y-b)²+(z-c)²=R²有千丝万缕的联系。又一猜想：说不定幻方的方程(猜测：f(x,y,z)=n²)当n(阶数)趋于无穷时，幻方的方程也就等于球的方程(或类球方程)。
呵，大晚上的容易乱想，想了一堆，还没有在网上找到类似支持的理论，只做一种猜测吧！

作者: 随风 时间: 2009-4-5 02:58 标题: 回复 22 楼 lhjoanna 兄

多谢兄的耐心讲解，认真看了看，说实话但也只看懂个大概，不过也受益匪浅了。
既然不存在目标数的下一行对应的数被占用的情况，那么代码可以修改一下提高效率。
我17楼代码之所以效率低下应该是因为call太多，loop就是为了处理这种情况，现在看来是多余的。
:

@echo off
:start
setlocal enabledelayedexpansion
echo.&set /p n= 请输入一个奇数 &cls
set /a m=n/2+1,h=1,c=n*n,he=(n*n+1)*n/2
echo  !n! 阶幻方各行,列以及对角线相加的和为: %he%&echo.
set .1-!m!=1
for /l %%a in (2 1 !c!) do (
   set /a h-=1,m=m%%n+1
   if !h! equ 0 set /a h=n
   if defined .!h!-!m! set /a h=qh%%n+1,m=qm
   set ".!h!-!m!=%%a"
   set /a qh=h,qm=m
)
for /l %%a in (0 1 9) do set c=!c:%%a= %%a !
for %%a in (!c!) do set /a j+=1
for /l %%a in (1 1 !n!) do (
   set "num="
   for /l %%b in (1 1 !n!) do (
      set "var=               !.%%a-%%b!"
      set "num=!num! !var:~-%j%!"
    )
    echo.!num!
)
endlocal&goto start
复制代码

作者: lhjoanna 时间: 2009-4-5 10:33

呵，我上面写的一些也只是自己的猜测而已，没有一些理论的支持。说实话，我之前对兄的那段loop循环也是一知半解，不过现在明白了，这样修改以后效率提高很多啊，比我的效率也要高一点。这也就说明了我对于一维变量提高效率的说法是不准确的。看来还要自己多研究，不能仅凭想法臆断！多谢兄~

作者: terse 时间: 2009-4-6 10:28

凑热闹马步的
修改前面的set ".!h!-!m!=1"这句放在FOR里面

@echo off
:start
setlocal enabledelayedexpansion
echo.&set /p n= 请输入一个奇数 &cls
set /a m=n/2+1,c=n*n,he=(n*n+1)*n/2
echo  !n! 阶幻方各行,列以及对角线相加的和为: %he%&echo.
for /l %%i in (1 1 !c!) do (
   set/a i=%%i%%n
   if !i! equ 1 (set/a h=h%%n+1) else set/a h=h%%n+2,m=m%%n+1
   if !h! gtr !n! set h=1
      set ".!h!-!m!=%%i"
)
for %%i in (0 1 10) do if not "!c:~%%i,1!"=="" set /a j=%%i+2&set "k=!k! "
for /l %%a in (1 1 !n!) do (
   set "var="
   for /l %%b in (1 1 !n!) do (
      set "str=!k!!.%%a-%%b!"
      set "var=!var! !str:~-%j%!"
    )
    echo.!var:~1!
)
pause
endlocal&goto start
复制代码

[ 本帖最后由 terse 于 2009-4-6 11:07 编辑 ]

作者: 小勇12 时间: 2009-4-11 23:52

真是厉害，呀向大家学习

作者: xxx 时间: 2009-4-12 14:03

嗯,我承认我是迟到了...而且还不是batch的...
是python的:

#09/4/4/12
def make_list(num):
    n,k,b,c = num,0,num/2,num**2
    listx = []
    for x in xrange(n):
        listx.append([])
        for _x in xrange(n):
            listx[x].append(False)
    for _x in xrange(c):
        if((_x+1)==1):
            listx[k] = 1

        elif((_x+1)%n==1):
            k = k+1
            if(k>n-1):
                k = k-n
            listx[k] = _x+1
        else:
            k = k+2
            b = b+1
            if(b>n-1):
                b = 0
            if(k>n-1):
                k = k-n
            listx[k] = _x+1
    for y in xrange(n):
            print(listx[y])

def start():
    print("Input a number:")
    x = input()
    if(x%2==0):
        print("Wrong.")
    else:
        make_list(x)
 
if __name__ == "__main__":
     start()
复制代码

[ 本帖最后由 xxx 于 2009-4-12 14:05 编辑 ]

作者: lhjoanna 时间: 2009-4-20 19:43

下午偶然从MATLAB上找到了构造幻方的源代码，是用MATLAB程序设计语言实现的(基于C语言设计)，可以生成阶数不限的幻方。下午把此算法用批处理实现了。下面附上批版代码以及magic(n)函数源代码。

@echo off
:begin
 setlocal enabledelayedexpansion
 set rank=
 echo.&set /p "rank=请输入幻方阶数:"
 set /a remainder=rank%%2
 if !remainder! equ 1 (
    call :odd !rank!
 ) else (
     set /a remainder=rank%%4
     if !remainder! equ 0 ( 
        call :even_4
     ) else call :even_2
   )

rem --------------奇数阶幻方------------------

:odd
 set rank=%1
 call :create
 for /l %%i in (1 1 !rank!) do (
     for /l %%j in (1 1 !rank!) do (
         set /a $%%i%%j="(.%%i%%j+.%%j%%i-(rank+3)/2+rank)%%rank"
         set /a #%%i%%j="(.%%i%%j+.%%j%%i*2-2+rank)%%rank"
         set /a _%%i%%j="rank*$%%i%%j+#%%i%%j+1"
     )
  )
 if not "%~2" equ "" goto :eof
 call :output
 endlocal&goto :begin

rem -------------偶数阶幻方(4整除)---------------

:even_4
 call :create
 set num=0
 for /l %%i in (1 1 !rank!) do (
     for /l %%j in (1 1 !rank!) do (
         set /a "a=(.%%i%%j%%4)/2,b=(.%%j%%i%%4)/2"
         if !a! equ !b! ( set "_%%i%%j=1" ) else set "_%%i%%j=0"
         set /a "num+=1,n=rank*rank+1"
         set /a #%%i%%j=!num!
         if !_%%i%%j! equ 1 (set /a _%%i%%j=n-#%%i%%j) else set _%%i%%j=!#%%i%%j!
     )
 )
 call :output
 endlocal&goto :begin

rem --------------偶数阶幻方(2整除)--------------

:even_2
 set /a p=rank/2,q=rank,p1=p+1
 call :odd !p! OK
 set rank=!q!
 call :rearrange 1 !p! !p1! !rank! 2
 call :rearrange !p1! !rank! 1 !p! 3
 call :rearrange !p1! !rank! !p1! !rank! 1
 call :transpos !p!
 if !rank! equ 2 (
   call :output
   endlocal&goto :begin
 )
 for /l %%i in (1 1 !p!) do set "var_i=!var_i! %%i" 
 set /a k=(rank-2)/4,m=rank-k+2
 for /l %%i in (1 1 !k!) do set "var_j=!var_j! %%i"
 for /l %%i in (!m! 1 !rank!) do set "var_j=!var_j! %%i"
 call :exchange "!var_i!" "!var_j!"
 set /a i=k+1
 set "j=1 !i!"
 call :exchange "!i!" "!j!"
 call :output
 set i=
 set j=
 set var_i=
 set var_j=
 endlocal&goto :begin


rem -------------以下为子函数-----------------

:create
 set /a rank_2=rank*rank,i=1,j=1
 for /l %%i in (1 1 !rank_2!) do (
       set .!i!!j!=!j!
       set /a j+=1
       if !j! gtr !rank! set j=1&set /a i+=1
 )
 goto :eof

:output
  call :append !rank!
  for /l %%i in (1 1 !rank!) do (
     for /l %%j in (1 1 !rank!) do set result=!result! !_%%i%%j:~-3!
     echo.!result!&set result=
  )
  goto :eof

:rearrange
 set /a p2=%5*p*p,i=1,j=1
 for /l %%i in (%1 1 %2) do (
     for /l %%j in (%3 1 %4) do (
         set /a _%%i%%j=_!j!!i!+p2
         set /a j+=1
     )
     set /a "i+=1,j=1"
 )
 goto :eof

:exchange
 for %%i in (%~1) do (
     for %%j in (%~2) do (
         set /a i=%%i+p
         set tmp=!_%%i%%j!
         call set _%%i%%j=%%_!i!%%j%%
         set _!i!%%j=!tmp!
     )
 )
 goto :eof

:transpos
 for /l %%i in (1 1 %1) do (
     for /l %%j in (%%i 1 %1) do (
         if not %%i equ %%j (
            set tmp=!_%%i%%j!
            set _%%i%%j=!_%%j%%i!
            set _%%j%%i=!tmp!
         )
     )
 )
 goto :eof

:append
  for /l %%i in (1 1 %1) do (
     for /l %%j in (1 1 %1) do (
         set "_%%i%%j=   !_%%i%%j!"
     )
  )
  goto :eof
复制代码

函数magic(n);

function M = magic(n)
%MAGIC Magic square.
% MAGIC(N) is an N-by-N matrix constructed from the integers
% 1 through N^2 with equal row, column, and diagonal sums.
% Produces valid magic squares for all N > 0 except N = 2.

% Copyright 1984-2002 The MathWorks, Inc.
% $Revision: 5.15 $ $Date: 2002/04/15 03:44:23 $

% Historically, MATLAB's magic was a built-in function.
% This M-file uses a new algorithm to generate the same matrices.

n = floor(real(double(n(1))));

% Odd order.
if mod(n,2) == 1
[J,I] = meshgrid(1:n);
A = mod(I+J-(n+3)/2,n);
B = mod(I+2*J-2,n);
M = n*A + B + 1;

% Doubly even order.
elseif mod(n,4) == 0
[J,I] = meshgrid(1:n);
K = fix(mod(I,4)/2) == fix(mod(J,4)/2);
M = reshape(1:n*n,n,n)';
M(K) = n*n+1 - M(K);

% Singly even order.
else
p = n/2;
M = magic(p);
M = [M M+2*p^2; M+3*p^2 M+p^2];
if n == 2, return, end
i = (1:p)';
k = (n-2)/4;
j = [1:k (n-k+2):n];
M([i; i+p],j) = M([i+p; i],j);
i = k+1;
j = [1 i];
M([i; i+p],j) = M([i+p; i],j);
end

分三种情况，奇数、偶数、双偶数。MATLAB源代码中调用了一些函数，可以在帮助文档中找到。
附：
在MATLAB软件环境下用命令调用magic(n)，效率很高，上千阶的幻方也只需要2-3秒；可用批实现的代码效率却不尽如人意，比上面几楼各位的代码还要低些，可能是大量的变量赋值运算影响了效率吧；大家再来优化下代码，看哪里还有提升的空间。

作者: 随风 时间: 2009-4-20 21:11

想通过代码来了解算法太难了，大致看了下兄的代码流程，只发现一处影响代码效率的地方。
批处理的运行效率，个人认为 set 或 set /a 并不会太影响，关键是看代码的设计，for的循环次数尤其是嵌套循环，再就是call若在for循环中有call则一定会使效率大打折扣。
建议改进的地方：
:exchange 标签下
call set _%%i%%j=%%_!i!%%j%%
改为 for %%a in (!i!) do set _%%i%%j=!_%%a%%j!

作者: lhjoanna 时间: 2009-4-21 01:35

按照兄的建议修改了下，感觉效率还有待提高。批代码中大量操作都用于矩阵的赋值与运算，而高级语言中数组则作为内嵌类型，而MATLAB更是以矩阵作为基本的操作单元，所以对矩阵进行线性运算耗费时间很低，可能这也就是其效率高的原因吧。
MATLAB中有很多经典算法，并且许多用于数值分析的算法都是世界一流的算法，效率自然很高，许多的源代码都是可以自己修改的，也很值得学习借鉴。我现在也就只能看懂整个程序的流程，至于为什么如此构造可以实现(以幻方为例)我还想不明白，这确实需要很强的数学背景了！

作者: Lumiere 时间: 2009-7-10 16:17 标题: 凑热闹

好早之前看到这个帖子了，在这个帖子还没有回复的时候就开始研究写了代码，可是错误不少，后来因为工作的事就一直没时间去斟酌。现在有时间了，仔细看了下，终于改出来了，本来挺高兴的，结果上来一看，前辈们早就把代码反复推敲了N久了，而且问题的本质已经从对症下药给出合理的解决代码上升倒了代码效率高下的研究，这是本人不敢企及的。本来不打算把代码贴上来了，可是本人后来输入较大点的数字的时候，又出现一个问题，就是“已经达到最大的setlocal递归层”但是似乎幻方的生成还是没有影响，数字也都对，我不太明白这个错误怎么长生的。老调重弹，麻烦前辈们给解释下，不胜感激！
我写的代码如下：

@echo off
:start
set /p n=Please input your odd integer:
set /a p=n%%2
if %p% equ 0 echo Input error!&&goto start

set /a i=%n%
set /a t=(%n%+1)/2
set /a a%t%_%n%=1,temp=1,m=n-1,p=n
:repeat
set /a p-=1
if %p% lss 0 goto array
for /l %%a in (1 1 %m%) do (
   setlocal enabledelayedexpansion
   if !t! gtr %n% set /a t=1
   if !i! gtr %n% set /a i=1
   set /a s=!t!+1,q=!i!+1
   if !s! gtr %n% set /a s=1
   if !q! gtr %n% set /a q=1
   set /a a!s!_!q!=a!t!_!i!+1,t+=1,i+=1
   set /a temp+=1
   if !temp! equ %n% (
         set /a temp=1,tmp=a!s!_!q!,q-=1,i-=1
         if !q! equ 0 set /a q=n 
         set /a a!s!_!q!=tmp+1
         goto repeat
)    
)
pause
:array
echo Now behold the powerful Magic Sqaure^^!:
set /a a!t!_!n!=1
for /l %%c in (!n! -1 1) do (
   for /l %%d in (1 1 !n!) do (
              set /a result=a%%d_%%c
              set /p=!result!<nul       
)
echo.
)
pause>nul
复制代码

如上，输入7以上的奇数就会出现那个问题，没弄明白，只好请教诸位了。

作者: Lumiere 时间: 2009-7-10 17:14

晕菜啊，这么久也没人来指点一下啊，再等~

作者: zhouyongjun 时间: 2009-7-10 17:21

变量延迟不要放在for里面

作者: Batcher 时间: 2009-7-10 17:49 标题: 回复 31楼的帖子

“已经达到最大的setlocal递归层”的问题，请参考：
http://bbs.bathome.net/thread-1224-1-3.html

作者: Lumiere 时间: 2009-7-11 00:40 标题: 回复 33楼的帖子

呵呵，就要这种效果，一句话就解决，我把变量延迟放到外面就不会提示那个错误了。再去好好看看这个问题的描述，多谢啦！

作者: Batcher 时间: 2009-7-11 00:48 标题: 回复 35楼的帖子

确实应该好好看看，也许你会发现不把变量延迟扩展放在for里面有时可能带来更多的问题^_^

作者: Lumiere 时间: 2009-7-11 12:03 标题: 回复 36楼的帖子

那个帖子我看了，上面说最好把变量延迟扩展申明放在for结构内，哪里需要哪里申明，然后再结束，那我的问题不就没办法解决了么？我试过了，在for里申明然后在结构结束之前用endlocal结束，结果还是会出现那个恼人的错误提示。但是我照33楼兄弟的说法把申明放到for结构之前，问题就没有了。到底哪个是对的？如果要放在for里面的话，如何把我的问题解决？

作者: keen 时间: 2009-7-11 13:44 标题: 回复 37楼的帖子

把setlocal enabledelayedexpansion放在for语句里面是为了防止读取某些含有叹号！字符串时，丢失叹号！字符。

而你的这个算幻方的题，可能不涉及到叹号！字符串的处理。所以可以把setlocal enabledelayedexpansion放在for语句外面防止超过最大递归层。

但当你处理一些含有叹号！字符串时，应该注意把setlocal enabledelayedexpansion放在for语句内部，防止丢失。

这就叫 “随机应变”，就是看情况选择setlocal enabledelayedexpansion的位置。

欢迎光临批处理之家 (http://www.bathome.net/)