批处理之家 - Powered by Discuz! Board

标题: [网络连接] 【已解决】请问下，下面这段BAT代码有办法统计条数吗？ [打印本页]

作者: macangyekillua 时间: 2013-7-25 18:16 标题: 【已解决】请问下，下面这段BAT代码有办法统计条数吗？

本帖最后由 macangyekillua 于 2013-7-27 10:57 编辑

@echo off
echo============== >> 不通.txt
date /t >>不通.txt
time /t >> 不通.txt
set #1=127.0.0.1
set #2=10.168.0.14
set #3=10.168.0.50
for /f "tokens=2 delims==" %%i in ('set #') do ping -n 1 %%i || (echo %%i 不通>>不通.txt) 
复制代码

请问上面这段代码我希望能够弹出个提示显示有几条是不通的要如何实现呢？谢谢。

作者: yu2n 时间: 2013-7-25 19:27

@echo off
echo ============== >> "不通.txt"
date /t >> "不通.txt"
time /t >> "不通.txt"
set #1=127.0.0.1
set #2=10.168.0.14
set #3=10.168.0.50

set NotOnline=0
setlocal enabledelayedexpansion
for /f "tokens=2 delims==" %%i in ('set #') do (
    ping -w 200 -n 1 %%i >nul 2>nul && (
        echo %%i 通
    ) || (
        set /a NotOnline=!NotOnline! + 1
        echo %%i 不通
        echo %%i 不通 >> "不通.txt"
    )
)
setlocal disabledelayedexpansion
echo 共有 %NotOnline% 条不通。
echo 共有 %NotOnline% 条不通。 >> "不通.txt"
pause
复制代码

作者: macangyekillua 时间: 2013-7-25 19:52

回复 2# yu2n

下班刚到家，确实可以用，非常非常的感谢你的热心。

作者: yu2n 时间: 2013-7-25 19:54

yu2n 发表于 2013-7-25 19:27

要弹出提示的话，代码最后可以加上

mshta vbscript:Msgbox("共有 %NotOnline% 条不通。",64,"提示")(window.close)
复制代码

作者: macangyekillua 时间: 2013-7-25 20:08

回复 4# yu2n

恩好的，非常感谢您。

作者: macangyekillua 时间: 2013-7-25 20:39

回复 4# yu2n

还想请问一下，有办法把date/t 和 time/t 放到同一行吗？
试了半天都没弄好。

作者: yu2n 时间: 2013-7-27 00:18

回复 6# macangyekillua

1. 简单的：

@echo,%date%   %time%
复制代码

结果：
2013/07/27 周六 0:17:48.99

2. 格式化(如2013-07-27 00:13:00)：

@set "dateStr=%date:~0,4%-%date:~5,2%-%date:~8,2%"
@set "timeStr=%time:~0,2%:%time:~3,2%:%time:~6,2%"
@echo,%dateStr% %timeStr%
复制代码

合成一句

@echo,%date:~0,4%-%date:~5,2%-%date:~8,2% %time:~0,2%^:%time:~3,2%^:%time:~6,2%
复制代码

结果：
2013-07-27 0:17:00

作者: macangyekillua 时间: 2013-7-27 10:56

本帖最后由 macangyekillua 于 2013-7-27 10:58 编辑

回复 7# yu2n

非常感谢，我自己反复研究了一下，弄出了第一种方法。
没想到你又热心的给出了更好的，真的学习到了。

不过我现在还有一个纠结点的问题，我想自己再研究一下，如果实在想不出，就短信麻烦下你了，
还请不吝赐教，谢谢。

欢迎光临批处理之家 (http://www.bathome.net/)