批处理之家 - Powered by Discuz! Board

标题: [文本处理] [已解决]批处理在字符间插入符号，请看一下问题出在哪里？ [打印本页]

作者: suseek 时间: 2013-10-30 09:41 标题: [已解决]批处理在字符间插入符号，请看一下问题出在哪里？

本帖最后由 suseek 于 2013-10-30 14:45 编辑

一个2008年的贴子
原贴是如何在文本中插入符号
比如 aaa.txt中
00112233445566778899
99887766554433221100

想用批处理在他们之间每隔2个数字插入+得到下面的效果

00+11+22+33+44+55+66+77+88+99
99+88+77+66+55+44+33+22+11+00
我的脚本是:

@echo off
setlocal enabledelayedexpansion

for /f  "delims=" %%a in ( aaa.txt ) do (
         set var=
       set  str=%%a      
          call :lp
       echo !var:~1!
)         
pause
:lp
set str1=!str:~,2!
set var=!var!+!str1!
  set str=!str:~2!    
if not defined str  goto :eof
goto :lp
复制代码

为什么结果会多出三项+
00+11+22+33+44+55+66+77+88+99+ + +
99+88+77+66+55+44+33+22+11+00+ + +
文档中并没有多余的空格,谢谢

作者: apang 时间: 2013-10-30 10:15

set str=%%a和set str=!str:~2!后面含有n多空格，str值为空格时就会出现后面的空加号
set赋值时用引号包围：set "str=%%a" 就可以了

作者: foxJL 时间: 2013-10-30 10:26

call的效率太低，试试全用for

@echo off&setlocal enabledelayedexpansion
for /f %%i in (aaa.txt) do (
  set "str=%%i" & set "v="
  for /l %%j in (0,2,18) do (set v=!v!+!str:~%%j,2!)
  echo,!v:~1!
)
pause
复制代码

作者: foxJL 时间: 2013-10-30 10:32

300行比你的快了10秒钟,要效率尽量少用call goto这些命令

作者: DAIC 时间: 2013-10-30 10:47

回复 4# foxJL

凑个热闹：

sed "s/../&+/g; s/+$//" aaa.txt
复制代码

作者: suseek 时间: 2013-10-30 14:48

谢谢APANG的指导,FOXJL的新思路,DAIC的新方法

欢迎光临批处理之家 (http://www.bathome.net/)