批处理之家 - Powered by Discuz! Board

标题: [文件操作] [已解决]批处理如何检测关键词并建立文件夹，将图片放入到该文件夹内呢 [打印本页]

作者: zgbbin 时间: 2015-4-14 16:41 标题: [已解决]批处理如何检测关键词并建立文件夹，将图片放入到该文件夹内呢

本帖最后由 zgbbin 于 2015-4-15 12:13 编辑

"D:\待处理\" 目录下有多个文件夹，每个文件夹里都有jpg图片
"D:\特殊名称.txt"和"D:\所有名称.txt"里有多个关键词（一行一个）
"所有名称.txt"里包含"特殊名称.txt"里的关键词，
文件夹名称里可能包含“特殊名称.txt”里的关键词，但一定包含“所有名称.txt"里的关键词。

先检测每个文件夹名称里是否包含“特殊名称.txt”里的关键词，
如果不包含“特殊名称.txt”里的关键词则对该文件夹无操作；

如果包含“特殊名称.txt”里的关键词则对该文件夹执行如下操作
1.在该文件夹下建立以包含“特殊名称.txt”里的关键词为名称的子文件夹；
2.检测该文件夹包含"D:\所有名称.txt"里几个关键词，记为N个（N≥1），
然后将该文件夹下的图片数量为成N等份，每个子文件夹里移进去1/N张；

例如：
文件夹A，不包含“特殊名称.txt”里的关键词，则不用管它；
文件夹B包含“特殊名称.txt”里的2个关键词“春天”、“秋天”，
则建立这2个子文件夹，继续检测到文件夹B包含“所有名称.txt"
里的3个关键词“春天”、“秋天”、“过年”，然后检测到图片有31张，
将图片分成3份，2个子文件夹“春天”、“秋天”各放入10张，剩下的11张不动。

注：只处理文件夹内的jpg/JPG图片文件，其它文件不处理。

作者: pcl_test 时间: 2015-4-14 20:04

本帖最后由 pcl_test 于 2015-4-14 22:36 编辑

@echo off
setlocal enabledelayedexpansion
set "folder=D:\待处理"
for /f "delims=" %%a in ('dir /ad /b "!folder!\"') do (

set "fname=%%a"
set /a n=m=s=0
for /f "delims=" %%b in ('type "D:\特殊名称.txt"') do (
if "!fname:%%b=!" neq "!fname!" (set /a n+=1 & md "!folder!\%%a\!n!%%b" 2>nul)
)

for /f "delims=" %%c in ('type "D:\所有名称.txt"') do (
if "!fname:%%c=!" neq "!fname!" set /a m+=1
)

cd /d "!folder!\%%a"
if !n! neq 0 (
for %%d in (*.jpg) do set /a s+=1
set /a r=s/m,z=0
for %%i in (*.jpg) do (
for /f "delims=" %%j in ('dir /ad /b "!m!*" 2^>nul') do set files=%%j
if exist "!files!" (move "%%i" "!files!\" 2>nul)
set /a z+=1
if !z! == !r! (set z=0 &ren "!files!" "!files:~1!" 2>nul & set /a m-=1)
)
)

)
echo 完成！2秒后自动关闭
ping 0 -n 3 >nul
exit
复制代码

作者: zgbbin 时间: 2015-4-14 21:46

有点小问题哦，我测试了一个文件夹，有38张照片，有3个关键词，其中2个是特殊关键词，运行后的结果为：建立了2个子文件夹，这2个子文件夹里移进去了12张照片，还有12张照片被移到了D盘根目录，只有2张照片不动。按道理应该是14张照片不动哦，不能把照片移到D盘根目录去哦。希望帮改一下，谢谢大神！

作者: pcl_test 时间: 2015-4-14 22:22

回复 4# zgbbin

已在2楼更正

作者: cobat 时间: 2015-4-14 23:07

本帖最后由 cobat 于 2015-4-16 20:23 编辑

@echo off
setlocal enabledelayedexpansion
for /d %%a in ("d:\待处理\*") do (
    set "$=%%~na"
    pushd "%%a"
    set/a "i=j=0"
    for /f "usebackq delims=" %%b in ("d:\特殊名称.txt") do (
        if "!$:%%b=!" NEQ "!$!" (
            if !j! EQU 0 (
                for %%d in (*.jpg) do set/a "i+=1"
                for /f "usebackq delims=" %%c in ("d:\所有名称.txt") do (
                    if "!$:%%c=!" NEQ "!$!" set/a "j+=1"
                )
                set/a "k=i/j"
            )
            md "%%b"
            set "n=0"
            for %%e in (*.jpg) do (
                set/a "n+=1"
                if !n! LEQ !k! move "%%e" "%%b"
            )
        )
    )
)
pause
复制代码

作者: zgbbin 时间: 2015-4-15 12:13

感谢2位朋友的帮助

作者: ww0000 时间: 2015-4-16 16:33

楼主,你好会折腾老师呀!哈

欢迎光临批处理之家 (http://www.bathome.net/)