for /l %%i in (1,1,100) do if exist %%i.txt echo %%i.txt>>test1.txt
for %%i in (  一 二 三 四 五 六 七 八 九 十) do if exist %%i.txt echo %%i.txt>>test.txt
for %%i in (一 二 三 四 五 六 七 八 九) do (
   for %%b in (十 十一 十二 十三 十四 十五 十六 十七 十八 十九 ) do (
    if exist %%i%%b.txt echo %%i%%b.txt>>test.txt
    )
    )
if exist 一百.txt echo 一百.txt>>test.txt
pause
复制代码

@echo off & setlocal enabledelayedexpansion
for %%a in (零.0 一.1 二.2 三.3 四.4 五.5 六.6 七.7 八.8 九.9) do (
    set "%%~xa=%%~na"
)
md "Test\" 2>nul
pushd "Test\"
for /l %%a in (1 1 1200) do (
    set "s=%%a"
    if %%a geq 1000 (
        call set "s=%%.!s:~,1!%%千%%.!s:~1,1!%%百%%.!s:~2,1!%%十%%.!s:~3!%%"
        set "s=!s:零百零十零=!" & set "s=!s:零百零十=零!"
        set "s=!s:零百=零!" & set "s=!s:零十零=!"
        set "s=!s:零十=零!" & set "s=!s:十零=十!"
    ) else if %%a geq 100 (
        call set "s=%%.!s:~,1!%%百%%.!s:~1,1!%%十%%.!s:~2!%%"
        set "s=!s:零十零=!"
        set "s=!s:零十=零!" & set "s=!s:十零=十!"
    ) else if %%a geq 10 (
        call set "s=%%.!s:~,1!%%十%%.!s:~1!%%"
        set "s=!s:十零=十!"
    ) else set "s=!.%%a!"
    echo,%%a>"第!s!章.txt"
)
pause
复制代码

@echo off
%1(for /f "tokens=1*" %%a in ('"%~0" :^|sort') do echo,%%b)>List.txt
%1pause & exit/b
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /b "Test\第*章*.txt"') do (
    for /f "delims=第章" %%b in ("%%~na") do set "s=%%b"
    for %%b in (八 九) do set "s=!s:零%%b=%%b!"
    if "!s:~,1!" == "十" set "s=一!s!"
    set "s=!s:千=*1000+!"
    set "s=!s:百=*100+!"
    set "s=!s:十=*10+!"
    for %%b in (0.零 1.一 2.二 3.三 4.四 5.五 6.六 7.七 8.八 9.九) do (
        for /f "delims=." %%c in ("%%~xb") do set "s=!s:%%c=%%~nb!"
    )
    set /a s=!s!+0
    set "s=0000!s!"
    echo,!s:~-5! %%a
)
复制代码

@echo off
%1(for /f "tokens=1*" %%a in ('"%~0" :^|sort') do echo,%%b)>List.txt
%1pause & exit/b
set "str=零一二三四五六七八九"
setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /b "Test\第*章*.txt"') do (
    for /f "delims=第章" %%b in ("%%~na") do set "s=%%b"
    for %%b in (八 九) do set "s=!s:零%%b=%%b!"
    if "!s:~,1!" == "十" set "s=一!s!"
    set "s=!s:千=*1000+!"
    set "s=!s:百=*100+!"
    set "s=!s:十=*10+!"
    for /l %%b in (0 1 9) do (
        for %%c in ("!str:~%%b,1!") do set "s=!s:%%~c=%%b!"
    )
    set /a s=!s!+0
    set "s=0000!s!"
    echo,!s:~-5! %%a
)
复制代码

@set @n=0; /* & echo off
pushd "Test\"
dir /b 第*章*.txt 第*节*.txt|cscript -nologo -e:jscript "%~0">"..\List.txt"
pause & exit/b & rem */

str = "零一二三四五六七八九十百千";
txt = WScript.StdIn.ReadAll().replace(/\r\n$/, "");
txt = txt.replace(/^第(.+)[章|节].*/mg,
    function(s0,s1) {
        s1 = s1.replace(/^十/, "一$&");
        s1 = s1.replace(/./g,
            function(s0){
                if (str.indexOf(s0) > 9) {
                    return "*" + Math.pow(10, str.indexOf(s0)-9) + "+"
                } else return str.indexOf(s0)
            }
        );
        return eval(s1.replace(/\+$/, "")) + " " + s0;
    }
);
ar = txt.split("\r\n");
ar.sort(function(x,y) {return x.split(" ")[0]-y.split(" ")[0]});
WScript.Echo(ar.join("\r\n").replace(/^\d+ /mg, ""))
复制代码

Dim strCase, fso, f, str, n, ar, re, m
strCase = "零一二三四五六七八九十百千"
Set fso = CreateObject("Scripting.FileSystemObject")
For Each f in fso.GetFolder("Test").Files
    If LCase(Right(f, 4)) = ".txt" Then str = str & f.Name & vbCrLf
Next

n = 0 : ReDim ar(n)
Set re = New RegExp
re.Pattern = "^第([" & strCase & "]+)[章节].*?\n"
re.Global = True
re.MultiLine = True
For Each m in re.Execute(str)
    ReDim PreServe ar(n)
    ar(n) = ConvertCase(m.SubMatches(0)) & " " & m
    n = n + 1
Next

call qSort(0, UBound(ar))
fso.CreateTextFile("List.txt", true).Write RegEx(Join(ar, ""))

MsgBox "OK"

''大写数字转成小写数字
Function ConvertCase(s)
    Dim i, s1, ss
    If Left(s, 1) = "十" Then s = "一" & s
    ''首位“十”改成“一十”
    For i = 1 to Len(s)
        s1 = Mid(s, i, 1)
        ''循环截取变量s值的第i位，赋值给s1
        If InStr(strCase, s1) > 10 Then
        ''变量s1值位于strCase值的第10位以上（十百千），改成形如 *10^2+
            ss = ss & "*10^" & (InStr(strCase, s1)-10) & "+"
        Else ss = ss & (InStr(strCase, s1)-1)
        ''否则改成strCase值中对应的位值数
        End If
    Next
    ConvertCase = Right("0000" & eval(ss & "+0"), 5)
    ''计算并凑成5位数字
End Function

''排序
Sub qSort(low, high)
    Dim i, j, pos, tmp
    If low > high Then Exit Sub
    i = low : j = high
    pos = ar(low)
    while i <> j
        while i < j and ar(j) >= pos
            j = j - 1        
        wend
        while i < j and ar(i) <= pos
            i = i + 1
        wend
        tmp = ar(i) : ar(i) = ar(j) : ar(j) = tmp
    wend
    ar(low) = ar(i) : ar(i) = pos
    qSort low, i-1
    qSort i+1, high
End Sub

''去掉前面的5位数字
Function RegEx(s)
    Dim reg
    Set reg = New RegExp
    reg.Pattern = "^\d+ "
    reg.Global = true
    reg.MultiLine = true
    RegEx = reg.Replace(s, "")
End Function
复制代码