@echo off
REM Win7/Win10/Win11等系统自带PowerShell

REM 指定天数
set DaysAgo=1
for /f %%i in ('powershell -c "Get-Date (Get-Date).AddDays(-%DaysAgo%) -uformat "%%Y-%%m-%%d""') do (
    set "DstDate=%%i"
)
echo,%DstDate%
pause
复制代码

@echo off
REM 指定天数
set DaysAgo=1
>"%temp%\MyDate.vbs" echo LastDate=date()-%DaysAgo%
>>"%temp%\MyDate.vbs" echo FmtDate=right(year(LastDate),4) ^& right("0" ^& month(LastDate),2) ^& right("0" ^& day(LastDate),2)
>>"%temp%\MyDate.vbs" echo wscript.echo FmtDate
for /f %%a in ('cscript /nologo "%temp%\MyDate.vbs"') do (
    set DstDate=%%a
)
set DstDate=%DstDate:~0,4%-%DstDate:~4,2%-%DstDate:~6,2%
echo %DaysAgo%天之前的日期是：%DstDate%
pause
复制代码

@echo off
REM 本例需要命令行工具gawk.exe的支持，下载地址：
REM http://bcn.bathome.net/s/tool/index.html?key=gawk

REM 指定天数
set DaysAgo=1
set ThisDate=2014-02-20
echo %ThisDate% | gawk -F "-" -v days=%DaysAgo% "{$1=$1;print strftime(\"%%F\",mktime($0\" 0 0 0\")-86400*days)}"
pause
复制代码

@echo off
REM 此类方法的关键在于如何获取标准化的当前系统日期
REM 请参考http://bbs.bathome.cn/thread-3328-1-1.html
REM 然后调用 Ritchie Lawrence 的日期函数，便可扩展出很多种方法，此处不再赘述。
REM 日期转换的核心算法请参考http://bbs.bathome.cn/thread-3056-1-1.html

REM 指定天数
set DaysAgo=1
for /f "skip=4 delims= " %%a in ('reg query "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate') do (
    set RegDateOld=%%a
)
set RegDateOld=%RegDateOld:~-8%
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d yyyy-M-d /f>nul
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
reg add "HKEY_CURRENT_USER\Control Panel\International" /v sShortDate /t REG_SZ /d %RegDateOld% /f>nul
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
set DstDate=%DstYear%-%DstMonth%-%DstDay%
echo %DaysAgo%天之前的日期是：%DstDate%
pause
goto :eof

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF
复制代码

@echo off
call :_DateAdd  2014.12.30  -5
echo, 2014.12.30  5天前是 %dt%
call :_DateAdd  2014-12-30  +5
echo, 2014-12-30  5天后是 %dt%
call :_DateAdd  2014/12/30  +500
echo, 2014/12/30  500天后是 %dt%
pause

' 返回日期(修正系统日期分隔符不同的问题) By Yu2n 2014.12.10
' 参数1日期，参数2为加减天数
Goto :Eof
:_DateAdd
  (echo, If IsDate^("%~1"^) Then
  echo,   dt=CDate^("%~1"^)
  echo, Else
  echo,   For Each s1 In Split^(". - /"^)
  echo,     For Each s2 In Split^(". - /"^)
  echo,       If IsDate^(Replace^("%~1",s1,s2^)^) Then dt=CDate^(Replace^("%~1",s1,s2^)^)
  echo,     Next
  echo,   Next
  echo, End If
  echo, dt = DateAdd^("d", Eval^("%~2"^), dt^)
  echo, WScript.Echo Right^(Year^(dt^),4^) ^& "-" ^& Right^("0" ^& Month^(dt^),2^) ^& "-" ^& Right^("0" ^& Day^(dt^),2^))>"%tmp%\_DateAdd.vbs"
  for /f "delims=" %%i in ('CScript //NoLogo "%tmp%\_DateAdd.vbs"') do set dt=%%i
  goto :Eof
复制代码

 2014.12.30  5天前是 2014-12-25
 2014-12-30  5天后是 2015-01-04
 2014/12/30  500天后是 2016-05-13
请按任意键继续. . .
复制代码

d1 = "2014.03.01"
nAdd = "-3"
d2 = DateAdd("d", Eval(nAdd), GetDate(d1))
d2 = Right(Year(d2),4) & "-" & Right("0" & Month(d2),2) & "-" & Right("0" & Day(d2),2)
WScript.Echo d2

' 返回日期(修正系统日期分隔符不同的问题) By Yu2n 2014.12.10
Function GetDate(ByVal strDate)
    If IsDate(strDate) Then GetDate = CDate(strDate) :  Exit Function
    Dim s1, s2
    For Each s1 In Split(". - /")
        For Each s2 In Split(". - /")
            If IsDate(Replace(strDate,s1,s2)) Then GetDate=CDate(Replace(strDate,s1,s2)) : Exit Function
        Next
    Next
End Function
复制代码