批处理之家 - Powered by Discuz! Board

标题: [文本处理] [已解决]又出错了：批量运行不同文件夹里的BAT [打印本页]

作者: 思想之翼 时间: 2013-11-10 17:35 标题: [已解决]又出错了：批量运行不同文件夹里的BAT

用以下代码批量运行不同文件夹里的BAT，其中 “删除空格.bat ” 可以运行，但 “并排合并.bat ” 出现错误，恳望大家帮助查找错误所在。

欲批量运行不同文件夹里的BAT，以下代码出错：

@echo off
start /WAIT "" "d:\3\2\1.1\删除空格.bat"
start /WAIT "" "d:\3\2\1.1\并排合并.bat"
start /WAIT "" "d:\3\2\1.2\删除空格.bat"
start /WAIT "" "d:\3\2\1.2\并排合并.bat"
exit
复制代码

文件夹中的并排合并.bat 出现错误其代码如下：

@echo off&setlocal enabledelayedexpansion
set 文件数=100
for /l %%a in (1,1,%文件数%) do (
    for /f "delims=" %%i in (%%a.txt) do (
        set /a n+=1
        for %%a in (!n!) do set "#%%a=!#%%a! %%i"
    )
    set /a m=n,n=0
)
(for /l %%a in (1,1,%m%) do echo,!#%%a:~1!)>wj.txt
复制代码

文件夹中的删除空格.bat 可以运行其代码如下：

@echo off
for /f "delims=" %%x in ('dir/b/a-d *.txt')do (echo %%x&set/a n+=1
(for /f "usebackq delims=" %%i in ("%%x")do for %%j in (%%i)do echo.%%j)>temp.yky
move temp.yky "%%x")
echo %n% 个文件处理完毕
exit
复制代码

作者: DAIC 时间: 2013-11-10 17:40

报错信息在哪里？

作者: 思想之翼 时间: 2013-11-10 18:57

回复 2# DAIC

并排合并.bat 停止运行，如下：
d:\3>_

作者: DAIC 时间: 2013-11-10 19:28

回复 3# 思想之翼

把@echo off删掉，看看是在哪一行停止的。

作者: wscript 时间: 2013-11-10 19:38

start /?
command/program
            如果是内部 cmd 命令或批文件，那么该命令处理器是
            用 /K 命令行开关运行 cmd.exe 的。这表示该窗口在命令运行
            后仍然存在。

start /WAIT "" cmd.exe /d /c "xxx.bat"
复制代码

作者: xxpinqz 时间: 2013-11-10 22:04

@echo off
cd /d "d:\3\2\1.1\"
start /WAIT "" cmd /c "删除空格.bat"
start /WAIT "" cmd /c "并排合并.bat"
cd /d "d:\3\2\1.2\"
start /WAIT "" cmd /c "删除空格.bat"
start /WAIT "" cmd /c "并排合并.bat"
exit
复制代码

这样试试。

欢迎光临批处理之家 (http://www.bathome.net/)