批处理之家 - Powered by Discuz! Board

标题: 批处理中去掉数字左面0的四种方法 [打印本页]

作者: irresolute 时间: 2009-3-7 20:21 标题: 批处理中去掉数字左面0的四种方法

@echo off
rem 看到两种去掉左面0的方法
set tt=001234
for /f "delims=0" %%i in ("%tt%") do (
echo %%i
)
echo ----
set /a "tt=1001234 %%1000000"
echo %tt%
rem （1000000+1234）/1000000=1234
echo ----
set tt=%tt:00=%
echo %tt%
echo ----
set tt=001234
set tt=%tt:~2%
echo %tt%
pause>nul

[ 本帖最后由 irresolute 于 2009-3-7 20:58 编辑 ]

作者: Batcher 时间: 2009-3-7 20:32

for /f "delims=0" %%i in ("%tt%") do (
echo %%i
)

set tt=%tt:00=%
echo %tt%

遇到中间有零的情况，以上两种方法不可用。

set tt=001234
set tt=%tt:~2%
echo %tt%

上面这种方法几乎没有什么实用意义。

set /a "tt=1001234 %%1000000"
echo %tt%
rem （1000000+1234）/1000000=1234

上面的这种数学运算的方法需要事先确保数字不超过批处理允许的上限。

还有一个楼主没有收录的方法，那就是从左开始逐位判断，虽然比较麻烦，但是却相对通用。

作者: yslyxqysl 时间: 2009-3-7 20:42

http://www.bathome.net/viewthrea ... amp;page=1#pid19047

@echo off
:accept
set /p n=Please input a number:
echo.%n%|findstr "^[0-9][0-9]*$">nul||goto accept
for /f "tokens=* delims=0" %%a in ("%n%") do echo %%a
echo.&pause
复制代码

作者: sjzong 时间: 2009-4-14 11:14

回3楼的

假设把 echo.%n%|findstr "^[0-9][0-9]*$">nul||goto accept 改成 echo.%n%|findstr "^[0-9]*$">nul||goto accept
就是去掉一个[0-9]可以吗？

作者: Batcher 时间: 2009-4-14 11:36 标题: 回复 4楼的帖子

你自己测试的结果如何呢？
请先测试，后提问。

作者: lxzzr 时间: 2009-4-14 11:40

@echo off
setlocal enabledelayedexpansion
set a=001234
for /l %%a in (0 1 20) do (
if not "!a:~%%a,1!" == "0" (
echo !a:~%%a,20!
goto :a
)
)
:a
pause
复制代码

[ 本帖最后由 lxzzr 于 2009-4-14 11:41 编辑 ]

作者: ZJHJ 时间: 2010-8-24 23:20

原帖由 irresolute 于 2009-3-7 20:21 发表
@echo off
rem 看到两种去掉左面0的方法
set tt=001234
for /f "delims=0" %%i in ("%tt%") do (
echo %%i
)
echo ----
set /a "tt=1001234 %%1000000"
echo %tt%
rem （1000000+1234）/1000000=1234
ech ...

"去掉左面0的方法"以上的情况很特殊而已,如果处理普遍的情况还能用吗?修改成
set tt=00060123400000
怎么样?
只有从左开始逐位判断才通用

欢迎光临批处理之家 (http://www.bathome.net/)