for /f "delims=" %%a in ('dir /b /s .\*.txt') do (
copy  "%%a" .\new /-y
)
复制代码

1<1/* :
@echo off
md d:\new 2>nul
for /f "tokens=1*delims=/" %%i in ('dir /b /s /a-d *.*^|cscript //Nologo //E:jscript "%~f0"')do (
    copy "%%j" "d:\new\%%i"
)
pause & exit
*/

var map = {};
var str = WScript.StdIn.ReadAll().replace(
    /.+\\(.+)\r\n/g,
    function(a,b){
        var s = '', n = b.toLowerCase();
        map.hasOwnProperty(n)?(map[n]++,s='('+map[n]+')'):map[n]=0;
        b = b.replace(/(.+?)(\.[^.]+|)$/, '$1'+s+'$2');
        return(b + '/' + a);
    }
)
WScript.Echo(str)
复制代码

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /b /s *.txt') do (
    set "fn=%%~nxa"
    set "fn=!fn: =_!"
    if defined #!fn! (
        for %%i in (!fn!) do copy "%%a" "new\%%~na(!#%%i!)%%~xa"
    ) else copy "%%a" "new\"
    set/a #!fn!+=1
)
pause
复制代码

@echo off
for /r %%i in (*) do (
    set "strName=%%~nxi" & set "n="
    call :CP "%%i"
)
pause & exit

:CP
if not exist "d:\new\%strName%" copy "%~1" "d:\new\%strName%" & goto :EOF
if exist "d:\new\%strName%" set /a n+=1
set "strName=%~n1(%n%)%~x1"
goto :CP
复制代码

@echo off & setlocal enabledelayedexpansion    
if not "%~1"==":" (
    md d:\new 2>nul
    for /f "tokens=1*delims=/" %%i in ('"%~f0" :^|sort') do (
        if /i "%%i"=="!strName!" (
            set /a n+=1
            copy "%%j" "d:\new\%%~ni(!n!)%%~xi"
        ) else (
            set "n="
            copy "%%j" d:\new\
        )
        set "strName=%%i"
    )
    pause
) else (
    for /r %%i in (*) do echo %%~nxi/%%i
)
复制代码

@echo off
set f1=d:\from
set f2=d:\to

cd /d "%f1%"
for /f "delims=" %%i in ('2^>nul dir /b /s /a-d *.txt *.rar') do (
	set f=%%i
	set nx=%%~nxi
	set x=%%~xi
	set n=1
	call :1 "%%~nxi"
)
pause
exit

	:1
	for /f "tokens=1* delims=(" %%a in ("%~1") do (
		if "%%b" neq "" (
			call :1 "%%b"
		) else (
			for /f "tokens=* delims=0123456789" %%c in ("%%a") do (
				if "%%c" equ ")%x%" (
					call set "str=%%nx:(%%a=%x%%%"
				) else (
					set "str=%nx%"
				)
				setlocal enabledelayedexpansion
				for /f "delims=" %%e in ("!str!") do (
					endlocal
					call :2 "%%e"
				)
			)
		)
	)
	exit /b

	:2
	set /a n+=1
	if not exist "%f2%\%~n1%~x1" (
		copy "%f%" "%f2%\%~n1%~x1"
	) else if not exist "%f2%\%~n1(%n%)%~x1" (
		copy "%f%" "%f2%\%~n1(%n%)%~x1"
	) else (
		goto :2
	)
	exit /b
复制代码

@echo off &set "d1=c:\源目录" &set "d2=d:\目标目录"
pushd "%d2%"
for /f "delims=" %%a in (' dir /b/s/a-d "%d1%\*.txt" ') do (
	if not exist "%%~nxa" (copy "%%a") else (
		set/a "n=1" &set "F=%%a" &set "nF=%%~na" &set "xF=%%~xa"
		(call :copy#n)
	)
)	
popd &pause &exit/b
:copy#n
	if exist "%nF%(%n%)%xF%" (set/a "n+=1" &goto :copy#n)
	copy "%F%" "%nF%(%n%)%xF%" &exit/b
复制代码

$sour = ".\old"
$dest = ".\new"
$ext = "*.txt"

Get-ChildItem -Path $sour -Filter $ext | ForEach-Object {
	if ( -Not (Test-Path ( Join-Path  -Path $dest  -ChildPath $_.Name )) ) {
		Copy-Item  -Path $_.FullName  -Destination ( Join-Path -Path $dest -ChildPath $_.Name )
	} else {
		$i = 0
		do {
			$i++
		}
		while ( Test-Path ( Join-Path -Path $dest -ChildPath ($_.BaseName + $i + $_.Extension) ) )
		Copy-Item  -Path $_.FullName  -Destination ( Join-Path -Path $dest -ChildPath ($_.BaseName + $i + $_.Extension) )
	}
	
}
复制代码

每家都有几曲乡愁，彼此彼此，一方水土养一方人，苦乐痛痒其实一脉相通...