批处理之家 - Powered by Discuz! Board

标题: 请问，能否用dos 获得默认Excel版本的安装目录？谢谢！ [打印本页]

作者: mansohu 时间: 2014-6-10 16:33 标题: 请问，能否用dos 获得默认Excel版本的安装目录？谢谢！

请问，能否用dos 获得默认Excel版本的安装目录？谢谢！

作者: mansohu 时间: 2014-6-26 12:42

还请各位老师多帮助，谢谢啊！

作者: szl1123 时间: 2014-6-26 13:40

回复 1# mansohu

@echo off
for /f "tokens=2,*" %%i in ('reg query "HKLM\SOFTWARE\Classes\Excelhtmlfile\shell\Open\command" /ve') do ( 
set excel=%%j
) 
set ml=%excel:~1,255%
echo EXCEL程序位置：%ml:~0,-1%
echo EXCEL程序所在目录：%ml:~0,-11%
pause
复制代码

以上仅供参考
HKLM\SOFTWARE\Classes\Excelhtmlfile\shell\Open\command 位置我只测试了OFFICE 2003 @XP OFFICE 2013 @WIN8.1版本，其它版本未测试，请自行测试。如果有其它可靠位置请自行更换。

我其实也是初学者，代码如有不托请指教。

作者: Batcher 时间: 2014-6-26 13:57

回复 3# szl1123

可以简化成这样：

@echo off
for /f "tokens=2*" %%i in ('reg query "HKLM\SOFTWARE\Classes\Excelhtmlfile\shell\Open\command" /ve') do ( 
    set excel=%%~j
) 
echo EXCEL程序位置：%excel%
echo EXCEL程序所在目录：%excel:~0,-10%
pause
复制代码

作者: szl1123 时间: 2014-6-26 14:04

回复 4# Batcher

谢谢指导。

作者: mansohu 时间: 2014-6-26 17:45

回复 szl1123

可以简化成这样：
Batcher 发表于 2014-6-26 13:57

感谢！非常感谢！

作者: CrLf 时间: 2014-6-26 18:00

最简单的是：

ftype rqyfile
复制代码

分享一下，事实上我一般喜欢这样找程序：

ftype|find /i "excel.exe"
rem 仅仅用来查路径

ftype | findstr /i "winrar.exe"
rem 其实是为了找 rar.exe，压缩包就靠你了

ftype | findstr /i "qvodplayer.exe"
rem →_→ 
复制代码

找到的关联文件路径哗啦哗啦都列出来了，然后挑一个最顺眼的...
当然前提是要找的程序有关联文件

欢迎光临批处理之家 (http://www.bathome.net/)