批处理之家 - Powered by Discuz! Board

标题: [文件操作] [已解决]求一个批量移动的文件的批处理 [打印本页]

作者: 511182890 时间: 2015-6-30 15:08 标题: [已解决]求一个批量移动的文件的批处理

本帖最后由 511182890 于 2015-7-6 08:11 编辑

DSN\KD\RC207+D2-P1101-KD座背分离无刀眼.DSN
DSN\LD\RC207+D2-P1101-LD座背分离.DSN
DSN\test.bat

test.bat的代码

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1,2* delims=-" %%i in ('dir /a-d /b /s *.DSN') do (
set "n=%%j"
md "!n:~,5!\" 2>nul
move "%%i-%%j-%%k" "!n:~,5!\"
) 
复制代码

执行批处理，要的结果是
DSN\KD\P1101\RC207+D2-P1101-KD座背分离无刀眼.DSN
DSN\LD\P1101\RC207+D2-P1101-LD座背分离.DSN

来位大神帮我修改一下代码

作者: Batcher 时间: 2015-6-30 17:28

@echo off
setlocal enabledelayedexpansion
for /f "tokens=1,2* delims=-" %%i in ('dir /a-d /b /s *.DSN') do (
    set "n=%%j"
    if not exist "!n:~,5!\" (
        md "%%~dpi!n:~,5!"
    )
    move "%%i-%%j-%%k" "%%~dpi!n:~,5!\"
)
复制代码

作者: 511182890 时间: 2015-7-1 08:10

回复 2# Batcher

重复执行的话会，变成DSN\LD\P1101\P1101\RC207+D2-P1101-LD座背分离.DSN
重复建文件夹

作者: aa77dd@163.com 时间: 2015-7-1 09:30

本帖最后由 aa77dd@163.com 于 2015-7-1 10:28 编辑

WIN7 64位和 WIN 2003 下测试通过

@echo off
for /f "delims=" %%i in ('dir /a-d /b /s *.DSN') do (
    for /f "tokens=2 delims=-" %%a in ("%%~nxi") do (
        for %%d in ("%%~dpi\.") do (
            if not "%%~nxd"=="%%a" (
                if not exist "%%~dpi%%a\" md "%%~dpi%%a\"
                move "%%i" "%%~dpi%%a\"
            )
        )
    )
)
复制代码

作者: 511182890 时间: 2015-7-1 13:49

回复 4# aa77dd@163.com

你好，可以用了，但是必须我的文件命名规范，如果我的文件是DSN\LD\RC207+D2-P1101中国-LD座背分离.DSN
那样执行后变成DSN\LD\P1101中国\RC207+D2-P1101中国-LD座背分离.DSN
所以帮忙修改一下，只取5位

作者: aa77dd@163.com 时间: 2015-7-1 15:28

回复 5# 511182890

你的问题是否还会有变化, 能否一次性作出完整而清晰的描述

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in ('dir /a-d /b /s *.DSN') do (
    for /f "tokens=2 delims=-" %%a in ("%%~nxi") do (
        set "t=%%a" & set "t=!t:~0,5!"
        for %%d in ("%%~dpi\.") do (
            if not "%%~nxd"=="!t!" (
                if not exist "%%~dpi!t!\" md "%%~dpi!t!\"
                move "%%i" "%%~dpi!t!\"
            )
        )
    )
)
复制代码

作者: 511182890 时间: 2015-7-1 17:26

本帖最后由 511182890 于 2015-7-1 17:27 编辑

回复 6# aa77dd@163.com

可以了

欢迎光临批处理之家 (http://www.bathome.net/)