批处理之家 - Powered by Discuz! Board

标题: [文本处理] 【已解决】BAT:再问如何批量整理txt文本数据 [打印本页]

作者: 思想之翼 时间: 2015-2-2 20:58 标题: 【已解决】BAT:再问如何批量整理txt文本数据

本帖最后由思想之翼于 2015-2-2 21:45 编辑

D:/数据1/内有若干txt文本，每个文本内的数据格式如下：
0 2 4 7 8 9
欲批量整理文本内的数据，整理后的数据格式为：
1=10
1=2
1=4
1=7
1=8
1=9
整理后的文本保留原名称，并写入D:/数据2/内
这样的代码如何写？恳望得到帮助。

作者: xxpinqz 时间: 2015-2-2 21:18

@echo off&cd /d "D:\数据1\"
for %%i in (*.txt)do (for /f "delims=" %%a in (%%i)do for %%b in (1%%a)do echo,1=%%b)>"D:\数据2\%%i"
复制代码

作者: apang 时间: 2015-2-2 21:30

@echo off
setlocal enabledelayedexpansion
md "D:\数据2" 2>nul
for %%a in ("D:\数据1\*.txt") do (
        (for /f "usebackq delims=" %%b in ("%%a") do (
                set "s= %%b "
                for %%b in (!s: 0 ^= 10 !) do echo,1=%%b
        ))>"D:\数据2\%%~nxa"
)
pause
复制代码

作者: 思想之翼 时间: 2015-2-2 21:42

回复 3# apang

感谢！！

作者: 慕夜蓝化 时间: 2015-2-3 11:03

@echo off
for %%i in ("d:\数据1\*.txt") do (
    (for /f "usebackq delims=" %%a in ("%%i") do (
        for %%b in (%%a) do (
            if %%b neq 0 (
                echo,1=%%b
            ) else (
                echo,1=1%%b
            )
        )
    )) >"d:\数据2\%%~nxi"
)
pause
复制代码

欢迎光临批处理之家 (http://www.bathome.net/)