批处理之家 - Powered by Discuz! Board

标题: [文本处理] 批处理怎样把文本内容按每一行的长度排序？ [打印本页]

作者: necnec1 时间: 2014-8-12 17:32 标题: 批处理怎样把文本内容按每一行的长度排序？

本帖最后由 pcl_test 于 2016-10-18 19:01 编辑

123
1234
12345
456
789000

上面的文本按照长度进行排序最长的放在第一最短的放在最后
请会的朋友帮下忙

作者: apang 时间: 2014-8-12 18:24

@set @n=0; /* & echo off
cscript -nologo -e:jscript "%~0"<a.txt>b.txt
pause & exit/b & rem */

txt = WScript.StdIn.ReadAll().replace(/(\r?\n)+/g, "\n");
ar = txt.replace(/\n$/, "").split("\n");
ar.sort(function(x,y) {return y.length-x.length});
WScript.Echo(ar.join("\r\n"))
复制代码

作者: apang 时间: 2014-8-12 18:28

纯P

@echo off
%1(for /f "tokens=1*" %%a in ('"%~0" :^|sort /r') do echo,%%b)>b.txt
%1pause & exit/b

for /f "delims=" %%a in (a.txt) do (
    set "str=%%a"
    setlocal enabledelayedexpansion
    set "s=!str!"
    for %%b in (4096 2048 1024 512 256 128 64 32 16) do (
        if "!s:~%%b!" neq "" set /a n+=%%b & set "s=!s:~%%b!"
    )
    set "s=!s!fedcba9876543210"
    set /a n+=100000+0x!s:~15,1!
    echo,!n! !str!
    endlocal
)
复制代码

作者: CrLf 时间: 2014-8-12 18:35

gnusort:

sort -n a.txt
复制代码

powershell:

type a.txt | sort length
复制代码

欢迎光临批处理之家 (http://www.bathome.net/)