批处理之家 - Powered by Discuz! Board

标题: [文本处理] 【已解决】批处理如何将多个BAT代码合而为一？ [打印本页]

作者: 思想之翼 时间: 2014-3-6 00:33 标题: 【已解决】批处理如何将多个BAT代码合而为一？

本帖最后由思想之翼于 2014-3-6 16:34 编辑

若有如下若干BAT代码，如何将其合而为一？
恳望再次得到帮助。

@echo off
for /f "skip=10 delims=" %%i in ('dir /b /a-d /o-n /s "C:\001\lishi\*.txt"') do (
copy "%%i" "C:\数据\1.txt"
goto :eof
)

@echo off
for /f "skip=10 delims=" %%i in ('dir /b /a-d /o-n /s "C:\002\lishi\*.txt"') do (
copy "%%i" "C:\数据\2.txt"
goto :eof
)

@echo off
for /f "skip=10 delims=" %%i in ('dir /b /a-d /o-n /s "C:\003\lishi\*.txt"') do (
copy "%%i" "C:\数据\3.txt"
goto :eof
)

.....

@echo off
for /f "skip=10 delims=" %%i in ('dir /b /a-d /o-n /s "C:\210\lishi\*.txt"') do (
copy "%%i" "C:\数据\210.txt"
goto :eof
)

作者: DAIC 时间: 2014-3-6 11:12

@echo off
setlocal enabledelayedexpansion
for /l %%a in (1001,1,1210) do (
    set n=%%a
    set x=!n:~-3!
    set /a y=%%a-1000
    call :Copy_File !x! !y!
)
goto :eof

:Copy_File
for /f "skip=10 delims=" %%i in ('dir /b /a-d /o-n /s "C:\%1\lishi\*.txt"') do (
    copy "%%i" "C:\数据\%2.txt"
    goto :eof
)
复制代码

欢迎光临批处理之家 (http://www.bathome.net/)