批处理之家 - Powered by Discuz! Board

标题: [文本处理] 【已解决】如何用批处理在一批文本中的特定字符串前添加回车换行符？ [打印本页]

作者: pan528 时间: 2015-5-1 19:43 标题: 【已解决】如何用批处理在一批文本中的特定字符串前添加回车换行符？

本帖最后由 pcl_test 于 2016-10-1 12:52 编辑

如在一批文本中的下列字符前加入回车符号：
WWW
Www
WWw
WwW
wWw
wWW

作者: bailong360 时间: 2015-5-1 21:21

@sed "s/[wW][wW][wW]/\n&/g" Your.txt >$New.txt
复制代码

http://batch-cn.qiniudn.com/tool/sed.exe

作者: pan528 时间: 2015-5-1 23:06

回复 2# bailong360

谢谢回帖！
通过测试了。
如果不用第三软件，批处理命令应当怎样写？

作者: CrLf 时间: 2015-5-1 23:30

powershell：

(type a.txt) -replace 'www',"`r`nwww" >b.txt
复制代码

纯批：

@echo off&setlocal enabledelayedexpansion
set Lf=^


for /f %%a in ('copy /z %0 nul') do set "Cr=%%a"
for %%z in ("!Cr!!Lf!") do (
   endlocal
   for /f "delims=" %%a in (a.txt) do (
      set "str=%%a"
      echo;!str:www=%%~zwww!
   )
)>b.txt
pause
复制代码

或 bat+js ：

1>1/* :
@echo off
cscript -nologo -e:jscript %0 <a.txt >b.txt
pause & exit
*/

var text = WSH.StdIn.ReadAll()
WSH.Echo(text.replace(/www/gi,'\r\n$&'))
复制代码

作者: pan528 时间: 2015-5-3 11:49

本帖最后由 pan528 于 2015-5-3 11:51 编辑

回复 4# CrLf
特别感谢！！！
一下子给了三个方案！
经测试，只有第三个代码通过了测试。
第一个代码看不懂。
第二个纯批的代码运行后，生成：
!str:www=
www!
!str:www=
www!
!str:www=
www!
!str:www=
www!
!str:www=
www!
!str:www=
www!
……
我不知道出错的原因，能帮助改一下吗？我非常希望纯批的代码有用。
谢谢！
五一节快乐！

作者: CrLf 时间: 2015-5-3 14:40

回复 5# pan528

哦，把那句 endlocal 去掉

作者: pan528 时间: 2015-5-5 06:41

回复 6# CrLf

感谢回帖，已通过测试。
看来我的批处理还没有了解到皮毛啊，今后还少不了向各位高手讨教。
向各位高手学习和致敬啦！

欢迎光临批处理之家 (http://www.bathome.net/)