标题: [网络工具] 批处理实用虚拟Wifi工具V1.2 [打印本页]
作者: cjiabing 时间: 2013-12-29 21:57 标题: 批处理实用虚拟Wifi工具V1.2
本帖最后由 cjiabing 于 2014-5-9 13:37 编辑
更新说明【20140509】:
1.添加设置网络共享失败的解决方案。有些机子装有杀毒软件如360的,系统防火墙一般会被关闭,导致无法手动设置共享。此时需要手动打开Windows Firewall的服务项。
2.优化设置了启动和关闭虚拟WIFI的选项。
3.添加了开机自动运行虚拟WIFI功能,默认开启虚拟WIFI,避免每次开机都去手动运行。
4.去掉自动关机功能,因为W7的AT功能受限,无法启动服务导致无法正常使用AT功能。但增加了提示。
- @echo off&title 实用虚拟Wifi工具 V1.2 - Cmd@Win7 - by cjiabing &netsh wlan start hostednetwork&call :ShowVirtualWifi
- :CreateVirtualWifi
- echo 两个硬条件:一要无线网卡;二要Windows 7以上系统。
- echo 创建虚拟Wifi仅需四步!&echo;
- set /p SSID=. 第一步:请设置Wifi名称(字母数字):
- set /p PassWord=. 第二步:请设置Wifi密码(至少8位):
- echo;&echo 注意:如被杀毒软件拦截,请选择“允许运行”!&echo;
- netsh wlan set hostednetwork mode=allow ssid=%SSID% key=%PassWord% >nul 2>nul
- net start MpsSvc
- echo 虚拟Wifi已启用!“无线网络连接 2”为新建的虚拟连接
- echo 图标右边会显示“Microsoft Virtual WiFi Miniport Adapter”
- echo;
- echo 第三步:手动设置共享
- echo 1.打开网络与共享中心→更改适配器设置→本地连接→属性→共享
- echo 2.两个复选框均选择“允许其他 ... 连接”
- echo 3.“家庭网络连接”选择“无线网络连接 2”
- echo 设置成功后“本地连接”图标右边会显示“网络 2,共享的”
- echo 设置失败时请重新启动系统防火墙Windows Firewall服务项
- echo 可使用命令 Netsh firewall reset 或 firewall.cpl 打开
- echo;
- echo 按任意键打开网络与共享中心 . . .
- pause>nul&Ncpa.cpl
- echo;
- echo 第四步:通过本程序“启动或关闭虚拟Wifi”
- echo;
- netsh wlan set hostednetwork mode=allow
- netsh wlan start hostednetwork
- echo 虚拟Wifi创建成功!
- echo;&pause&goto ShowVirtualWifi
- :ShowVirtualWifi
- cls
- for /f "tokens=1* delims=:" %%a in ('netsh wlan show hostednetwork') do (
- if "%%a"==" 模式 " if "%%b"==" 已禁用" (echo Wifi模式为:%%b,请重新建立虚拟Wifi!&goto CreateVirtualWifi) else echo Wifi模式为:%%b
- if /i "%%a"==" SSID 名称 " echo Wifi名称为:%%b
- if "%%a"==" 状态 " echo Wifi状态为:%%b&if "%%~b"==" 未启动" echo 请启动虚拟Wifi!
- )
- echo ———————————————————————————————————————
- echo 已经存在虚拟Wifi,您可以:
- echo.
- echo 【1】启动虚拟Wifi
- echo 【2】关闭虚拟Wifi
- echo 【3】开机自动启动虚拟Wifi
- echo 【4】开机不自动启动虚拟Wifi
- echo 【5】删除/禁用虚拟Wifi
- echo 【6】打开网络与共享中心
- echo 【7】命令提示符
- echo 设置自动关机(须开启服务):at 12:42:11 shutdown -s -f -t 60
- echo 取消自动关机(仅在关机倒计时过程中使用):shutdown -a
- echo 建议延迟系统休眠时间。推荐使用TeamViewer远程遥控关机。
- echo ———————————————————————————————————————
- echo.
- set input=
- set /p input=. 请输入序号并回车执行:
- echo.
- if "%input%"=="" netsh wlan show hostednetwork|find "已启动">nul&&netsh wlan stop hostednetwork||netsh wlan start hostednetwork
- if %input%==1 netsh wlan start hostednetwork
- if %input%==2 netsh wlan stop hostednetwork
- if %input%==3 reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Run /v "虚拟Wifi" /d "%~f0" /f
- if %input%==4 reg delete HKCU\Software\Microsoft\Windows\CurrentVersion\Run\ /v 虚拟Wifi /f
- if %input%==5 netsh wlan set hostednetwork mode=disallow &echo 虚拟Wifi删除成功!
- if %input%==6 Ncpa.cpl
- if %input%==7 cmd
- echo.
- pause&goto ShowVirtualWifi
复制代码
作者: DeepBlueTears 时间: 2013-12-29 22:24
一个作用类似的作品,欢迎提出建议:
http://www.bathome.net/thread-21048-1-1.html
作者: ivor 时间: 2013-12-29 22:55
早就用上微软的虚拟wifi了
作者: cjiabing 时间: 2014-1-3 18:35
回复 2# DeepBlueTears
早拜读过了,不过还没用过
作者: cjiabing 时间: 2014-1-3 18:36
回复 3# ivor
我们比较保守点。你是先进分子。
作者: netbenton 时间: 2014-1-3 20:01
哈哈~又有新玩法了~~
作者: cjiabing 时间: 2014-1-9 12:38
回复 6# netbenton
玩玩更健康!~
受不鸟W7的窗口主题颜色!~白茫茫一片,雾霭中毒一般!~批处理文件的图片一点不明显!怀念XP
作者: DeepBlueTears 时间: 2014-1-9 23:29
回复 4# cjiabing
从功能上来说,还有两个方面需要努力。一是能在批处理内解决共享的设置,二是能对一些故障进行修复(某些服务被停用了等等)。如果能解决这两个问题,再在人性化使用和兼容性上做一些优化比较好了。
作者: cjiabing 时间: 2014-1-10 00:59
回复 8# DeepBlueTears
谢谢指出
作者: mayz1994@qq.com 时间: 2014-1-22 14:10
还是xp,用不上
欢迎光临 批处理之家 (http://www.bathome.net/) |
Powered by Discuz! 7.2 |