批处理之家 - Powered by Discuz! Board

标题: [文件操作] [已解决]批处理怎样给zip文件的文件名结尾加个4位随机字符串？ [打印本页]

作者: WisdomFusion 时间: 2014-7-19 10:48 标题: [已解决]批处理怎样给zip文件的文件名结尾加个4位随机字符串？

本帖最后由 WisdomFusion 于 2014-7-19 15:16 编辑

如当前文件夹里有

111.zip
222.zip
333.zip
...

想批量move成

111_h7ye.zip
222_ui89.zip
333_7hy9.zip
...

下面是我测试用的代码，一直调不通，请高手帮忙看看，谢谢

@ECHO OFF & SETLOCAL EnableDelayedExpansion
FOR %%f IN (DIR /B *.zip) DO (
    SET file=%%f
    SET "file=!file:.zip=!"
    
    set pas=
    set s=abcdefghijklmnopqrstuvwxyz1234567890
    set m=0
    :loop
    set /a n=%random% %% 36
    call set pas=%pas%%%s:~%n%,1%%
    set /a m=m+1
    if not %m%==4 goto loop
    
    MOVE "%%f" "!file!_%pas%.zip"
)
复制代码

作者: apang 时间: 2014-7-19 11:47

@ECHO OFF & SETLOCAL EnableDelayedExpansion
set "s=abcdefghijklmnopqrstuvwxyz1234567890"
FOR /f "delims=" %%f IN ('DIR /B *.zip') DO (
    set "pas="
    for /l %%a in (1 1 4) do (
        set /a n=!random! %% 36
        for %%b in (!n!) do set "pas=!pas!!s:~%%b,1!"
    )
    MOVE "%%f" "%%~nf_!pas!.zip"
)
pause
复制代码

作者: WisdomFusion 时间: 2014-7-19 12:12

回复 2# apang

谢谢，成功了，而且代码更简法了，多谢

欢迎光临批处理之家 (http://www.bathome.net/)