批处理之家 - Powered by Discuz! Board

标题: [系统相关] [已解决]能否使用批处理在IE浏览器兼容性视图设置里添加指定站点 [打印本页]

作者: 左眉 时间: 2015-9-17 14:40 标题: [已解决]能否使用批处理在IE浏览器兼容性视图设置里添加指定站点

本帖最后由 pcl_test 于 2017-5-29 23:21 编辑

已解决：
我要封装系统，发现第一次进系统后，IE有个第一次使用的推荐设置，然后兼容性视图设置的站点就全不见了，然后找一位大侠的代码如下
可是完全看不懂，如果需要添加自己需要的站点如192.168.97.60 之类的我该怎么添加啊还有怎么设置成执行完批处理后自动关闭
谢谢各个大大了很急

以下是我把7daysinn.cn网站设置兼容性的bat源码，你参考下

@ECHO OFF
color 2f
mode con lines=20 cols=50
title 一键解决MT兼容性问题V1.0 By:小智
> "%Temp%.\DefOpen.reg" ECHO Windows Registry Editor Version 5.00
>>"%Temp%.\DefOpen.reg" ECHO.
>>"%Temp%.\DefOpen.reg" ECHO [HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\BrowserEmulation]
>>"%Temp%.\DefOpen.reg" ECHO "IntranetCompatibilityMode"=dword:00000001
>>"%Temp%.\DefOpen.reg" ECHO "MSCompatibilityMode"=dword:00000001
>>"%Temp%.\DefOpen.reg" ECHO.
>>"%Temp%.\DefOpen.reg" ECHO [HKEY_CURRENT_USER\Software\Microsoft\Internet Explorer\BrowserEmulation\ClearableListData]
>>"%Temp%.\DefOpen.reg" ECHO "UserFilter"=hex:41,1f,00,00,53,08,ad,ba,01,00,00,00,34,00,00,00,01,00,00,00,\
>>"%Temp%.\DefOpen.reg" ECHO   01,00,00,00,0c,00,00,00,60,af,c3,07,08,f8,cf,01,01,00,00,00,0b,00,37,00,64,\
>>"%Temp%.\DefOpen.reg" ECHO   00,61,00,79,00,73,00,69,00,6e,00,6e,00,2e,00,63,00,6e,00
>>"%Temp%.\DefOpen.reg" ECHO.
START /WAIT REGEDIT /S "%Temp%.\DefOpen.reg"
START /WAIT REGEDIT /S "%Temp%.\DefOpen.reg"
DEL "%Temp%.\DefOpen.reg"
taskkill /f /t /im iexplore.exe 2>nul
echo ===============================================
echo ^|                                             ^|
echo ^|                                             ^|
echo ^|         √. MT兼容性已修复完毕!              ^|
echo ^|                                             ^|
echo ^|        请先关闭浏览器再打开报MT即可         ^|
echo ^|                                             ^|
echo ^|                               By:小智       ^|
echo ===============================================
pause
复制代码

可是

作者: DAIC 时间: 2015-9-17 14:52

怎么设置成执行完批处理后自动关闭

把 pause 命令删掉

作者: 左眉 时间: 2015-9-17 15:47

把 pause 命令删掉
DAIC 发表于 2015-9-17 14:52

最后一个单词删掉是吧谢谢啊可是上面的问题谁来解答一下啊

作者: pcl_test 时间: 2015-9-17 19:13

UserFilter"=hex:后面的16进制就是站点信息，然某些信息不好解读
一种方法，先在IE浏览器手动添加站点，然后运行下面代码的批处理，生成的另一个批处理就是可作为自动修改设置的批处理

@echo off
if "%~n0" equ "兼容性视图设置" echo;重命名后再次运行&ping /n 2 0 >nul& exit
>nul reg export "HKCU\Software\Microsoft\Internet Explorer\BrowserEmulation\ClearableListData" "%tmp%\$.reg" /y
>"%tmp%\$.txt" more +7 "%~f0"
(type "%tmp%\$.txt"&type "%tmp%\$.reg")>兼容性视图设置.bat
echo;完成，运行生成的批处理文件即可修改兼容性视图设置
ping /n 2 0 >nul& exit
@echo off
>"%tmp%\t.reg" more +5 "%~f0"
regedit /s "%tmp%\t.reg"
echo;兼容性视图设置已修改，请重启IE浏览器
ping /n 2 0 >nul& exit
复制代码

作者: 左眉 时间: 2015-9-18 15:08

本帖最后由左眉于 2015-9-18 15:22 编辑

UserFilter"=hex:后面的16进制就是站点信息，然某些信息不好解读
一种方法，先在IE浏览器手动添加站点，然 ...
pcl_test 发表于 2015-9-17 19:13

版主出手，一招搞掂！！谢谢！顺便帮我写一个 受信任站点的安全级别设到最低，然后添加站点的 bat吗？跟之前的一样的我设置好站点，拉倒最低安全级别，然后用你的批处理导出一个批处理?
对不起，做伸手党了小白一个

作者: Speed乄Jay 时间: 2018-7-30 20:22

回复 4# pcl_test

版本厉害，正好用到，谢谢。

作者: 一足鸟 时间: 2020-8-6 10:04

谢谢！到别台电脑试试……谢谢！

欢迎光临批处理之家 (http://www.bathome.net/)

Powered by Discuz! 7.2