Board logo

标题: [文本处理] 求教如何批处理修改.ini文件中某一日期 [打印本页]
作者: 花开花落    时间: 2013-8-26 10:26     标题: 求教如何批处理修改.ini文件中某一日期

求教如何批处理修改.ini文件中某一日期

如何通过批处理，将下面SaleNo=20130708一行中，等号后面的内容修改为当前日期，格式不变。
比如今天是2013年8月26日，等号后面的内容就修改为20130826
[system]
oilgunno=088
StationID=
SaleNo=20130708
作者: Lumiere    时间: 2013-8-26 12:27

回复 1# 花开花落
如果文本就这三行而且前面是固定的话，代码如下：
  1. @echo off

  2. set date=%date:/=%

  3. echo [system]>1.ini

  4. echo oilgunno=088>>1.ini

  5. echo StationID=>>1.ini

  6. echo SaleNo=%date:~0,-3%>>1.ini

  7. pause
复制代码
作者: DAIC    时间: 2013-8-26 13:36

  1. sed "s/SaleNo=.*/SaleNo=20130826/" a.ini > b.ini
复制代码
作者: PowerShell    时间: 2013-8-26 19:16

本帖最后由 PowerShell 于 2013-8-26 19:19 编辑

这条powershell命令，可以把“SaleNo=”为开头，后面内容任意的字符串，替换成今天内容，即你想要的
  1. "SaleNo=2013s0708" -replace "SaleNo=.*",('SaleNo=' + (get-date -uformat %Y%m%d))
复制代码
再说一遍，第一个带引号的字符串，应该是含有【SaleNo=】，而后面任意。也就是说这样也行
  1. "SaleNo=sdfsdkfflflccc" -replace "SaleNo=.*",('SaleNo=' + (get-date -uformat %Y%m%d))
复制代码
结果为：
SaleNo=20130826
作者: 花开花落    时间: 2013-8-27 21:24

本帖最后由 花开花落 于 2013-8-27 21:33 编辑

回复 2# Lumiere


    文本不是就这三行，前后都有很多内容，我只想替换SaleNo= 这一行， 除了这一行，整个文本没有再出现SaleNo=的字符了

    也可以把SaleNo= 这一行完全删除了，重新添加，要怎么写呢？
作者: Lumiere    时间: 2013-8-27 23:33

本帖最后由 Lumiere 于 2013-8-27 23:36 编辑

回复 5# 花开花落

那在帖子一开始就说清楚撒，我不知道后面两位高手的sed命令和powersell命令能否满足你的要求，你可以试一下。下面是我的批处理代码，自己试一下看。
假设你的这个ini文件名为1.ini，将以下代码做成bat文件放在同一文件夹下。
1.如果只是需要删除那一行，其他不便的话，代码如下：
  1. @echo off

  2. findstr /v "SaleNo" 1.ini>>2.ini

  3. del 1.ini&ren 2.ini 1.ini

  4. pause
复制代码
2.如果要替换那行而不是删除的话：
  1. @echo off

  2. set date=%date:/=%

  3. for /f "delims=" %%a in (1.ini) do (

  4. echo %%a|find "SaleNo="||echo %%a>>2.ini

  5. echo %%a|find "SaleNo="&&call echo SaleNo=%date:~0,-3%>>2.ini

  6. )

  7. del 1.ini&ren 2.ini 1.ini

  8. pause
复制代码
文本名假设一样。
作者: terse    时间: 2013-8-28 00:29

本帖最后由 terse 于 2013-8-28 11:55 编辑 
  1. @echo off&setlocal enabledelayedexpansion

  2. (for /f "tokens=*" %%i in (a.ini) do (

  3. 	set "str=%%i"

  4. 	if /i "!str:~,7!" == "SaleNo=" (

  5. 		echo SaleNo=%date:~,4%%date:~5,2%%date:~8,2%

  6. 	) else  echo !str!

  7. ))>$

  8. move $ a.ini

  9. pause
复制代码
作者: Lumiere    时间: 2013-8-28 01:54

回复 7# terse


    我测试了以下兄台的代码好像最后在那一行多了个双引号，其他没事。想请教一下哎，那个像美元一样的符号在批处理中表示什么意思？有什么用法呢？
作者: 花开花落    时间: 2013-8-28 09:10

两位的代码我都试过了，都可以实现，确实长见识了，非常感谢，不过还有一个小问题，就是这两个批处理执行完所有的空行都没有了，这个可以处理不？
作者: Batcher    时间: 2013-8-28 11:12

回复 8# Lumiere


一个普通的临时文件的名字
如果你喜欢的话可以把它改成a.txt
作者: terse    时间: 2013-8-28 11:53

回复 9# 花开花落 
  1. @echo off&setlocal enabledelayedexpansion

  2. (for /f "delims=" %%i in ('findstr /n .* b.ini') do (

  3. 	set "str=%%i"

  4. 	setlocal enabledelayedexpansion

  5. 	set "str=!str:*:=!"

  6. 	if /i "!str:~,7!" == "SaleNo=" (

  7. 		set "str=SaleNo=%date:~,4%%date:~5,2%%date:~8,2%"

  8. 	)

  9. 	echo;!str!

  10. 	endlocal

  11. ))>$

  12. move $ b.ini

  13. pause
复制代码
作者: Lumiere    时间: 2013-8-28 11:54

回复 10# Batcher


    就这样没有名字没有扩展名就表示临时文件么？这种临时文件与明确指明文件的名字来创建临时文件有什么内存资源占用方面的差别吗？还有其他用法么？
作者: terse    时间: 2013-8-28 11:55

回复 8# Lumiere
是的 多打了一个 谢提醒
作者: 花开花落    时间: 2013-8-28 13:44

本帖最后由 花开花落 于 2013-8-28 13:49 编辑

回复 11# terse


    这次可以了，非常感谢大家，学习啦
作者: Batcher    时间: 2013-8-28 13:55

回复 12# Lumiere


    效率上没有差异，可能他们觉得写成那个样子比较酷。或者写成那样不容易覆盖当前目录下的同名文件
作者: Lumiere    时间: 2013-8-28 16:47

回复 15# Batcher


    谢谢，学习了！
作者: terse    时间: 2013-8-28 18:59

回复 16# Lumiere
更多的因素是 不容易覆盖当前目录下的同名文件
作者: Lumiere    时间: 2013-8-28 20:12

回复 17# terse


    理解了，谢谢
作者: 花开花落    时间: 2013-8-29 09:30

是的，不覆盖同名文件总是写起来比较麻烦，但是感觉很帅呀
作者: 花开花落    时间: 2013-9-13 16:06

还有一个问题要请教，在这个ini文件中有一行内容，需要用到当前的IP地址，怎么将下面
“HOST=”后面的“192.168.1.6”，替换为“HOST=我当前机器本地连接的IP地址”呢

[Hosts]
Host=192.168.1.6
Standby=192.168.1.7
作者: 花开花落    时间: 2013-9-13 16:22

回复 11# terse


   
还有一个问题要请教，在这个ini文件中有一行内容，需要用到当前的IP地址，怎么将下面
“HOST=”后面的“192.168.1.6”，替换为“HOST=我当前机器本地连接的IP地址”呢

[Hosts]
Host=192.168.1.6
Standby=192.168.1.7



欢迎光临 批处理之家 (http://www.bathome.net/) Powered by Discuz! 7.2