批处理之家 - Powered by Discuz! Board

标题: [文本处理] 求助批处理中按指定格式输出当前日期并计算取上个月第一天？ [打印本页]

作者: kelaisile 时间: 2009-3-30 19:08 标题: 求助批处理中按指定格式输出当前日期并计算取上个月第一天？

比如说。我想取当前日期按如下格式输出
分别为：
2009-03-30
20090330
只取月份:
200903
当月第一天:
2009-03-01
下月第一天:
2009-04-01

请高手赐教！！

作者: Batcher 时间: 2009-3-30 19:42

开始
运行
cmd
echo %date% %time%
结果贴出来看看

Q: 怎样把CMD窗口里的结果复制出来？
A: 右键单击CMD窗口的标题栏->"属性"->"选项"->勾选"快速编辑模式"->然后在CMD窗口用鼠标左键选中想要拷贝的内容->在选中的内容上单击鼠标右键->粘贴到文本文件中即可

作者: kelaisile 时间: 2009-3-30 19:51

什么啊？我说按上面的格式输出

作者: zqz0012005 时间: 2009-3-30 20:31

让你把结果贴出来看看都不行吗？
知道你的情况才好对症下药。

作者: Batcher 时间: 2009-3-30 20:39 标题: 回复 4楼的帖子

什么啊？我说按2楼的方法把结果贴出来看看

作者: kelaisile 时间: 2009-3-30 20:47

C:\>echo %date% %time%
2009-03-30 星期一 20:46:07.42

我会了。呵呵
echo %date:~0,10%

但是取上个月第一天怎么做呢？

作者: Batcher 时间: 2009-3-30 21:53 标题: 回复 6楼的帖子

@echo off
rem set date=2009-03-30 星期一
set ThisYear=%date:~0,4%
set ThisMonth=%date:~5,2%
set ThisDay=%date:~8,2%
call :DateToDays %ThisYear% %ThisMonth% %ThisDay% ThisDays
set /a DstDays=%ThisDays%-1%ThisDay%+100
call :DaysToDate %DstDays% DstYear DstMonth DstDay
echo 上个月第一天：%DstYear%-%DstMonth%-01
pause
goto :eof

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF
复制代码

欢迎光临批处理之家 (http://www.bathome.net/)

Powered by Discuz! 7.2