批处理之家 - Powered by Discuz! Board

@if (0)==(0) echo off
setlocal enabledelayedexpansion
chcp 437&graftabl 936
REM 变量初始化
prompt $
title **工资详情批量发送工具.::By KOUKON::.
COLOR 9e
:_start
cls
set /p "from=请输入你的邮箱地址:"
echo,%from% | findstr ".*@[0-9a-zA-Z]*\.[0-9a-zA-Z]*.*" >nul 2>nul || (
echo,不合法邮箱地址,请重新输入...
pause
goto :_start
)
for /f "tokens=1,* delims=@" %%i in ('echo %from%') do (
set "user=%%i"
set "server=smtp.%%j"
)
echo,用户名 : %user%
echo,服务器 : %server%
set/p"=请输入邮箱登录密码:"<nul
REM 生成取得字符程序
pushd %tmp%
echo,hP1X500P[PZBBBfh#b##fXf-V@`$fPf]f3/f1/5++u5x>in.com
for /f "tokens=*" %%a in ('in.com') do (
set "pass=%%a"
)
del /f in.com
popd
echo,
REM echo,密码 : !pass!
:_next
REM set /p "to=请输入你要发送的邮箱:"
set "x=X-Header-Test "Can Blat do it Yes it Can!""
set "debug=-log MailLog.log -timestamp "
cd.>MailLog.log
REM 获取详情
set /p "strFile=拖入整理好的工资条列表(csv格式文件):"
:_readContent
echo,下面开始读取工资详情……
echo,&echo,
for /f "skip=1 tokens=*" %%u in ('type %strFile%') do (
set "Line=%%u"
REM cscript -nologo -e:jscript %~s0 DealNullChar "!Line!"
for /f "tokens=*" %%v in ('cscript -nologo -e:jscript %~s0 DealNullChar "!Line!"') do set "Line=%%v"
REM echo,处理后内容 : !Line!
for /f "tokens=1-18 delims=," %%a in ('echo,!Line!') do (
(
echo,%%a:
echo, 您好。这是本月工资详单，请查阅。
set/p"=姓名 : "<nul
if "%%a" NEQ "null" (echo,%%a) else echo,
set/p"=卡号 : "<nul
if "%%b" NEQ "null" (echo,%%b) else echo,
set/p"=基本工资 : "<nul
if "%%c" NEQ "null" (echo,%%c) else echo,
set/p"=住房补贴 : "<nul
if "%%d" NEQ "null" (echo,%%d) else echo,
set/p"=浮动 : "<nul
if "%%e" NEQ "null" (echo,%%e) else echo,
set/p"=预付奖金 : "<nul
if "%%f" NEQ "null" (echo,%%f) else echo,
set/p"=奖金 : "<nul
if "%%g" NEQ "null" (echo,%%g) else echo,
set/p"=加班其它 : "<nul
if "%%h" NEQ "null" (echo,%%h) else echo,
set/p"=小计 : "<nul
if "%%i" NEQ "null" (echo,%%i) else echo,
set/p"=住房金 : "<nul
if "%%j" NEQ "null" (echo,%%j) else echo,
set/p"=其他 : "<nul
if "%%k" NEQ "null" (echo,%%k) else echo,
set/p"=考勤 : "<nul
if "%%l" NEQ "null" (echo,%%l) else echo,
set/p"=税前合计 : "<nul
if "%%m" NEQ "null" (echo,%%m) else echo,
set/p"=计税金额 : "<nul
if "%%n" NEQ "null" (echo,%%n) else echo,
set/p"=扣税 : "<nul
if "%%o" NEQ "null" (echo,%%o) else echo,
set/p"=应发数 : "<nul
if "%%p" NEQ "null" (echo,%%p) else echo,
set/p"=已发 : "<nul
if "%%q" NEQ "null" (echo,%%q) else echo,
set/p"=实发数 : "<nul
if "%%r" NEQ "null" (echo,%%r) else echo,
echo, ****公司财务部
echo, %date%
) >"mailBody.dat"
REM find /v ""<"mailBody.dat"
REM ECHO,%%a, %%b, %%c, %%d, %%e, %%f, %%g, %%h, %%i, %%j, %%k, %%l, %%m, %%n, %%o, %%p, %%q, %%r
set "strName="
set "strMail="
set "strTel="
for /f "tokens=*" %%w in ('findstr /c:"%%a" 名单.csv') do (
for /f "tokens=1-3 delims=," %%1 in ('cscript -nologo -e:jscript %~s0 DealNullChar "%%~w"') do (
echo,姓名 : %%1
echo,邮箱 : %%2
echo,手机 : %%3
set "subj=%%1 工资详单"
if "%%1" NEQ "" if "%%1" NEQ "null" set "strName=%%1"
if "%%2" NEQ "" if "%%2" NEQ "null" set "strMail=%%2"
if "%%3" NEQ "" if "%%3" NEQ "null" set "strTel=%%3"
)
)
REM echo,strName : !strName!
REM echo,strMail : !strMail!
REM echo,strTel : !strTel!
if "!strName!" NEQ "" (
echo,发送邮件至 !strMail!
if "!strMail!" NEQ "" (
start "" /WAIT /b %~s0:blat.exe -server %server% -u %user% -pw %pass% -f %from% -to "!strMail!" -s "!subj!" -bodyF "mailBody.dat" -charset "GBK" -debug %debug%
) else (
echo,未检测到登记邮箱，跳过此步骤
)
echo,检测手机号
if "!strTel!" NEQ "" (
for /f "tokens=*" %%z in ('cscript -nologo -e:jscript %~s0 IsCM "!strTel!"') do (
if %%z NEQ 0 (
echo,当前用户手机号为移动号码，可以推送至手机邮箱
start "" /WAIT /b %~s0:blat.exe -server %server% -u %user% -pw %pass% -f %from% -to "!strTel!@139.com" -s "!subj! 手机推送" -bodyF "mailBody.dat" -charset "GBK" -debug %debug%
) else (
echo,非移动手机号，跳过手机推送步骤
)
)
) else (
echo,未登记手机号，跳过此步骤
)
) else (
echo,★★★当前统计人员【%%a】:该条工资明细无登记联系方式，跳过邮件发送步骤★★★
)
echo,&echo,
)
)
pause>nul
del /f "mailBody.dat"
goto :EOF
@end
var fun = WScript.arguments(0);
switch (fun){
case "IsCM":
CheckArgs(2);
var strTel = WScript.arguments(1);
IsCM(strTel);
break;
case "DealNullChar":
CheckArgs(2);
var strContent = WScript.arguments(1);
DealNullChar(strContent);
break;
case "RegTest":
CheckArgs(2);
var strContent = WScript.arguments(1);
RegTest(strContent);
break;
default:;
}
function CheckArgs(num){
if (WScript.arguments.length < num){
WScript.echo("参数不齐");
WScript.quit();
}
}
function IsCM(strTel){
var reg = /^(\+86)?1((3[4-9])||(5[0-28-9])||(8[278]))\d{8}$/g;
WScript.echo(reg.test(strTel));
}
function DealNullChar(strContent){
var reg = /,,/g;
while (true) {
strContent = strContent.replace(reg, ",null,");
//WScript.echo("处理后结果 : " + strContent);
var ret = RegTest(strContent);
//WScript.echo("正则 " + reg + " 符合度判断结果 : " + ret);
if (!ret) break;
}
WScript.echo(strContent);
}
function RegTest(strContent){
var reg = /,,/g;
var ret = reg.test(strContent);
//WScript.echo(ret);
return ret;
}