批处理之家 - Powered by Discuz! Board

标题: [文本处理] BAT批处理如何修改指定文本的某行？ [打印本页]

作者: cartey 时间: 2014-6-28 23:56 标题: BAT批处理如何修改指定文本的某行？

新手求教！！
现有d：\m文件夹下1,2,3....10文件夹，每个文件夹里都有相同名字的文本b.txt，内容不同。需要修改所有b.txt里的第20行。需要注意的是1,2,3等文件夹里还有其他的文本文件，但不要修改。在网上找到了批处理和文本放在同一个文件夹的代码：

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in ('type b.txt') do (
set /a n+=1
if !n! equ 1 (
echo %%a>b.txt
) else (
if !n! equ 20 (
 for /f "delims=" %%i in ("    <add key="A23" value="1" />") do echo %%i>>b.txt         <add key="A23" value="1" />为修改后的内容，前面有空格
) else (
echo.%%a>>b.txt
)
)
)
pause
复制代码

请教，如果我要把bat文件放在桌面上，修改所有d：\m\1,2,3....里的b.txt 该怎么做呢

作者: zhanglei1371 时间: 2014-6-29 07:46

本帖最后由 zhanglei1371 于 2014-6-29 11:20 编辑

@echo off&setlocal enabledelayedexpansion
for /d %%d in (D:\m\*) do (
pushd %%d
for /f "delims=" %%a in ('type b.txt') do (
set /a n+=1
if !n! equ 1 (
echo %%a>>b.txt
) else (
if !n! equ 20 (
for /f "delims=" %%i in ("    <add key="A23" value="1" />") do echo %%i>>b.txt
) else (
echo.%%a>>b.txt  
)
)
)
popd
set n=0
)
pause
复制代码

作者: cartey 时间: 2014-6-29 09:43

回复 2# zhanglei1371
测试了下，没有修改到数据

作者: cartey 时间: 2014-6-29 10:04

回复 2# zhanglei1371
我做了下测试，我用了的简单的文本测试，修改行为第3行。d:\m\1\b.txt.原始数据为
ahbwr1
haerh2
haerg3
hserh4
执行结果为：
ahbwr1
haerh2
haerg3
hserh4ahbwr1
haerh2
<add key="A23" value="1" />
hserh4

d:\m\2\b.txt 原始数据为
ahbwr11
haerh22
haerg33
hserh44
结果是：
ahbwr11
haerh22
haerg33
hserh44ahbwr11
haerh22
haerg33
hserh44
后面3,4,5的结果是d:\m\2\b.txt 相同的效果

作者: apang 时间: 2014-6-29 14:11

@echo off
set "s=    <add key="A23" value="1" />"
for /f "delims=" %%i in ('dir /a-d /b /s "D:\m\b.txt"') do (
    set n=0
    (for /f "usebackq delims=" %%a in ("%%i") do (
        set /a n+=1 & set "str=%%a"
        setlocal enabledelayedexpansion
        if !n! equ 20 (
            echo,!s!
        ) else (
            echo,!str!
        )
        endlocal
    ))>$
    move $ "%%i"
)
pause
复制代码

作者: cartey 时间: 2014-6-29 20:28

回复 5# apang
虽然自己还没弄明白但是是我要的结果谢谢！非常感谢

欢迎光临批处理之家 (http://www.bathome.net/)